如何在一个无标题的窗体上截获键盘输入的信息？

[qhdzh]

将窗体的
Form1.BorderStyle = 0时，如何获得键盘输入的信息，如按下了哪个键，包括Ctrl,Alt ,Shif。我用过窗体的KeyPress，可是不行。

[goodname008]

' 用KeyDown事件啊，不过先得把KeyPreview属性设成True

Option Explicit

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
Debug.Print KeyCode, Shift
End Sub

Private Sub Form_Load()
Me.KeyPreview = True
End Sub

[ufcr]

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)

Dim ShiftDown As Boolean
Dim AltDown As Boolean
Dim CtrlDown As Boolean
ShiftDown = (Shift And vbShiftMask) > 0
AltDown = (Shift And vbAltMask) > 0
CtrlDown = (Shift And vbCtrlMask) > 0


Select Case KeyCode
...
End Select
...

End Sub

[yunok]

我的代码：如下

'以下在Form
Private Sub Form_Load()
Call EnableKBDHook
End Sub

Private Sub Form_Unload(Cancel As Integer)
Call UnHookKBD
End Sub
－－－－－－－－－－－－－－
一下在模块中：
Option Explicit
Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" (ByVal idHook As Long, ByVal lpfn As Long, ByVal hmod As Long, ByVal dwThreadId As Long) As Long
Declare Function UnhookWindowsHookEx Lib "user32" (ByVal hHook As Long) As Long
Declare Function CallNextHookEx Lib "user32" (ByVal hHook As Long, ByVal ncode As Long, ByVal wParam As Long, lParam As Any) As Long

Public hnexthookproc As Long
Public Const HC_ACTION = 0
Public Const WH_KEYBOARD = 2

Public Sub UnHookKBD()
If hnexthookproc <> 0 Then
UnhookWindowsHookEx hnexthookproc
hnexthookproc = 0
End If
End Sub

Public Function MyKBHFunc(ByVal iCode As Long, _
ByVal wParam As Long, ByVal lParam As Long) As Long
'这3个参数是固定的，不能动，而MyKBHFunc这个名称只要和
'SetWindowsHookex()中 AddressOf後的名称一样便可，不一定叫什麽
'wParam 是传入按了哪个key的virtual-key code

'如果您将以下的两行unmark则所有键盘的输入皆没有作用
'MyKBHFunc = 1 '吃掉讯息
'Exit Function

MyKBHFunc = 0 '讯息要处理
If iCode < 0 Then
MyKBHFunc = CallNextHookEx(hnexthookproc, iCode, wParam, lParam)
Exit Function
End If
If wParam = vbKeySnapshot Then '侦测 有没有按到PrintScreen键
MyKBHFunc = 1 '在这个Hook便吃掉这个讯息
Debug.Print "haha"
Else
Call CallNextHookEx(hnexthookproc, iCode, wParam, lParam)
End If
End Function
Public Function EnableKBDHook()
If hnexthookproc <> 0 Then
Exit Function
End If
hnexthookproc = SetWindowsHookEx(WH_KEYBOARD, AddressOf _
MyKBHFunc, App.hInstance, 0)
If hnexthookproc <> 0 Then
EnableKBDHook = hnexthookproc
End If
End Function

'===========================================================

[hxy2003]

UP

[flc]

up

[射天狼]

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
'Ctrl , Alt, Shif
If Shift = 1 Then MsgBox "按下SHIFT", vbInformation
If Shift = 2 Then MsgBox "按下CTRL", vbInformation
If Shift = 4 Then MsgBox "按下ALT", vbInformation
End Sub

Private Sub Form_Load()
Me.KeyPreview = True
End Sub