帮我看一下我写的一个存储过程问题在哪里，为什么不能执行

[起个名字忒难]

CREATE PROCEDURE sp_BackupDatabases
AS
BEGIN
--设置备份数据库的存放目录
DECLARE @diskPath NVARCHAR(300)
DECLARE @i int
set @i=1
while @i<6
begin
SET @diskPath='E:\Database\Backup\data_fast_'+cast(@i as nvarchar(2))+'_'
+CONVERT(VARCHAR, GETDATE(),112)+'_'
+REPLACE(CONVERT(VARCHAR, GETDATE(),108),':','')+'.BAK';
exec('BACKUP DATABASE data_fast_'+@i+' TO DISK = '+@diskPath+' WITH FORMAT;')
set @i=@i+1
end
END

这个存储过程目的是备份data_fast_1 一直到 data_fast_5 共5个database，执行的时候，一直提示
消息 102，级别 15，状态 1，第 1 行
'E:' 附近有语法错误。
消息 319，级别 15，状态 1，第 1 行
关键字 'with' 附近有语法错误。如果此语句是公用表表达式、xmlnamespaces 子句或者更改跟踪上下文子句，那么前一个语句必须以分号结尾。
消息 102，级别 15，状态 1，第 1 行

[吉普赛的歌]

IF OBJECT_ID('sp_BackupDatabases') IS NOT NULL
	DROP PROC sp_BackupDatabases
GO
CREATE PROCEDURE sp_BackupDatabases 	
AS
BEGIN
--设置备份数据库的存放目录
DECLARE @diskPath NVARCHAR(300),@sql NVARCHAR(MAX)	
DECLARE @i int
set @i=1
while @i<6 
begin
	SET @diskPath='E:\Database\Backup\data_fast_'+cast(@i as nvarchar(2))+'_'
		+CONVERT(VARCHAR, GETDATE(),112)+'_'
		+REPLACE(CONVERT(VARCHAR, GETDATE(),108),':','')+'.BAK';        
	SET @sql='BACKUP DATABASE data_fast_'+@i+' TO DISK =N'''+@diskPath+''' WITH FORMAT;'
	PRINT @sql
	EXEC(@sql)
	set @i=@i+1
end
END
GO

[起个名字忒难]

感谢版主帮忙，能说一下我之前写的问题在哪里吗？你这个代码现在报这个错误

[听雨停了]

exec('BACKUP DATABASE data_fast_'+@i+' TO DISK = '+@diskPath+' WITH FORMAT;')
--改成
exec('BACKUP DATABASE data_fast_'+@i+' TO DISK = '''+@diskPath+''' WITH FORMAT;')

把上面这句改一下就好了，路径少了引号，所以报错了，加上就好了

[快溜]

exec('BACKUP DATABASE data_fast_'+rtrim(@i)+' TO DISK = '+@diskPath+' WITH FORMAT;')

[吉普赛的歌]

引用 3 楼 huang1314wei 的回复:

感谢版主帮忙，能说一下我之前写的问题在哪里吗？你这个代码现在报这个错误

整型没有转成字符串， 只有同类型的才能相加， 下面这个亲测没问题的了：

IF OBJECT_ID('sp_BackupDatabases') IS NOT NULL
    DROP PROC sp_BackupDatabases
GO
CREATE PROCEDURE sp_BackupDatabases    
AS
BEGIN
--设置备份数据库的存放目录
DECLARE @diskPath NVARCHAR(300),@sql NVARCHAR(MAX)   
DECLARE @i int
set @i=1
while @i<6
begin
    SET @diskPath='E:\Database\Backup\data_fast_'+cast(@i as nvarchar(2))+'_'
        +CONVERT(VARCHAR, GETDATE(),112)+'_'
        +REPLACE(CONVERT(VARCHAR, GETDATE(),108),':','')+'.BAK';        
    SET @sql='BACKUP DATABASE data_fast_'+cast(@i as nvarchar(2))+' TO DISK =N'''+@diskPath+''' WITH FORMAT;'
    PRINT @sql
    EXEC(@sql)
    set @i=@i+1
end
END
GO

[道素]

长文件名要将完整的路径文件名用双引号括起来

exec('BACKUP DATABASE data_fast_'+ltrim(@i)+' TO DISK =" '+@diskPath+'" WITH FORMAT;')