动太添加菜单

[bg5jb]

我要编写一个工程
需要在程序中动态地加载菜单，
请问有什么办法可以实现？？？？
谢谢！！！

[道素]

Const MF_CHECKED = &H8&
Const MF_APPEND = &H100&
Const TPM_LEFTALIGN = &H0&
Const MF_DISABLED = &H2&
Const MF_GRAYED = &H1&
Const MF_SEPARATOR = &H800&
Const MF_STRING = &H0&
Private Type POINTAPI
x As Long
y As Long
End Type
Private Declare Function CreatePopupMenu Lib "user32" () As Long
Private Declare Function TrackPopupMenu Lib "user32" (ByVal hMenu As Long, ByVal wFlags As Long, ByVal x As Long, ByVal y As Long, ByVal nReserved As Long, ByVal hwnd As Long, ByVal lprc As Any) As Long
Private Declare Function GetSystemMenu Lib "user32" (ByVal hwnd As Long, ByVal bRevert As Long) As Long
Private Declare Function AppendMenu Lib "user32" Alias "AppendMenuA" (ByVal hMenu As Long, ByVal wFlags As Long, ByVal wIDNewItem As Long, ByVal lpNewItem As Any) As Long
Private Declare Function DestroyMenu Lib "user32" (ByVal hMenu As Long) As Long
Private Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
Dim hMenu As Long
Private Sub Form_Load()
'Create an empty popupmenu
hMenu = CreatePopupMenu()
'Append a few menu items
AppendMenu hMenu, MF_STRING, ByVal 0&, "Hello !"
AppendMenu hMenu, MF_GRAYED Or MF_DISABLED, ByVal 0&, "Testing ..."
AppendMenu hMenu, MF_SEPARATOR, ByVal 0&, ByVal 0&
AppendMenu hMenu, MF_CHECKED, ByVal 0&, "TrackPopupMenu"
End Sub
Private Sub Form_MouseUp(Button As Integer, Shift As Integer, x As Single, y As Single)
Dim Pt As POINTAPI
'Get the position of the mouse cursor
GetCursorPos Pt
If Button = 1 Then
'Show our popupmenu
TrackPopupMenu hMenu, TPM_LEFTALIGN, Pt.x, Pt.y, 0, Me.hwnd, ByVal 0&
Else
'Show our form's default popup menu
TrackPopupMenu GetSystemMenu(Me.hwnd, False), TPM_LEFTALIGN, Pt.x, Pt.y, 0, Me.hwnd, ByVal 0&
End If
End Sub
Private Sub Form_Unload(Cancel As Integer)
'Destroy our menu
DestroyMenu hMenu
End Sub

[射天狼]

支持楼上~~~

[lihonggen0]

http://vb1.myrice.com/article/other/other015.htm

[lihonggen0]

利用INI文件给程序创建动态菜单

　　
　　象Word那样，在“文件”菜单中可以找到我们最近打开或编辑过的文件。这是程序在运行时创建了动态菜单的缘故。VB程序实现此功能有很多文章探讨过，但大都着眼于Windows的注册表。我们的注册表早已发福了，有没有办法不让她再增加负担？
　　用INI文件！INI文件是系统、应用程序的配置文件。它可以使得我们的VB程序更具灵活性，充分地利用它自然也能够实现动态菜单的创建。下面给个例子。
　　
　　首先，我们得给程序添加一个模块，在模块中申明读写INI用的两个Windows API函数，并在其中封装自定义的读取、写入INI的函数：
　　
　　Option Explicit
　　
　　'读写INI的API函數
　　Public Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long
　　Public Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any,
　　ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
　　
　　'自定义写入INI函數
　　Public Function WriteIni(ByVal section As String, ByVal key As String, ByVal value As String) As Boolean
　　Dim x As Long, Buff As String * 128, I As Integer
　　Buff = value + Chr(0)
　　x = WritePrivateProfileString(section, key, Buff, App.Path + "\MenuSetting.ini")
　　WriteIni = x
　　End Function
　　
　　'自定义读取INI函數
　　Public Function ReadIni(ByVal section As String, ByVal key As String) As String
　　Dim x As Long, Buff As String * 128, I As Integer
　　x = GetPrivateProfileString(section, key, "", Buff, 128, App.Path + "\MenuSetting.ini")
　　I = InStr(Buff, Chr(0))
　　ReadIni = Trim(Left(Buff, I - 1))
　　End Function
　　
　　接着，回到主窗体，给主窗体添加若干控件、编辑菜单(控件和菜单名称详见代码)，其中，“文件”菜单的动态菜单要用数组，其Index号可以从1开始，注意将这些动态菜单设为不可见。本例可保存最近打开的三个文件，如需要多一些可自行添加。以下是主窗体代码：
　　
　　Option Explicit
　　'声明用于判断写入INI中的FileName(n)中的n变量
　　Dim I As String '为了能添在FileName串的后面，声明为String
　　
　　Private Sub Form_Load()
　　I = 0 '初值
　　Text1.Left = 0
　　Text1.Top = 0
　　Text1 = ""
　　Text1.FontSize = 12
　　Me.Caption = "txtEditor"
　　Me.Width = 8000
　　Me.Height = 6000
　　AddMenu '添加动态菜单
　　End Sub
　　
　　Private Sub Form_Resize() '这个没什么可说，为了使例程完整而已
　　Text1.Width = Me.ScaleWidth
　　Text1.Height = Me.ScaleHeight
　　End Sub
　　
　　Private Sub mnuExit_Click()
　　End '退出
　　End Sub
　　
　　'打开文件
　　Private Sub mnuOpen_Click()
　　Dim sF As String
　　CommonDialog1.Filter = "文档文件(*.txt)|*.txt|所有文件(*.*)|*.*"
　　CommonDialog1.ShowOpen
　　Open CommonDialog1.FileName For Input As #1
　　Text1.Text = StrConv(InputB$(LOF(1), 1), vbUnicode)
　　Close #1
　　If I > = 3 Then I = 0 '如大于等于3则返回原值
　　I = I + 1
　　sF = "FileName" + I
　　'打开后写进INI文件
　　CommonDialog1.FileName = WriteIni("Open", sF, CommonDialog1.FileName)
　　AddMenu '立即添加使动态菜单生效
　　End Sub
　　
　　'添加菜单
　　Private Sub AddMenu()
　　Dim fN1 As String, fN2 As String, fN3 As String
　　'從INI文件中读取数据
　　fN1 = ReadIni("Open", "FileName1")
　　fN2 = ReadIni("Open", "FilEName2")
　　fN3 = ReadIni("Open", "FileName3")
　　'如数据存在则令动态菜单可见并给其Caption属性赋值
　　If fN3 < > "" Then mnuSep02.Visible = True: mnuAdd(1).Visible = True: mnuAdd(1).Caption = fN1
　　If fN2 < > "" Then mnuSep02.Visible = True: mnuAdd(2).Visible = True: mnuAdd(2).Caption = fN2
　　If fN1 < > "" Then mnuSep02.Visible = True: mnuAdd(3).Visible = True: mnuAdd(3).Caption = fN3
　　End Sub
　　
　　本例子演示了利用INI文件实现动态菜单的创建，若需要移植到你的程序中，应作相应的改动，使其更具合理性和实用性。有什么看法欢迎大家与我交流！

[lilaclone]

给你贴个例子
添加记录到文档菜单

最近用过的文件会自动出现在文档菜单中，只要用很少的代码，在你的程序中也可实现这样的功能：
声明：
Public Const SHARD_PATH = &H2&
Public Declare Function SHAddToRecentDocs Lib "shell32.dll" (ByVal dwFlags As Long, ByVal dwData As String) As Long
函数：
Public Sub AddRecent(strFile As String)
Dim lRetVal As Long
If strFile = "" Then
lRetVal = SHAddToRecentDocs(SHARD_PATH, vbNullString)
Else
lRetVal = SHAddToRecentDocs(SHARD_PATH, strFile)
End If
End Sub
例子：
AddRecent "C:myfile.txt"
AddRecent "" '清除文档菜单

[lilaclone]

菜单项的动态装入
菜单项的动态装入是指菜单项的个数不固定. 例子就是文件菜单中最近打开的
文件的列表。在第一次打开文件之前,该列表是空的,并且不在文件菜单中出现;打
开一个文件后,该列表不再是空的,并且文件菜单中出现代表被打开文件的菜单项。
具体的实现过程如下:
在文件菜单里增加一个菜单项,标题任意,并假设菜单项的Name属性是
opened_files_ list;
更改菜单项opened_files_list的可见属性,使 opened_files_list.Visible=
False
更改菜单项opened_files_list的下标属性,使 opened_files_list.Index=0
在程序中控制菜单项opened_files_list的动态装入。
假设要显示打开过的第二个文件的文件名,并且该文件名存放在一个文件名数
组opened _file_name里。以下的代码就实现了这一功能:
　
Load opened_files_list(1)
opened_files_list(1).Caption="&2"+opened_file_name(1)
opened_files_list(1).Visible=True
　
需要注意的是,对于下标为0的菜单项,不能用Load方法。因为在程序执行时,该
菜单项就 已经被装入到内存里了;另外,在菜单项的标题属性字符里的"&"字符具有
特殊的含义,它的作 用是在显示该属性字符串的同时,并不显示"&"本身,而紧跟"&"
的字符在显示时具有下划线, 并且该字符成为热键。
如果下标不为0的菜单项不再需要,为了减少对内存资源的占用,可以用Unload
方法把它 从内存卸出;同样地,不能用Unload卸出下标为0的菜单项。

[lihonggen0]

这样也可以


'先在屏幕上添加一个菜单，再在菜单下面加一个名为mnu的子菜单，索引设置为0
Private Sub Form_Load()
For i = 1 To 10
Load mnu(i)
mnu(i).Visible = True
Next
End Sub

[lm517]

关注