查询合并记录

[lxllamy]

PMember表(Member_ID)
PAssin表(Assin_ID,Assin_Name)
PMember_Assin(Member_ID,Assin_ID)

纪录：
PMember
纪录1 123
PAssin
Assin_ID Assin_Name
纪录1 123 自行车
纪录1 456 计算机
PMember_Assin

Member_ID Assin_ID
123 123
123 456

查询语句

select a.Member_Id,c.Assin_Name from PMember a,PMember_assin b,PAssin c where a.Member_ID=b.Member_Id and c.assin_ID=b.assin_ID and a.member_ID='123'

得到两条记录
Member_ID Assin_Name
123 自行车
123 计算机
我想得到的是
Member_ID Assin_Name1 Assin_Name2
123 自行车 计算机

请问怎么写才可以？谢谢！

[lxllamy]

谢谢各位，第一次用这种sql语句，我觉得似乎仅仅对单个Member_ID可以，如去掉Member_ID=123就有问题.如果我要把这三个表中的纪录变成一个视图
似乎用这种对多个Member_ID还是不行，能帮忙想想办法吗？

[hjb111]

交叉数据报表
有时候需要旋转结果以便在水平方向显示列，而在垂直方向显示行。这就是所谓的创建 PivotTable®、创建交叉数据报表或旋转数据。

假定有一个表 Pivot，其中每季度占一行。对 Pivot 的 SELECT 操作在垂直方向上列出这些季度：

Year Quarter Amount
---- ------- ------
1990 1 1.1
1990 2 1.2
1990 3 1.3
1990 4 1.4
1991 1 2.1
1991 2 2.2
1991 3 2.3
1991 4 2.4

生成报表的表必须是这样的，其中每年占一行，每个季度的数值显示在一个单独的列中，如：

Year
Q1
Q2
Q3
Q4

1990
1.1
1.2
1.3
1.4

1991
2.1
2.2
2.3
2.4



下面的语句用于创建 Pivot 表并在其中填入第一个表中的数据：

USE Northwind
GO

CREATE TABLE Pivot
( Year SMALLINT,
Quarter TINYINT,
Amount DECIMAL(2,1) )
GO
INSERT INTO Pivot VALUES (1990, 1, 1.1)
INSERT INTO Pivot VALUES (1990, 2, 1.2)
INSERT INTO Pivot VALUES (1990, 3, 1.3)
INSERT INTO Pivot VALUES (1990, 4, 1.4)
INSERT INTO Pivot VALUES (1991, 1, 2.1)
INSERT INTO Pivot VALUES (1991, 2, 2.2)
INSERT INTO Pivot VALUES (1991, 3, 2.3)
INSERT INTO Pivot VALUES (1991, 4, 2.4)
GO

下面是用于创建旋转结果的 SELECT 语句：

SELECT Year,
SUM(CASE Quarter WHEN 1 THEN Amount ELSE 0 END) AS Q1,
SUM(CASE Quarter WHEN 2 THEN Amount ELSE 0 END) AS Q2,
SUM(CASE Quarter WHEN 3 THEN Amount ELSE 0 END) AS Q3,
SUM(CASE Quarter WHEN 4 THEN Amount ELSE 0 END) AS Q4
FROM Northwind.dbo.Pivot
GROUP BY Year
GO

该 SELECT 语句还处理其中每个季度占多行的表。GROUP BY 语句将 Pivot 中一年的所有行合并成一行输出。当执行分组操作时，SUM 聚合中的 CASE 函数的应用方式是这样的：将每季度的 Amount 值添加到结果集的适当列中，在其它季度的结果集列中添加 0。

如果该 SELECT 语句的结果用作电子表格的输入，那么电子表格将很容易计算每年的合计。当从应用程序使用 SELECT 时，可能更易于增强 SELECT 语句来计算每年的合计。例如：

SELECT P1.*, (P1.Q1 + P1.Q2 + P1.Q3 + P1.Q4) AS YearTotal
FROM (SELECT Year,
SUM(CASE P.Quarter WHEN 1 THEN P.Amount ELSE 0 END) AS Q1,
SUM(CASE P.Quarter WHEN 2 THEN P.Amount ELSE 0 END) AS Q2,
SUM(CASE P.Quarter WHEN 3 THEN P.Amount ELSE 0 END) AS Q3,
SUM(CASE P.Quarter WHEN 4 THEN P.Amount ELSE 0 END) AS Q4
FROM Pivot AS P
GROUP BY P.Year) AS P1
GO

带有 CUBE 的 GROUP BY 和带有 ROLLUP 的 GROUP BY 都计算与本例显示相同的信息种类，但格式稍有不同。

[CrazyFor]

select a.Member_Id,c.Assin_Name into #t from PMember a,PMember_assin b,PAssin c where a.Member_ID=b.Member_Id and c.assin_ID=b.assin_ID and a.member_ID='123'
select * from #t

再参照下面的方法,把表#t横过来.
参考:
create table #(a varchar(100),b int)
insert # values('aa',11)
insert # values('bb',1)
insert # values('aa',45)
insert # values('cc',81)
insert # values('a',11)
insert # values('aay',561)
insert # values('a',14)

declare @sql varchar(8000)
set @sql = 'select '
select @sql = @sql + 'sum(case a when '''+a+'''
then b else 0 end) '+a+'的数量,'
from (select distinct a from #) as a

select @sql = left(@sql,len(@sql)-1) + ' from #'

exec(@sql)

drop table #

[dlkfth]

例子 dsql_bm 药房表，dsql_sale 销售表 关系是药房表.id=销售表.parent

declare @sql varchar(8000)

set @sql='select zyh ,'

select @sql=@sql+'isnull(sum(case when parent='+cast(id as varchar(10)) + ' then je end ),0) as '+bmmc+' ,' from dsql_bm order by id

set @sql=left(@sql,len(@sql) - 1)

set @sql=@sql + ' from dsql_sale group by zyh'
print @sql
exec (@sql)


结果如下
1001 2 10 0
1002 0 3 8

[flying120]

up hjb111(东方不败猪八戒)(西方失败唐老鸭) 你需要新建临时表，插入数据再显示

[Zengqf_W]

create table PMember(id_num int IDENTITY(1,1),Member_ID int)
insert into PMember values(123)
insert into PMember values(124)

create table PAssin(id int IDentity(1,1), Assin_ID int,Assin_Name varchar(50))
Insert Into PAssin Values (1,'自行车')
Insert Into PAssin Values (2,'计算机')
Insert Into PAssin Values (3,'汽车')
Insert Into PAssin Values (4,'电话')

create table PMember_Assin(Member_ID int ,Assin_ID int)
insert into PMember_Assin values(123,1)
insert into PMember_Assin values(123,2)
insert into PMember_Assin values(123,3)
insert into PMember_Assin values(124,1)
insert into PMember_Assin values(123,4)

declare @s varchar(8000)
set @s = 'Select '

select @s = @s + ''''+Assin_Name +''','
from PMember,PAssin,PMember_Assin
Where PMember.Member_ID = PMember_Assin.Member_ID
and PAssin.Assin_ID = PMember_Assin.Assin_ID
and PMember.Member_ID = 123


Select @s = @s + ' PMember.Member_ID from PMember,PAssin,PMember_Assin
Where PMember.Member_ID = PMember_Assin.Member_ID
and PAssin.Assin_ID = PMember_Assin.Assin_ID
and PMember.Member_ID = 123
group by PMember.Member_ID'

exec(@s)

drop table PMember
drop table PAssin
drop table PMember_Assin