用正则表达式替换WORD段尾空格出现的奇怪现象

[天地惠]

请教各位大侠专家！
用正则表达式替换段尾空格时，如果文字段落之后紧跟着表格，则被替换的文字所在段落会跑到表格中去，除此之外其他情况却是正常的。百思不得其解，烦请各位老师指点。

Sub 删除段尾空格()
Dim i As Paragraph, mt, oRang As Range, n%, m%
Set regx = CreateObject("vbscript.regexp")
With regx
.Global = True: .IgnoreCase = False: .MultiLine = True
.Pattern = "\s+(\r)" '删除段落尾部的空格,如果没有\r，将会将回车符一并作为空格处理了。
For Each i In ActiveDocument.Paragraphs '在遍历各个段落
For Each mt In .Execute(i.Range.Text) '遍历所匹配的各个文本
m = mt.FirstIndex: n = mt.Length - 1 '查找的起始位置（从0开始计数）、长度
Set oRang = ActiveDocument.Range(i.Range.Start + m, i.Range.Start + m + n) '定位查找到的文本在整个文章中的起始位置、终止位置
i.Range.Text = .Replace(i.Range.Text, "$1")
Next
Next
End With
End Sub

运行之前的文档


运行之后的文档

[milaoshu1020]

我这里可以重现你说的奇怪现象.
不使用正则表达式,而是直接将原来的Text赋值给Text的话,也同样会有这个问题.
我试了很久,只找到一个能基本代替正则表达式替换的方法,你可以试试:

Sub 删除段尾空格()
    Dim objFind As Find
    Set objFind = ActiveDocument.Content.Find
    objFind.Execute FindText:="^w^13", ReplaceWith:="^13", Replace:=wdReplaceAll
End Sub

这段代码执行后同样有问题,就是表格上边的一行不能去掉空格,表格内部不能去掉空格.
其他的地方大概没有问题.

[天地惠]

但是，为什么在WORD界面“查找替换”空格却不会出现这种奇怪的现象。
我是菜鸟，在此提出此问题，主要是想大神们帮助解决这个问题。用VBA的正则表达式，怎样才能避免这种奇怪的现象发生

[milaoshu1020]

引用 3 楼 天地惠 的回复:

但是，为什么在WORD界面“查找替换”空格却不会出现这种奇怪的现象。
我是菜鸟，在此提出此问题，主要是想大神们帮助解决这个问题。用VBA的正则表达式，怎样才能避免这种奇怪的现象发生

我的WORD界面"查找替换"^w^13"同样会有这个问题啊.
"^w"相当于正则表达式里的"\s+";
"^13"就相当于正则表达式里的"\r";
你直接搜索/替换空格或者"^w"确实是没问题的,但加上结束标志"^13"就不行了,仅有部分被搜索/替换.
所以这个应该是Word这个软件设计的问题.

[天地惠]

请问大神，能否在上面提问代码的基础上，通过判断下一段落是否为表格，以决定本段尾的空格是否删除？
如果这个思路可行，烦请大神帮助完善一下代码。

衷心感谢！！

[milaoshu1020]

i.Range.Tables.Count
等于0的话应该就不在表格中.

[SoSo工具集作者]

Sub 删除段尾空格()
    Dim i As Paragraph, mt, oRang As Range, n%, m%, mRange As Range
    Set regx = CreateObject("vbscript.regexp")
    With regx
        .Global = True: .IgnoreCase = False: .MultiLine = True
        .Pattern = "\s+$"   '删除 段落尾部的空格,如果没有\r，将会将回车符一并作为空格处理了。
        For Each i In ActiveDocument.Paragraphs  '在遍历各个段落
            Set mRange = ActiveDocument.Range(i.Range.Start, i.Range.End - 1)
            For Each mt In .Execute(mRange.Text)    '遍历所匹配的各个文本
                m = mt.FirstIndex: n = mt.Length  '查找的起始位置（从0开始计数）、长度
                Set oRang = ActiveDocument.Range(mRange.Start + m, mRange.Start + m + n) '定位查找到的文本在整个文章中的起始位置、终止位置
               oRang.Text = .Replace(oRang.Text, "")
            Next
        Next
    End With
End Sub

[a44234]

mypara.Range.Information(wdWithInTable)

[linyuxuan94]

可以用Select避开段落和表格之间的换行符

Sub 删除段尾空格()
Dim i As Paragraph, mt, oRang As Range, n%, m%
Set regx = CreateObject("vbscript.regexp")
With regx
        .Global = True: .IgnoreCase = False: .MultiLine = True
        .Pattern = "\s+(\r)"   '删除段落尾部的空格,如果没有\r，将会将回车符一并作为空格处理了。
        For Each i In ActiveDocument.Paragraphs  '在遍历各个段落
                For Each mt In .Execute(i.Range.Text)    '遍历所匹配的各个文本
                        m = mt.FirstIndex: n = mt.Length - 1 '查找的起始位置（从0开始计数）、长度
                        Set oRang = ActiveDocument.Range(i.Range.Start + m, i.Range.Start + m + n)  '定位查找到的文本在整个文章中的起始位置、终止位置
			i.Range.Select
			Selection.MoveLeft Unit:=wdCharacter, Count:=1, Extend:=wdExtend 
			Selection.Range.Text=Left(.Replace(i.Range.Text, "$1"),Len(.Replace(i.Range.Text, "$1"))-1)
			'避免删除段尾换行符
                Next
        Next        
End With
End Sub

[linyuxuan94]

也可以用下面代码避开段落和表格之间的换行符

Sub 删除段尾空格()
Dim i As Paragraph, mt, oRang As Range, n%, m%
Set regx = CreateObject("vbscript.regexp")
With regx
        .Global = True: .IgnoreCase = False: .MultiLine = True
        .Pattern = "\s+(\r)"   '删除段落尾部的空格,如果没有\r，将会将回车符一并作为空格处理了。
        For Each i In ActiveDocument.Paragraphs  '在遍历各个段落
                For Each mt In .Execute(i.Range.Text)    '遍历所匹配的各个文本
                        m = mt.FirstIndex: n = mt.Length - 1 '查找的起始位置（从0开始计数）、长度
                        Set oRang = ActiveDocument.Range(i.Range.Start + m, i.Range.Start + m + n)  '定位查找到的文本在整个文章中的起始位置、终止位置
			Set myRange = i.Range 
			myRange.End = myRange.End - 1
			myRange.Text = Left(formativetext, Len(formativetext) - 1)
			'避免删除段尾换行符
                Next
        Next        
End With
End Sub