我的程序要的A3横向的纸，而这个打印机经他们共享后要打A4的纸，这怎么解决？

[cnlipeng]

不可能我程序要打印时，就去调打印机属性吧！

[cnlipeng]

这么复杂啊！我可用不来。我现在把打印机默认设为　A3　横向，好像也解决了，他们打A4纸时，自已放A4纸就行了！

[lihonggen0]

Option Explicit

Public Enum PrinterOrientationConstants
OrientPortrait = 1
OrientLandscape = 2
End Enum

Private Type DEVMODE
dmDeviceName As String * 32
dmSpecVersion As Integer
dmDriverVersion As Integer
dmSize As Integer
dmDriverExtra As Integer
dmFields As Long
dmOrientation As Integer
dmPaperSize As Integer
dmPaperLength As Integer
dmPaperWidth As Integer
dmScale As Integer
dmCopies As Integer
dmDefaultSource As Integer
dmPrintQuality As Integer
dmColor As Integer
dmDuplex As Integer
dmYResolution As Integer
dmTTOption As Integer
dmCollate As Integer
dmFormName As String * 32
dmUnusedPadding As Integer
dmBitsPerPel As Integer
dmPelsWidth As Long
dmPelsHeight As Long
dmDisplayFlags As Long
dmDisplayFrequency As Long
End Type

Private Type PRINTER_DEFAULTS
pDatatype As String
pDevMode As Long
DesiredAccess As Long
End Type

Private Type PRINTER_INFO_2
pServerName As Long
pPrinterName As Long
pShareName As Long
pPortName As Long
pDriverName As Long
pComment As Long
pLocation As Long
pDevMode As Long
pSepFile As Long
pPrintProcessor As Long
pDatatype As Long
pParameters As Long
pSecurityDescriptor As Long
Attributes As Long
Priority As Long
DefaultPriority As Long
StartTime As Long
UntilTime As Long
Status As Long
cJobs As Long
AveragePPM As Long
End Type

'*******************'
' iDmpaper值 纸张 '
' 8 A3 '
' 9 A4 '
' 11 A5 '
' 13 B5 '
'*******************'

Private Const DM_IN_BUFFER As Long = 8
Private Const DM_OUT_BUFFER As Long = 2
Private Const DM_ORIENTATION As Long = &H1
Private Const DM_PAPERSIZE = &H2&

Private Const PRINTER_ACCESS_ADMINISTER As Long = &H4
Private Const PRINTER_ACCESS_USE As Long = &H8
Private Const STANDARD_RIGHTS_REQUIRED As Long = &HF0000
Private Const PRINTER_ALL_ACCESS = (STANDARD_RIGHTS_REQUIRED _
Or _
PRINTER_ACCESS_ADMINISTER Or PRINTER_ACCESS_USE)

Private Declare Sub CopyMemory Lib "kernel32" Alias _
"RtlMoveMemory" _
(hpvDest As Any, hpvSource As Any, ByVal _
cbCopy As Long)

Private Declare Function OpenPrinter Lib "winspool.drv" Alias _
"OpenPrinterA" (ByVal pPrinterName As String, phPrinter As _
Long, pDefault As Any) As Long

Private Declare Function ClosePrinter Lib "winspool.drv" _
(ByVal hPrinter As Long) As Long

Private Declare Function DocumentProperties Lib "winspool.drv" _
Alias "DocumentPropertiesA" (ByVal hWnd As Long, ByVal hPrinter _
As Long, _
ByVal pDeviceName As String, pDevModeOutput As _
Any, _
pDevModeInput As Any, _
ByVal fMode As Long) As Long

Private Declare Function GetPrinter Lib "winspool.drv" _
Alias "GetPrinterA" (ByVal hPrinter As Long, ByVal Level As Long, _
pPrinter As Any, ByVal cbBuf As Long, pcbNeeded As Long) As _
Long

Private Declare Function SetPrinter Lib "winspool.drv" _
Alias "SetPrinterA" (ByVal hPrinter As Long, ByVal Level As Long, _
pPrinter As Any, ByVal Command As Long) As Long

'在打印或预览之前直接调用SetDefaultPrinterOrientation 打印走向常数。注意：红色注释部分用于改变纸张的大小。
Function SetDefaultPrinterOrientation(ByVal eOrientation As _
PrinterOrientationConstants, iDmpaper As Integer) As Boolean

Dim bDevMode() As Byte
Dim bPrinterInfo2() As Byte
Dim hPrinter As Long
Dim lResult As Long
Dim nSize As Long
Dim sPrnName As String
Dim dm As DEVMODE
Dim olddm As DEVMODE
Dim pd As PRINTER_DEFAULTS
Dim pi2 As PRINTER_INFO_2

' 获取默认打印机的设备名称
sPrnName = Printer.DeviceName
' 由于要调用SetPrinter，所以
' 如果是在NT下就要求PRINTER_ALL_ACCESS
pd.DesiredAccess = PRINTER_ALL_ACCESS

' 获取打印机句柄
If OpenPrinter(sPrnName, hPrinter, pd) Then

' 获取PRINTER_INFO_2结构要求的字节数

Call GetPrinter(hPrinter, 2&, 0&, 0&, nSize)
ReDim bPrinterInfo2(1 To nSize) As Byte
lResult = GetPrinter(hPrinter, 2, bPrinterInfo2(1), nSize, nSize)
Call CopyMemory(pi2, bPrinterInfo2(1), Len(pi2))
nSize = DocumentProperties(0&, hPrinter, sPrnName, 0&, 0&, 0)
ReDim bDevMode(1 To nSize)
If pi2.pDevMode Then
Call CopyMemory(bDevMode(1), ByVal pi2.pDevMode, Len(dm))
Else
Call DocumentProperties(0&, hPrinter, sPrnName, bDevMode(1), 0&, DM_OUT_BUFFER)
End If

Call CopyMemory(dm, bDevMode(1), Len(dm))
Call CopyMemory(olddm, bDevMode(1), Len(olddm))
With dm
' 设置新的走向
.dmOrientation = eOrientation
.dmFields = DM_ORIENTATION
.dmPaperSize = iDmpaper '将纸张大小设为iDmpaper，请自行更改所需大小
' .dmPaperLength = iDmpaperLength
' .dmPaperWidth = iDmpaperWidth
.dmFields = DM_PAPERSIZE '必须，否则无法设置纸张大小
End With

Call CopyMemory(bDevMode(1), dm, Len(dm))

Call DocumentProperties(0&, hPrinter, sPrnName, _
bDevMode(1), bDevMode(1), DM_IN_BUFFER Or _
DM_OUT_BUFFER)

pi2.pDevMode = VarPtr(bDevMode(1))

lResult = SetPrinter(hPrinter, 2, pi2, 0&)

Call ClosePrinter(hPrinter)
SetDefaultPrinterOrientation = True
Else
SetDefaultPrinterOrientation = False
End If

End Function

[lihonggen0]

PaperSize 属性


返回或设置一个值，该值指出当前打印机的纸张大小。在设计时是不可用。

语法

object.PaperSize [= value]

PaperSize 属性的语法包含下面部分：

部分 描述
Object 对象表达式，其值是“应用于”列表中的一个对象。
Value 一个用来指定纸张大小的值或常数，“设置值”中有详细描述。


设置值

value 的设置值是：

常数 值 描述
VbPRPSLetter 1 信笺， 8 1/2 x 11 英寸。
VbPRPSLetterSmall 2 +A611 小型信笺， 8 1/2 x 11 英寸。
VbPRPSTabloid 3 小型报， 11 x 17 英寸。
VbPRPSLedger 4 分类帐， 17 x 11 英寸。
VbPRPSLegal 5 法律文件， 8 1/2 x 14 英寸。
VbPRPSStatement 6 声明书，5 1/2 x 8 1/2 英寸。
VbPRPSExecutive 7 行政文件，7 1/2 x 10 1/2 英寸。
VbPRPSA3 8 A3, 297 x 420 毫米
VbPRPSA4 9 A4, 210 x 297 毫米
VbPRPSA4Small 10 A4小号， 210 x 297 毫米
VbPRPSA5 11 A5, 148 x 210 毫米
VbPRPSB4 12 B4, 250 x 354 毫米
VbPRPSB5 13 B5, 182 x 257 毫米
VbPRPSFolio 14 对开本， 8 1/2 x 13 英寸。
VbPRPSQuarto 15 四开本， 215 x 275 毫米。
VbPRPS10x14 16 10 x 14 英寸。
VbPRPS11x17 17 11 x 17 英寸。
VbPRPSNote 18 便条，8 1/2 x 11 英寸。
VbPRPSEnv9 19 #9 信封， 3 7/8 x 8 7/8 英寸。
VbPRPSEnv10 20 #10 信封， 4 1/8 x 9 1/2 英寸。
VbPRPSEnv11 21 #11 信封， 4 1/2 x 10 3/8 英寸。
VbPRPSEnv12 22 #12 信封， 4 1/2 x 11 英寸。
VbPRPSEnv14 23 #14 信封， 5 x 11 1/2 英寸。
VbPRPSCSheet 24 C 尺寸工作单
VbPRPSDSheet 25 D 尺寸工作单
VbPRPSESheet 26 E 尺寸工作单
VbPRPSEnvDL 27 DL 型信封， 110 x 220 毫米
VbPRPSEnvC3 29 C3 型信封， 324 x 458 毫米
VbPRPSEnvC4 30 C4 型信封， 229 x 324 毫米
VbPRPSEnvC5 28 C5 型信封， 162 x 229 毫米
VbPRPSEnvC6 31 C6 型信封， 114 x 162 毫米
VbPRPSEnvC65 32 C65 型信封，114 x 229 毫米
VbPRPSEnvB4 33 B4 型信封， 250 x 353 毫米
VbPRPSEnvB5 34 B5 型信封，176 x 250 毫米
VbPRPSEnvB6 35 B6 型信封， 176 x 125 毫米
VbPRPSEnvItaly 36 信封， 110 x 230 毫米
VbPRPSEnvMonarch 37 信封大王， 3 7/8 x 7 1/2 英寸。
VbPRPSEnvPersonal 38 信封， 3 5/8 x 6 1/2 英寸。
VbPRPSFanfoldUS 39 U.S. 标准复写簿， 14 7/8 x 11 英寸。
VbPRPSFanfoldStdGerman 40 德国标准复写簿， 8 1/2 x 12 英寸。
VbPRPSFanfoldLglGerman 41 德国法律复写簿， 8 1/2 x 13 英寸。
VbPRPSUser 256 用户定义


说明

这些常数在 Visual Basic (VB) 中的对象浏览器中的对象库中列出。

打印机 Height 和 Width 属性的设置自动地将 PaperSize 设置为 vbPRPSUser。

注意 Printer 对象此属性的效果依赖于打印机厂家提供的驱动程序。某些属性设置值可能不起作用，或者一些不同的属性设置值可能有相同的效果。接受范围之外的设置值可能产生也可能不产生错误。详细信息，请参阅厂家具体驱动程序的文档。