vb读取文件TraceNo.ini方法如下,那请问写回TraceNo.ini怎么做?

[yangscott]

文件TraceNo.ini中存放的是流水号,每次读取后就要更改流水号.请问写回TraceNo.ini文件语句怎么写?
Dim iFileNo As Integer, iDataBegin, iDataLast
Dim strTraceNo As String, strParam As String * 4
iFileNo = FreeFile
Open App.Path & "/TraceNo.ini" For Input Access Read As #iFileNo
Line Input #iFileNo, strTraceNo

[yangscott]

不一定是要对.ini文件进行操作的,我的意思是对文件,比如是.txt文件进行写操作.

[射天狼]

Dim iFileNo As Integer, iDataBegin, iDataLast
Dim strTraceNo As String, strParam As String * 4

iFileNo = FreeFile

Open App.Path & "/TraceNo.ini" For Output As #iFileNo '以写方式打开
Print #iFileNo, strTraceNo
Close #1

[foxnet2003]

说得没错，同意楼上的

[yangscott]

那怎么写入文件TraceNo.ini

[daviddivad]

'读写ini文件用下面的方法比较好.



'读写INI文件
Private Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
Private Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long

'------------------------------------------------------------------------
' 文件读写处理----------开始
'得到默认的处理文件名
Private Function fGetDefaultFileName$()
Dim iRe$
iRe = App.Path
If Right(iRe, 1) <> "\" Then iRe = iRe & "\"
iRe = iRe & "config.txt"

fGetDefaultFileName = iRe
End Function

'读取文件
Private Function fGetIni(ByVal sKey$ _
, ByVal sData$ _
, Optional ByVal sDefaltValue$ = "" _
, Optional ByVal sFileName$ = "" _
) As String
Dim iStr As String * 256, iReturn$
If sFileName = "" Then sFileName = fGetDefaultFileName

GetPrivateProfileString sKey, sData, "{}", iStr, 256, sFileName
iReturn = Left(iStr, InStr(iStr, Chr(0)) - 1)
If iReturn = "{}" Then
iReturn = sDefaltValue
Else
iReturn = Mid(iReturn, 2, Len(iReturn) - 2)
End If

fGetIni = iReturn
End Function

'保存INI文件
Private Sub sSetIni(ByVal sKey$ _
, ByVal sData$ _
, ByVal sValue$ _
, Optional ByVal sFileName$ = "")
If sFileName = "" Then sFileName = fGetDefaultFileName
WritePrivateProfileString sKey, sData, "{" + sValue + "}", sFileName
End Sub
' 配置文件处理----------结束
'------------------------------------------------------------------------

Private Sub Form_Load()
txt_ip = fGetIni("config", "Server", "")
txt_port = fGetIni("config", "Listen", "")
End Sub

Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
sSetIni "config", "Server", txt_ip
sSetIni "config", "Listen", txt_port
End Sub

[CHKK]

操作INI文件上面仁兄说的好