如何把MDI窗体的子窗体右上角的最大最小化屏蔽，但不屏蔽关闭按钮？

[gototry]

最好能给点程序代码

[strongfisher]

不像其他的 Form 一样，MDIForm 并没有提供 MaxButton 及 MinButton 的属性来让我们移除最大化及最小化的按钮，如果您想移除 MDIForm 的最大化及最小化的按钮，您可以在 MDIForm 中加入以下的程序，但是如果您只想移除其中的一个，则只要将对应的程序码加上注解符号即可。

'请在 MDIForm 的声明区中加入以下声明

[strongfisher]

#If Win32 Then
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
#Else
Private Declare Function SetWindowLong Lib "User" (ByVal hwnd As Integer, ByVal nIndex As Integer, ByVal dwNewLong As Long) As Long
Private Declare Function GetWindowLong Lib "User" (ByVal hwnd As Integer, ByVal nIndex As Integer) As Long
#End If

Const WS_MINIMIZEBOX = &H20000 '最小化
Const WS_MAXIMIZEBOX = &H10000 '最大化
Const GWL_STYLE = (-16)

'在 MDIForm 的 MDIForm_Load 事件中加入以下程序码

Sub MDIForm_Load()
Dim lWnd As Long
lWnd = GetWindowLong(Me.hwnd, GWL_STYLE)
lWnd = lWnd And Not (WS_MINIMIZEBOX) '最小化
lWnd = lWnd And Not (WS_MAXIMIZEBOX) '最大化
lWnd = SetWindowLong(Me.hwnd, GWL_STYLE, lWnd)
End Sub

[beckham1122]

也只能用API了。学习————————

[hillmanweb]

可以设置窗体的BorderStyle属性，具体含义如下：

Form 对象的 BorderStyle 属性设置值如下：

常数 设置值 描述
vbBSNone 0 无（没有边框或与边框相关的元素）。
vbFixedSingle 1 固定单边框。可以包含控制菜单框，标题栏，“最大化”按钮，和“最小化”按钮。只有使用最大化和最小化按钮才能改变大小。
vbSizable 2 （缺省值）可调整的边框。可以使用设置值1列出的任何可选边框元素重新改变尺寸。
vbFixedDouble 3 固定对话框。可以包含控制菜单框和标题栏，不能包含最大化和最小化按钮，不能改变尺寸。
vbFixedToolWindow 4 固定工具窗口。不能改变尺寸。显示关闭按钮并用缩小的字体显示标题栏。窗体在 Windows 95 的任务条中不显示。
vbSizableToolWindow 5 可变尺寸工具窗口。可变大小。显示关闭按钮并用缩小的字体显示标题栏。窗体在 Windows 95 的任务条中不显示。

××××××××××××××××××××××××
你可以设置成1或者3的样式，应该可以达到你的要求。

[lihonggen0]

方法很多呀：

方法一：


Private Declare Function GetSystemMenu Lib "user32" (ByVal hwnd As Long, ByVal bRevert As Long) As Long
Private Declare Function GetMenuItemCount Lib "user32" (ByVal hMenu As Long) As Long
Private Declare Function DrawMenuBar Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function RemoveMenu Lib "user32" (ByVal hMenu As Long, ByVal nPosition As Long, ByVal wFlags As Long) As Long
Const MF_BYPOSITION = &H400&
Const MF_REMOVE = &H1000&
Private Sub MDIForm_Load()
Dim hSysMenu As Long, nCnt As Long
' Get handle to our form's system menu
' (Restore, Maximize, Move, close etc.)
hSysMenu = GetSystemMenu(Me.hwnd, False)
If hSysMenu Then
' Get System menu's menu count
nCnt = GetMenuItemCount(hSysMenu)
If nCnt Then
RemoveMenu hSysMenu, nCnt - 3, MF_BYPOSITION Or MF_REMOVE
RemoveMenu hSysMenu, nCnt - 4, MF_BYPOSITION Or MF_REMOVE

DrawMenuBar (Me.hwnd)
End If
End If
End Sub

[lihonggen0]

方法二：

Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function GetSystemMenu Lib "user32" (ByVal hwnd As Long, ByVal bRevert As Long) As Long
Private Declare Function RemoveMenu Lib "user32" (ByVal hMenu As Long, ByVal nPosition As Long, ByVal wFlags As Long) As Long
Private Declare Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal x As Long, ByVal y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
Const SWP_FRAMECHANGED = &H20
Const SWP_NOMOVE = &H2
Const SWP_NOZORDER = &H4
Const SWP_NOSIZE = &H1
Const WS_EX_TOOLWINDOW = &H80&
Const GWL_EXSTYLE = (-20)
Const MF_BYPOSITION = &H400&
Const MF_REMOVE = &H1000&
Const SC_CLOSE = &HF060
Const SC_MAXIMIZE = &HF030
Const SC_MINIMIZE = &HF020



Private Sub MDIForm_Load()
RemoveMenu GetSystemMenu(hwnd, 0), SC_CLOSE, MF_REMOVE

RemoveMenu GetSystemMenu(hwnd, 0), SC_MAXIMIZE, MF_REMOVE

RemoveMenu GetSystemMenu(hwnd, 0), SC_MINIMIZE, MF_REMOVE


End Sub

[lihonggen0]

方法三：

Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Const WS_MINIMIZEBOX = &H20000
Private Const WS_MAXIMIZEBOX = &H10000
Private Const GWL_STYLE = (-16)

Private Sub MDIForm_Load()
Dim TempLng As Long
TempLng = GetWindowLong(Me.hwnd, GWL_STYLE)
TempLng = TempLng And Not WS_MINIMIZEBOX '最小化
TempLng = TempLng And Not WS_MAXIMIZEBOX '最大化
SetWindowLong Me.hwnd, GWL_STYLE, TempLng

End Sub


是最好的方法！