高分题!有谁知道如何发送鼠标滚轮消息

[zhuyuzhao]

我想点击一个按扭然后触发鼠标上下滚轮消息 ,应该如何发送该消息!在线等......

[pigpag]

为什么要触发滚轮事件？是不是要滚动窗口？

[zhuyuzhao]

我只想知道发送什么消息可以得到和鼠标滚轮相同的作用

[佛的光辉]

WM_MOUSEWHEEL消息，该消息的值为0x020A

[yijiansong]

SendMessage（cmdOK_MouseMove(vbKeyMButton , 0, X , Y )）

[pigpag]

为什么大家都只用keybd_event？有mouse_event的！

[hxy1982]

up

[swpilogging]

vb.net里面这样就很简单

[zhuyuzhao]

楼上朋友你误解我的意思,我是说用sendmessage发一个什么消息可以取得和鼠标滚轮一样的作用

[chenkangli]

vbKeyMButton 4

[myhfit]

就发送WM_MOUSEWHEEL阿
发送一样的消息自然是一样的作用
不会的话自己拦截消息试一下啊
好像方向记得是wParam 一个正的一个负的

[ClassicWuHao]

MSDN上不是说得很清楚了嘛: 发送wm_mousewheel,wParam表示滚动的距离，+值表示向前滚动(即远离用户),-值表明向后滚动(即靠近用户)。lParam中的低位表示x轴的坐标,高位表示y轴的坐标，两者都是相对于屏幕的左上角而言.

[dsclub]

换成鼠标消息不就行了！！！

自己动手写一写嘛，别都指着别人………

[pigpag]

keybd_event会用吗？
mouse_event不一样的嘛！

[matchchen]

看看这篇文章，应该有帮助：

一、提出问题

自从1996年微软推出Intellimouse鼠标后，带滚轮的鼠标开始大行其道，支持鼠标滚轮的应用软件也越来越多。但我感到奇怪，为什么VB到6.0本身仍然不支持鼠标滚轮，VF可是从5.0就提供MouseWheel事件了。

如何让VB应用程序支持鼠标滚轮？MSDN上有一篇解决VB下应用Intellimouse鼠标的文章，它解决这一问题的方法是通过一个几十K的第三方控件实现的，可惜该控件没有源代码。况且为了支持鼠标滚轮使用一个第三方控件，好像有点得不偿失。本文给出用纯VB实现这一功能的方法。

二、解决问题

我们知道VB应用程序响应的Windows传来的消息，需要通过VB解释。可是很不幸，虽然VB解释所有得消息，却只让用户程序在事件中处理部分消息，VB自己处理其他的消息，或者忽略这些消息。

在VB5.0以前应用程序无法越过VB直接处理消息，微软从VB5.0开始提供AddressOf 运算符，该运算符可以让用户程序将函数或者过程的地址传递给一个API函数。这样我们就可以在VB应用程序中编写自己的窗口处理函数，通过AddressOf 运算符将在VB中定义的窗口地址传递给窗口处理函数，从而绕过VB的解释器，自己处理消息。事实上，该方法可用于在VB中处理任何消息。

实现应用程序支持鼠标滚轮的关键是，捕获鼠标滚轮的消息 MSH_MOUSEWHEEL、WM_MOUSEWHEEL。其中MSH_MOUSEWHEEL是为95准备的，需要Intellimouse驱动程序，而WM_MOUSEWHEEL是目前各版本Windows（98/NT40/2000）内置的消息。本文主要处理WM_MOUSEWHEEL消息。下面是WM_MOUSEWHEEL的语法。

WM_MOUSEWHEEL
fwKeys = LOWORD(wParam); /* key flags */
zDelta = (short) HIWORD(wParam);
/* wheel rotation */
xPos = (short) LOWORD(lParam);
/* horizontal position of pointer */
yPos = (short) HIWORD(lParam);
/* vertical position of pointer */

其中：fwKeys指出是否有CTRL、SHIFT、鼠标键(左、中、右、附加)按下，允许复合。zDelta传递滚轮滚动的快慢，该值小于零表示滚轮向后滚动（朝用户方向），大于零表示滚轮向前滚动（朝显示器方向）。lParam指出鼠标指针相对屏幕左上的x、y轴坐标。
滚轮按钮相当于普通的三键鼠标的中键，根据滚轮按钮的动作，Windows分别发出WM_MBUTTONUP、WM_MBUTTONDOWN、WM_MBUTTONDBLCLK消息，这些消息VB已经在鼠标事件中支持。

三、实际应用

根据上述原理，给出一个数据库应用的典型例子。

1.户界面如图1所示。该例是班级和学生一对多的查询，当用户在学生网格以外滚动鼠标滚轮，班级主表前后移动；用户在网格以内滚动鼠标学生明细表垂直移动；如果在网格以内按住鼠标滚轮键并且滚动鼠标，学生明细表水平移动。


2.FORM1上ADO Data 控件对象datPrimaryRS的 ConnectionString为"PROVIDER=MSDataShape;Data PROVIDER=MSDASQL;dsn=SCHOOL;uid=;pwd=;"， RecordSelectors 属性的SQL命令文本为"SHAPE {select * from 班级} AS ParentCMD APPEND ({select * from 学生 } AS ChildCMD RELATE 班级名称 TO 班级名称) AS ChildCMD"。

3.TextBox的DataSource均为datPrimaryRS,DataFiled如图所示。

4.窗口下部的网格是DataGrid控件,名称为grdDataGrid。

5.表单From1.frm的清单如下：

Private Sub FORM_Load()
Set grdDataGrid.DataSource = _
datPrimaryRS.Recordset("ChildCMD").Underlyingvalue
Hook Me.hWnd
End Sub

Private Sub FORM_Unload(Cancel As Integer)
UnHook Me.hWnd
End Sub

---- 6.标准模块Module1.bas清单如下：
Option Explicit
Public Type POINTL
x As Long
y As Long
End Type
Declare Function CallWindowProc _
Lib "USER32" Alias "CallWindowProcA" _
(ByVal lpPrevWndFunc As Long, _
ByVal hWnd As Long, _
ByVal Msg As Long, _
ByVal wParam As Long, _
ByVal lParam As Long) As Long

Declare Function SetWindowLong _
Lib "USER32" Alias "SetWindowLongA" _
(ByVal hWnd As Long, _
ByVal nIndex As Long, _
ByVal dwNewLong As Long) As Long

Declare Function SystemParametersInfo _
Lib "USER32" Alias "SystemParametersInfoA" _
(ByVal uAction As Long, _
ByVal uParam As Long, _
lpvParam As Any, _
ByVal fuWinIni As Long) As Long

Declare Function ScreenToClient Lib "USER32" _
(ByVal hWnd As Long, xyPoint As POINTL) As Long

Public Const GWL_WNDPROC = -4
Public Const SPI_GETWHEELSCROLLLINES = 104
Public Const WM_MOUSEWHEEL = &H20A
Public WHEEL_SCROLL_LINES As Long

Global lpPrevWndProc As Long

Public Sub Hook(ByVal hWnd As Long)
lpPrevWndProc = SetWindowLong(hWnd, GWL_WNDPROC, _
AddressOf WindowProc)
'获取"控制面板"中的滚动行数值
Call SystemParametersInfo(SPI_GETWHEELSCROLLLINES, _
0, WHEEL_SCROLL_LINES, 0)
If WHEEL_SCROLL_LINES > FORM1.grdDataGrid.VisibleRows Then
WHEEL_SCROLL_LINES = FORM1.grdDataGrid.VisibleRows
End If
End Sub

Public Sub UnHook(ByVal hWnd As Long)
Dim lngReturnvalue As Long
lngReturnvalue = SetWindowLong(hWnd,
GWL_WNDPROC, lpPrevWndProc)
End Sub

Function WindowProc(ByVal hw As Long, _
ByVal uMsg As Long, _
ByVal wParam As Long, _
ByVal lParam As Long) As Long
Dim pt As POINTL
Select Case uMsg
Case WM_MOUSEWHEEL
Dim wzDelta, wKeys As Integer
wzDelta = HIWORD(wParam)
wKeys = LOWORD(wParam)
pt.x = LOWORD(lParam)
pt.y = HIWORD(lParam)
'将屏幕坐标转换为FORM1.窗口坐标
ScreenToClient FORM1.hWnd, pt
With FORM1.grdDataGrid

'判断坐标是否在FORM1.grdDataGrid窗口内
If pt.x > .Left / Screen.TwipsPerPixelX And _
pt.x < (.Left + .Width) / Screen.TwipsPerPixelX And _
pt.y > .Top / Screen.TwipsPerPixelY And _
pt.y < (.Top + .Height) / Screen.TwipsPerPixelY Then
'滚动明细数据库
If wKeys = 16 Then
'滚动键按下，水平滚动grdDataGrid
If Sgn(wzDelta) = 1 Then
FORM1.grdDataGrid.Scroll -1, 0
Else
FORM1.grdDataGrid.Scroll 1, 0
End If
Else
'垂直滚动grdDataGrid
If Sgn(wzDelta) = 1 Then
FORM1.grdDataGrid.Scroll 0, 0 - WHEEL_SCROLL_LINES
Else
FORM1.grdDataGrid.Scroll 0, WHEEL_SCROLL_LINES
End If
End If
Else
'鼠标不在grdDataGrid区域，滚动主数据库
With FORM1.datPrimaryRS.Recordset
If Sgn(wzDelta) = 1 Then
If .BOF = False Then
.MovePrevious
If .BOF = True Then
.MoveFirst
End If
End If
Else
If .EOF = False Then
.MoveNext
If .EOF = True Then
.MoveLast
End If
End If
End If
End With
End If
End With
Case Else
WindowProc = CallWindowProc(lpPrevWndProc, hw, _
uMsg, wParam, lParam)
End Select
End Function

Public Function HIWORD(LongIn As Long) As Integer
' 取出32位值的高16位
HIWORD = (LongIn And &HFFFF0000) \ &H10000
End Function

Public Function LOWORD(LongIn As Long) As Integer
' 取出32位值的低16位
LOWORD = LongIn And &HFFFF&
End Function

7.该例在未安装任何附加鼠标驱动程序的Win2000/98环境，采用联想网络鼠标/罗技银貂，VB6.0下均通过。
需要进一步说明的是,对用户界面鼠标滚轮的操作也要遵循公共用户界面操作习惯，不要随意定义一些怪异的操作，如果你编制的应用程序支持鼠标滚轮，请看看是否符合下面这些标准。

垂直滚动：当用户向后滚动轮子（朝用户方向），滚动条向下移动；向前滚动轮子（朝显示器方向），滚动条向上移动。对文档当前的选择应该不受影响，对数据库当前记录指针不变。

水平滚动：如果同时有垂直滚动条，鼠标滚轮首先应控制上下滚动；当文档只有水平滚动杠时，用户向后滚动轮子，滚动条向右移动，向前滚动轮子，滚动条向左移动。对文档当前的选择应该不受影响，对数据库字段选择不受影响。

滚动速度：鼠标滚轮每滚一个刻痕，对于长文档移动的行数，应符合控制面板中鼠标的定义（默认移动三行），对短文档每次滚一行，在任何情况下，决不要超过窗口显示的行数。

平移：平移事实上就是滚动条的连续操作。平移一般是配合滚轮按钮的拖拽，最好提供方向指示光标。

自动滚动：自动滚动通常开始于鼠标滚轮按钮单击，以后任何击键、鼠标按键或者滚动鼠标滚轮终止。滚动方向和速度取决于鼠标偏移滚轮按钮单击时原始位置的方向和距离，距原始位置标记越远自动滚动越快，距离近则慢。应用程序需要提供初始位置位图以及方向指示图标。

缩放：在按住 Ctrl 键的同时前后滚动滚轮。向后滚动轮子（朝用户方向），缩小比例；向前滚动轮子（朝显示器方向），增大比例。

四、结束语

通过前面的介绍，你会发现编制"直接"支持鼠标滚轮软件，需要增加不少工作量。但对软件的易用性有显著的提高，笔者认为这一点付出是值得的。当然你也可以通过使用专门的鼠标功能增强软件来实现部分鼠标滚轮功能。最后需要注意的是，并不是每个用户都有滚轮鼠标，软件的鼠标滚轮上功能，要让用户通过其他的操作也可以实现。

[zhuyuzhao]

大家取一个用sendMessage发送消息的例子看看好吗?

[dsclub]

'This project needs a ListBox, named List1 and a TextBox, named Text1
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Integer, ByVal lParam As Any) As Long
Const LB_FINDSTRING = &H18F
Private Sub Form_Load()
'KPD-Team 1998
'URL: http://www.allapi.net/
'E-Mail: [e-mail]
'Add some items to the listbox
With List1
.AddItem "Computer"
.AddItem "Screen"
.AddItem "Modem"
.AddItem "Printer"
.AddItem "Scanner"
.AddItem "Sound Blaster"
.AddItem "Keyboard"
.AddItem "CD-Rom"
.AddItem "Mouse"
End With
End Sub
Private Sub Text1_Change()
'Retrieve the item's listindex
List1.ListIndex = SendMessage(List1.hwnd, LB_FINDSTRING, -1, ByVal CStr(Text1.Text))
End Sub

[xwzxwz]

学习。。。

[pigpag]

这个不就是子类吗？

[jintianatxd]

学习ing

[Gelim]

学习！