datareport纸张宽度问题

zy000 2003-08-19 11:58:52
用 datareoprt.show显示报表,提示错误:报表宽度大于纸的宽度.请问这个问题怎么解决??
...全文
44 9 打赏 收藏 转发到动态 举报
写回复
用AI写文章
9 条回复
切换为时间正序
请发表友善的回复…
发表回复
gemgama 2003-08-24
  • 打赏
  • 举报
回复
回楼主:我的计算机没有打印机是不是就没办法
没有打印机无所谓,就新安装一个打印机的驱动程序就行了,这样就相当与有一台物理的打印机
negy 2003-08-21
  • 打赏
  • 举报
回复

Private Const CCHDEVICENAME = 32
Private Const CCHFORMNAME = 32

'Constants for NT security
Private Const STANDARD_RIGHTS_REQUIRED = &HF0000
Private Const PRINTER_ACCESS_ADMINISTER = &H4
Private Const PRINTER_ACCESS_USE = &H8
Private Const PRINTER_ALL_ACCESS = (STANDARD_RIGHTS_REQUIRED Or PRINTER_ACCESS_ADMINISTER Or PRINTER_ACCESS_USE)

'Constants used to make changes to the values contained in the DevMode
Private Const DM_MODIFY = 8
Private Const DM_IN_BUFFER = DM_MODIFY
Private Const DM_COPY = 2
Private Const DM_OUT_BUFFER = DM_COPY
Private Const DM_DUPLEX = &H1000&
Public Const DMDUP_SIMPLEX = 1
Private Const DMDUP_VERTICAL = 2
Private Const DMDUP_HORIZONTAL = 3
Private Const DM_ORIENTATION = &H1&
Public Const DM_PAPERSIZE = &H2&

'------USER DEFINED TYPES

'The DevMode structure contains printing parameters.
'Note that this only represents the PUBLIC portion of the DevMode.
' The full DevMode also contains a variable length PRIVATE section
' which varies in length and content between printer drivers.
'NEVER use this User Defined Type directly with any API call.
' Always combine it into a FULL DevMode structure and then send the
' full DevMode to the API call.
Private Type DEVMODE
dmDeviceName As String * CCHDEVICENAME
dmSpecVersion As Integer
dmDriverVersion As Integer
dmSize As Integer
dmDriverExtra As Integer
dmFields As Long
dmOrientation As Integer
dmPaperSize As Integer
dmPaperLength As Integer
dmPaperWidth As Integer
dmScale As Integer
dmCopies As Integer
dmDefaultSource As Integer
dmPrintQuality As Integer
dmColor As Integer
dmDuplex As Integer
dmYResolution As Integer
dmTTOption As Integer
dmCollate As Integer
dmFormName As String * CCHFORMNAME
dmLogPixels As Integer
dmBitsPerPel As Long
dmPelsWidth As Long
dmPelsHeight As Long
dmDisplayFlags As Long
dmDisplayFrequency As Long
dmICMMethod As Long '// Windows 95 only
dmICMIntent As Long ' // Windows 95 only
dmMediaType As Long ' // Windows 95 only
dmDitherType As Long ' // Windows 95 only
dmReserved1 As Long ' // Windows 95 only
dmReserved2 As Long ' // Windows 95 only
End Type

Private Type PRINTER_DEFAULTS
'Note:
' The definition of Printer_Defaults in the VB5 API viewer is incorrect.
' Below, pDevMode has been corrected to LONG.
pDatatype As String
pDevMode As Long
DesiredAccess As Long
End Type


'------DECLARATIONS

Private Declare Function OpenPrinter Lib "winspool.drv" Alias "OpenPrinterA" (ByVal pPrinterName As String, phPrinter As Long, pDefault As PRINTER_DEFAULTS) As Long
Private Declare Function SetPrinter Lib "winspool.drv" Alias "SetPrinterA" (ByVal hPrinter As Long, ByVal Level As Long, pPrinter As Any, ByVal Command As Long) As Long
Private Declare Function GetPrinter Lib "winspool.drv" Alias "GetPrinterA" (ByVal hPrinter As Long, ByVal Level As Long, pPrinter As Any, ByVal cbBuf As Long, pcbNeeded As Long) As Long
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (hpvDest As Any, hpvSource As Any, ByVal cbCopy As Long)
Private Declare Function ClosePrinter Lib "winspool.drv" (ByVal hPrinter As Long) As Long

'The following is an unusual declaration of DocumentProperties:
' pDevModeOutput and pDevModeInput are usually declared ByRef. They are declared
' ByVal in this program because we're using a Printer_Info_2 structure.
' The pi2 structure contains a variable of type LONG which contains the address
' of the DevMode structure (this is called a pointer). This LONG variable must
' be passed ByVal.
' Normally this function is called with a BYTE ARRAY which contains the DevMode
' structure and the Byte Array is passed ByRef.
Private Declare Function DocumentProperties Lib "winspool.drv" Alias "DocumentPropertiesA" (ByVal hwnd As Long, ByVal hPrinter As Long, ByVal pDeviceName As String, ByVal pDevModeOutput As Any, ByVal pDevModeInput As Any, ByVal fMode As Long) As Long


'------CODE

Public Sub SetOrientation(NewSetting As Long, chng As Integer)
Dim PrinterHandle As Long
Dim PrinterName As String
Dim pd As PRINTER_DEFAULTS
Dim MyDevMode As DEVMODE
Dim Result As Long
Dim Needed As Long
Dim pFullDevMode As Long
Dim pi2_buffer() As Long 'This is a block of memory for the Printer_Info_2 structure
'If you need to use the Printer_Info_2 User Defined Type, the
' definition of Printer_Info_2 in the API viewer is incorrect.
' pDevMode and pSecurityDescriptor should be defined As Long.

If NewSetting = Printer.Orientation Then Exit Sub

PrinterName = Printer.DeviceName
If PrinterName = "" Then
Exit Sub
End If

pd.pDatatype = vbNullString
pd.pDevMode = 0&
'Printer_Access_All is required for NT security
pd.DesiredAccess = PRINTER_ALL_ACCESS

Result = OpenPrinter(PrinterName, PrinterHandle, pd)

'The first call to GetPrinter gets the size, in bytes, of the buffer needed.
'This value is divided by 4 since each element of pi2_buffer is a long.
Result = GetPrinter(PrinterHandle, 2, ByVal 0&, 0, Needed)
ReDim pi2_buffer((Needed \ 4))
Result = GetPrinter(PrinterHandle, 2, pi2_buffer(0), Needed, Needed)

'The seventh element of pi2_buffer is a Pointer to a block of memory
' which contains the full DevMode (including the PRIVATE portion).
pFullDevMode = pi2_buffer(7)

'Copy the Public portion of FullDevMode into our DevMode structure
Call CopyMemory(MyDevMode, ByVal pFullDevMode, Len(MyDevMode))

'Make desired changes
MyDevMode.dmDuplex = NewSetting
MyDevMode.dmFields = DM_DUPLEX Or DM_ORIENTATION
MyDevMode.dmOrientation = chng
'Copy our DevMode structure back into FullDevMode
Call CopyMemory(ByVal pFullDevMode, MyDevMode, Len(MyDevMode))

'Copy our changes to "the PUBLIC portion of the DevMode" into "the PRIVATE portion of the DevMode"
' Result = DocumentProperties(Form1.hwnd, PrinterHandle, PrinterName, ByVal pFullDevMode, ByVal pFullDevMode, DM_IN_BUFFER Or DM_OUT_BUFFER)

'Update the printer's default properties (to verify, go to the Printer folder
' and check the properties for the printer)
Result = SetPrinter(PrinterHandle, 2, pi2_buffer(0), 0&)

Call ClosePrinter(PrinterHandle)

'Note: Once "Set Printer = " is executed, anywhere in the code, after that point
' changes made with SetPrinter will ONLY affect the system-wide printer --
' -- the changes will NOT affect the VB printer object.
' Therefore, it may be necessary to reset the printer object's parameters to
' those chosen in the devmode.
Dim p As Printer
For Each p In Printers
If p.DeviceName = PrinterName Then
Set Printer = p
Exit For
End If
Next p
' Printer.Duplex = MyDevMode.dmDuplex
End Sub
iiboy 2003-08-21
  • 打赏
  • 举报
回复
哦!
对了,如果没有打印机的话,也可以安装一台不存在的打印实现功能哦!只是不能打印罢了,模拟显示还是可以的.
在安装打印机时,将"自动检测并安装我的即插即用打印机"前的'钓'去掉,然后"下一步",其它选项就随便你了.直到安装完毕,当然就在存在打印测试页了哆!
iiboy 2003-08-21
  • 打赏
  • 举报
回复
一般来说是你打印的内容超出了打印纸可打印的范围,要不使用更大的纸,要不可以将LeftMargin和RightMargin设为0看如何.
gzqg 2003-08-21
  • 打赏
  • 举报
回复
不需要打印机只要安装一个打印机驱动程序就行了.你的问题有几种可能:1 横/纵不对; 2 纸张大小设置不对; 3 需要调整reportwidth 和 leftmargin,rightmargin(空白).
hc_z 2003-08-20
  • 打赏
  • 举报
回复
要吗将你报表的宽度缩小,要嘛横打,要么改变纸张的宽度。前两个好说。第三个不好实现,给个代码,也刚从CSDN抄下来的。^_^。
Option Explicit

Public Enum PrinterOrientationConstants
OrientPortrait = 1
OrientLandscape = 2
End Enum

Private Type DEVMODE
dmDeviceName As String * 32
dmSpecVersion As Integer
dmDriverVersion As Integer
dmSize As Integer
dmDriverExtra As Integer
dmFields As Long
dmOrientation As Integer
dmPaperSize As Integer
dmPaperLength As Integer
dmPaperWidth As Integer
dmScale As Integer
dmCopies As Integer
dmDefaultSource As Integer
dmPrintQuality As Integer
dmColor As Integer
dmDuplex As Integer
dmYResolution As Integer
dmTTOption As Integer
dmCollate As Integer
dmFormName As String * 32
dmUnusedPadding As Integer
dmBitsPerPel As Integer
dmPelsWidth As Long
dmPelsHeight As Long
dmDisplayFlags As Long
dmDisplayFrequency As Long
End Type

Private Type PRINTER_DEFAULTS
pDatatype As String
pDevMode As Long
DesiredAccess As Long
End Type

Private Type PRINTER_INFO_2
pServerName As Long
pPrinterName As Long
pShareName As Long
pPortName As Long
pDriverName As Long
pComment As Long
pLocation As Long
pDevMode As Long
pSepFile As Long
pPrintProcessor As Long
pDatatype As Long
pParameters As Long
pSecurityDescriptor As Long
Attributes As Long
Priority As Long
DefaultPriority As Long
StartTime As Long
UntilTime As Long
Status As Long
cJobs As Long
AveragePPM As Long
End Type

'*******************'
' iDmpaperÖµ Ö½ÕÅ '
' 9 A4 '
' 11 A5 '
' 13 B5 '
'*******************'

Private Const DM_IN_BUFFER As Long = 8
Private Const DM_OUT_BUFFER As Long = 2
Private Const DM_ORIENTATION As Long = &H1
Private Const DM_PAPERSIZE = &H2&

'by zhc
Private Const DM_PAPERLENGTH = &H3&
Private Const DM_PAPERWIDTH = &H4&

Private Const DM_SCALE = &H5&
Private Const DM_COPIES = &H6&
Private Const DM_DEFAULTSOURCE = &H7&
Private Const DM_PRINTQUALITY = &H8&




Private Const PRINTER_ACCESS_ADMINISTER As Long = &H4
Private Const PRINTER_ACCESS_USE As Long = &H8
Private Const STANDARD_RIGHTS_REQUIRED As Long = &HF0000
Private Const PRINTER_ALL_ACCESS = (STANDARD_RIGHTS_REQUIRED _
Or _
PRINTER_ACCESS_ADMINISTER Or PRINTER_ACCESS_USE)

Private Declare Sub CopyMemory Lib "kernel32" Alias _
"RtlMoveMemory" _
(hpvDest As Any, hpvSource As Any, ByVal _
cbCopy As Long)

Private Declare Function OpenPrinter Lib "winspool.drv" Alias _
"OpenPrinterA" (ByVal pPrinterName As String, phPrinter As _
Long, pDefault As Any) As Long

Private Declare Function ClosePrinter Lib "winspool.drv" _
(ByVal hPrinter As Long) As Long

Private Declare Function DocumentProperties Lib "winspool.drv" _
Alias "DocumentPropertiesA" (ByVal hwnd As Long, ByVal hPrinter _
As Long, _
ByVal pDeviceName As String, pDevModeOutput As _
Any, _
pDevModeInput As Any, _
ByVal fMode As Long) As Long

Private Declare Function GetPrinter Lib "winspool.drv" _
Alias "GetPrinterA" (ByVal hPrinter As Long, ByVal Level As Long, _
pPrinter As Any, ByVal cbBuf As Long, pcbNeeded As Long) As _
Long

Private Declare Function SetPrinter Lib "winspool.drv" _
Alias "SetPrinterA" (ByVal hPrinter As Long, ByVal Level As Long, _
pPrinter As Any, ByVal Command As Long) As Long

'ÔÚ´òÓ¡»òÔ¤ÀÀ֮ǰֱ½Óµ÷ÓÃSetDefaultPrinterOrientation ´òÓ¡×ßÏò³£Êý.
'×¢Ò⣺ºìɫעÊͲ¿·ÖÓÃÓڸıäÖ½ÕŵĴóС¡£
Function SetDefaultPrinterOrientation(ByVal eOrientation As _
PrinterOrientationConstants, iDmpaper As Integer) As Boolean

Dim bDevMode() As Byte
Dim bPrinterInfo2() As Byte
Dim hPrinter As Long
Dim lResult As Long
Dim nSize As Long
Dim sPrnName As String
Dim dm As DEVMODE
Dim olddm As DEVMODE
Dim pd As PRINTER_DEFAULTS
Dim pi2 As PRINTER_INFO_2

' »ñȡĬÈÏ´òÓ¡»úµÄÉ豸Ãû³Æ
sPrnName = Printer.DeviceName
' ÓÉÓÚÒªµ÷ÓÃSetPrinter£¬ËùÒÔ
' Èç¹ûÊÇÔÚNTϾÍÒªÇóPRINTER_ALL_ACCESS
' pd.DesiredAccess = PRINTER_ALL_ACCESS'by zhc win2000

' »ñÈ¡´òÓ¡»ú¾ä±ú
If OpenPrinter(sPrnName, hPrinter, pd) Then

' »ñÈ¡PRINTER_INFO_2½á¹¹ÒªÇóµÄ×Ö½ÚÊý

Call GetPrinter(hPrinter, 2&, 0&, 0&, nSize)
ReDim bPrinterInfo2(1 To nSize) As Byte
lResult = GetPrinter(hPrinter, 2, bPrinterInfo2(1), nSize, nSize)
Call CopyMemory(pi2, bPrinterInfo2(1), Len(pi2))
nSize = DocumentProperties(0&, hPrinter, sPrnName, 0&, 0&, 0)
ReDim bDevMode(1 To nSize)
If pi2.pDevMode Then
Call CopyMemory(bDevMode(1), ByVal pi2.pDevMode, Len(dm))
Else
Call DocumentProperties(0&, hPrinter, sPrnName, bDevMode(1), 0&, DM_OUT_BUFFER)
End If

Call CopyMemory(dm, bDevMode(1), Len(dm))
Call CopyMemory(olddm, bDevMode(1), Len(olddm))
With dm
' ÉèÖÃеÄ×ßÏò
.dmOrientation = eOrientation
.dmFields = DM_ORIENTATION

.dmPaperSize = iDmpaper '½«Ö½ÕÅ´óСÉèΪiDmpaper£¬Çë×ÔÐиü¸ÄËùÐè´óС
' .dmFields = DM_PAPERSIZE '±ØÐ룬·ñÔòÎÞ·¨ÉèÖÃÖ½ÕÅ´óС

' .dmPaperLength = 3000 'iDmpaperLength
' .dmFields = DM_PAPERLENGTH '±ØÐ룬·ñÔòÎÞ·¨ÉèÖÃÖ½ÕÅ´ó
.dmPaperWidth = 3000 ' iDmpaperWidth
.dmFields = DM_PAPERSIZE ' DM_PAPERWIDTH '±ØÐ룬·ñÔòÎÞ·¨ÉèÖÃÖ½ÕÅ´ó

End With

Call CopyMemory(bDevMode(1), dm, Len(dm))

Call DocumentProperties(0&, hPrinter, sPrnName, _
bDevMode(1), bDevMode(1), DM_IN_BUFFER Or _
DM_OUT_BUFFER)

pi2.pDevMode = VarPtr(bDevMode(1))

lResult = SetPrinter(hPrinter, 2, pi2, 0&)

Call ClosePrinter(hPrinter)
SetDefaultPrinterOrientation = True
Else
SetDefaultPrinterOrientation = False
End If

End Function
gemgama 2003-08-19
  • 打赏
  • 举报
回复
设置系统默认打印机的纸张的大小,最好就设定为自定义的最大值
zy000 2003-08-19
  • 打赏
  • 举报
回复
我的计算机没有打印机是不是就没办法了
flyfalcon 2003-08-19
  • 打赏
  • 举报
回复
纵向打印改成横向打印

809

社区成员

发帖
与我相关
我的任务
社区描述
VB 多媒体
社区管理员
  • 多媒体
加入社区
  • 近7日
  • 近30日
  • 至今
社区公告
暂无公告

试试用AI创作助手写篇文章吧