[cmd]怎么处理重定向的文本

[sudoks]

本来想用net user 获取用户重定向到文本, 然后用vc读取文件,但是发现文件里有很多不需要的内容,怎么处理掉.
重定向
怎么能处理成这样

[ForestDB]

cmd脚本可编程性并不太好，建议powershell，或者配合python之类的脚本。要不就是在VC中直接做文本处理。

[qybao]

写个bat，过滤net user的信息，然后重定向到文件

rem 用for来分割每行数据，然后判断合法数据输出
for /f "usebackq tokens=1,2,3 delims= " %%i in ('net user') do (
    set v1=%%i
    set v2=%%j
    if not "%v1%"=="" if not "%v2%"=="" if not "%v1:~0,1%"=="-" if not "%v1:~0,2"=="\\" (
        echo "%%i"
        echo "%%j"
        echo "%%k"
    )
)

[sudoks]

引用 2 楼 qybao 的回复:

写个bat，过滤net user的信息，然后重定向到文件

rem 用for来分割每行数据，然后判断合法数据输出
for /f "usebackq tokens=1,2,3 delims= " %%i in ('net user') do (
    set v1=%%i
    set v2=%%j
    if not "%v1%"=="" if not "%v2%"=="" if not "%v1:~0,1%"=="-" if not "%v1:~0,2"=="\\" (
        echo "%%i"
        echo "%%j"
        echo "%%k"
    )
)

大神,我按照你的方法试了下,没有重定向出来啊. 是我写到位置不对么

[qybao]

if的最后一个判断错了
"%v1:~0,2"=="\\" 改成 "%v1:~0,2%"=="\\" 漏了个百分号

[sudoks]

引用 4 楼 qybao 的回复:

if的最后一个判断错了 "%v1:~0,2"=="\\" 改成 "%v1:~0,2%"=="\\" 漏了个百分号

我加的重定向位置是不是错了.没有创建文件.

[qybao]

引用 5 楼 Young man 的回复:

我加的重定向位置是不是错了.没有创建文件.

测试了一下，不是你重定向出问题，而是变量延时展开的问题
改成以下（加上变量延时展开）

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1,2,3 delims= " %%i in ('net user') do (
    set v1=%%i
    set v2=%%j
    if not "!v1!"=="" if not "!v2!"=="" if not "!v1:~0,1!"=="-" if not "!v1:~0,2!"=="\\" (
        echo %%i
        echo %%j
        if not "%%k"=="" echo %%k
    )
)

[sudoks]

引用 6 楼 qybao 的回复:

[quote=引用 5 楼 Young man 的回复:] 我加的重定向位置是不是错了.没有创建文件.

测试了一下，不是你重定向出问题，而是变量延时展开的问题 改成以下（加上变量延时展开）

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1,2,3 delims= " %%i in ('net user') do (
    set v1=%%i
    set v2=%%j
    if not "!v1!"=="" if not "!v2!"=="" if not "!v1:~0,1!"=="-" if not "!v1:~0,2!"=="\\" (
        echo %%i
        echo %%j
        if not "%%k"=="" echo %%k
    )
)

[/quote] 太感谢了,完美解决