请教一个关联表查询的问题

[nimingxin1987]

tb1
-------------------------------------------------
RecordID ToDoUserID
1 1,2
2
3 1,2,3,4
4 2,4

tbUser
-------------------------------------------------
UserID sName
1 小张
2 小王
3 小李
4 小赵

希望得到结果
-------------------------------------------------
RecordID ToDoUser
1 小张,小王
2
3 小张,小王,小李,小赵
4 小王,小赵

[二月十六]

--测试数据
if not object_id(N'Tempdb..#tb1') is null
	drop table #tb1
Go
Create table #tb1([RecordID] int,[ToDoUserID] nvarchar(27))
Insert #tb1
select 1,N'1,2' union all
select 2,null union all
select 3,N'1,2,3,4' union all
select 4,N'2,4'
GO
if not object_id(N'Tempdb..#tbUser') is null
	drop table #tbUser
Go
Create table #tbUser([UserID] int,[sName] nvarchar(22))
Insert #tbUser
select 1,N'小张' union all
select 2,N'小王' union all
select 3,N'小李' union all
select 4,N'小赵'
Go
--测试数据结束
SELECT  RecordID ,
        STUFF(( SELECT  ',' + sName
                FROM    #tbUser
                WHERE   CHARINDEX(',' + RTRIM(UserID) + ',',
                                  ',' + ToDoUserID + ',') > 0
              FOR
                XML PATH('')
              ), 1, 1, '') AS ToDoUser
FROM    #tb1

[听雨停了]

前两天有人问了一个一模一样的问题，你可以去看看，版主这个也是那天他写的复制过来给你的。链接:http://bbs.csdn.net/topics/392264177