异常处理问题

[nsqsmile]

能不能详细讲一下异常的应用？
比如事务的声明、异常定义、异常触发等

[nsqsmile]

to YANGQINGDELPHI:
（1）bad_data_in_select EXCEPTION;--这应该是自定义异常的声明语句吧
（2） RAISE bad_data_in_select;--这句干什么用的？跳转到异常处理
(3）上面代码中为什么有两个exception段？第一个exception段只起到一个跳转作用？

[Drate]

☆PL/SQL异常处理初步☆

PL/SQL处理异常不同于其他程序语言的错误管理方法，PL/SQL的异常处理机制与ADA很相似，有一个处理错误的全包含方法。当发生错误时，程序无条件转到异常处理部分，这就要求代码要非常干净并把错误处理部分和程序的其它部分分开。oracle允许声明其他异常条件类型以扩展错误/异常处理。这种扩展使PL/SQL的异常处理非常灵活。

　　当一个运行时错误发生时，称为一个异常被抛出。PL/SQL程序编译时的错误不是能被处理得异常，只有在运行时的异常能被处理。在PL/SQL程序设计中异常的抛出和处理是非常重要的内容。

　　抛出异常

　　由三种方式抛出异常

　　　. 通过PL/SQL运行时引擎

　　　. 使用RAISE语句

　　　. 调用RAISE_APPLICATION_ERROR存储过程

　　当数据库或PL/SQL在运行时发生错误时，一个异常被PL/SQL运行时引擎自动抛出。异常也可以通过RAISE语句抛出

　　RAISE exception_name;

　　显式抛出异常是程序员处理声明的异常的习惯用法，但RAISE不限于声明了的异常，它可以抛出任何任何异常。例如，你希望用TIMEOUT_ON_RESOURCE错误检测新的运行时异常处理器，你只需简单的在程序中使用下面的语句：

　　RAISE TIMEOUT_ON_RESOUCE;

　　下面看一个订单输入系统，当库存小于订单时抛出一个inventory_too_low异常。

DECLARE
inventory_too_low EXCEPTION;
---其他声明语句
BEGIN
.
.
IF order_rec.qty>inventory_rec.qty THEN
RAISE inventory_too_low;
END IF
.
.
EXCEPTION
WHEN inventory_too_low THEN
order_rec.staus:='backordered';
replenish_inventory(inventory_nbr=>
inventory_rec.sku,min_amount=>order_rec.qty-inventory_rec.qty);
END;


　　这里replenish_inventory是一个触发器。
　
　　处理异常

　　PL/SQL程序块的异常部分包含了程序处理错误的代码，当异常被抛出时，一个异常陷阱就自动发生，程序控制离开执行部分转入异常部分,一旦程序进入异常部分就不能再回到同一块的执行部分。下面是异常部分的一般语法：

EXCEPTION
　WHEN exception_name THEN
　　Code for handing exception_name
　[WHEN another_exception THEN
　　Code for handing another_exception]
　[WHEN others THEN
　　code for handing any other exception.]


　　用户必须在独立的WHEN子串中为每个异常设计异常处理代码，WHEN OTHERS子串必须放置在最后面作为缺省处理器处理没有显式处理的异常。当异常发生时，控制转到异常部分，ORACLE查找当前异常相应的WHEN..THEN语句，捕捉异常，THEN之后的代码被执行，如果错误陷阱代码只是退出相应的嵌套块，那么程序将继续执行内部块END后面的语句。如果没有找到相应的异常陷阱，那么将执行WHEN OTHERS。在异常部分WHEN 子串没有数量限制。

EXCEPTION

　WHEN inventory_too_low THEN
　　order_rec.staus:='backordered';
　　replenish_inventory(inventory_nbr=>
　　inventory_rec.sku,min_amount=>order_rec.qty-inventory_rec.qty);
　WHEN discontinued_item THEN
　　--code for discontinued_item processing
　WHEN zero_divide THEN
　　--code for zero_divide
　WHEN OTHERS THEN
　　--code for any other exception
END;


　　当异常抛出后，控制无条件转到异常部分，这就意味着控制不能回到异常发生的位置，当异常被处理和解决后，控制返回到上一层执行部分的下一条语句。

BEGIN
　DECLARE
　　bad_credit;
　BEGIN
　　RAISE bad_credit;
　　　--发生异常，控制转向；
　EXCEPTION
　　WHEN bad_credit THEN
　　　dbms_output.put_line('bad_credit');
　　END;

　　--bad_credit异常处理后，控制转到这里
　EXCEPTION
　　WHEN OTHERS THEN
　　　--控制不会从bad_credit异常转到这里
　　　--因为bad_credit已被处理
END;


　　当异常发生时，在块的内部没有该异常处理器时，控制将转到或传播到上一层块的异常处理部分。

BEGIN
　DECLARE ---内部块开始
　　bad_credit;
　BEGIN
　　RAISE bad_credit;
　　　--发生异常，控制转向；
　　EXCEPTION
　　WHEN ZERO_DIVIDE THEN --不能处理bad_credite异常
　　　dbms_output.put_line('divide by zero error');
　　END --结束内部块

　　　--控制不能到达这里，因为异常没有解决；
　　　--异常部分

　　EXCEPTION
　　WHEN OTHERS THEN
　　　--由于bad_credit没有解决，控制将转到这里
END;

　　异常传播

　　没有处理的异常将沿检测异常调用程序传播到外面，当异常被处理并解决或到达程序最外层传播停止。
在声明部分抛出的异常将控制转到上一层的异常部分。

BEGIN
executable statements
BEGIN
today DATE:='SYADATE'; --ERRROR
BEGIN --内部块开始
dbms_output.put_line('this line will not execute');
EXCEPTION
WHEN OTHERS THEN
--异常不会在这里处理
END;--内部块结束

EXCEPTION
WHEN OTHERS THEN
处理异常
END

　　执行部分抛出的异常将首先传递到同一块的异常部分，如果在同一块的异常部分没有处理这个异常的处理器，那么异常将会传播到上一层的异常部分中，一直到最外层。

　　在异常部分抛出的异常将控制转到上一层的异常部分。

　　处理异常将停止异常的传播和解决。有时用户希望在错误发生时，程序仍然能执行一些动作，要达到这个目的，可以把希望执行的动作放在异常处理器中，然后执行不带参数的RAISE语句，RAISE语句将重新抛出出现的异常，允许他继续传播。

DECLARE
order_too_old EXCEPTION;
BEGIN
RAISE order_too_old;
EXCEPTION
WHEN order_too_old THEN
DECLARE
file_handle UTL_FILE.FILE_TYPE;
BEGIN
--open file
file_handle:=UTL_FILE.FOPEN
(location=>'/ora01/app/oracle/admin/test/utlsir'
,filename=>'error.log'
.open_mode=>'W');
--write error stack
UTL_FILE.PUT_LINE(filehandle,
DBMS_UTILITY.FORMAT_ERROR_STACK);
--write the call stack
UTL_FILE.PUT_LINE(filehandle,
DBMS_UTILITY.FORMAT_CALL_STACK);
--close error log
UTL_FILE.FCLOSE(file_handle);
RAISE; --re-raise the exception
END
END

　　如果从FORMAT_XXX_STACK输出一个很大的值，那么使用DBMS_OUTPUT或UTL_FILE显示错误或调用堆的异常部分自身也会抛出异常，这两个堆常规下最多能返回2000字节，但utl_file.put_line被限制在1000字节以内，而dbms_output.put_line限制在512字节内。如果使用前面的代码并且不允许这种可能性，那么在异常处理器中将抛出一个未处理的异常。

　　GOTO语句不能用于将控制从执行部分传递到异常部分或反之。

　　已命名异常

　　在PL/SQL块的异常部分只有已命名的异常才能被WHEN子串处理，ORACLE包含了一系列已命名的异常，这些异常都声明在STANDARD包中，这些内建异常在这里就不一一讲述，有兴趣的读者可以查阅有关资料。

[Drate]

PL/SQL异常处理初步(1)☆


　　常用异常处理方法

　　除了标准异常外，用户可以声明自己的已命名异常。比如商业规则错误，或者将自定义异常与一个数据库号相联系，甚至可以将数据库错误号赋予自定义异常。PL/SQL的这个性能极大的提高了对异常的管理和处理的能力。

　　声明自己的异常　

　　如果你希望声明自己的异常，那么你可以在异常处理器中包括WHEN子句，声明的异常的作用范围与声明的变量相同。声明在外层块的异常能被该块和它的子块访问，但声明在子块的异常不能被父块处理。
　
　　例：

　BEGIN
DECLARE
Insufficient_credite EXCEPTION;
BEGIN
RASISE Insufficient_credite;
EXCEPTION
WHEN Insufficient_credite THEN
--可以在此处理异常
　　　extend_credite(cust_id);
END　-嵌套块结束
EXCEPTION
WHEN Insufficient_credite THEN
--超出范围，不能在这里处理异常
　END;

　　如果声明的异常与内建的异常同名，那么当引用异常将解决你的异常而不是内建的异常。

　　给数据库错误命名

　　如果希望处理一个异常，那么异常必须有一个名字，数据库错误有数千个，但是只有不到25个是内建的已命名异常，但需要处理这些未命名的异常时，你可以将一个名字和一个错误号联系在一起，达到这个目的的语句是：PRAGMA EXCEPTION_INIT语句

　　语法如下：

　　PRAGMA EXCEPTION_INIT(exception_name，error_number);

　　执行这个语句之前，必须首先声明异常名。

DECLARE
invald_table_name EXCEPTION;
PRAGMA EXCEPTION_INIT(invald_table_name,-942);
BEGIN

EXCEPTION
WHEN invald_table_name THEN
UTL_FILE.PUT_LINE(file_handle,'user' || UID || 'hit a bad table');
END;

　　另外一种处理数据库错误的方法是使用内建函数SQLCODE和SQLERRM，这两个函数在包一级声明，SQLCODE将返回现行数据库错误号，这些错误号中除了NO_DATA_FOUND是+100外其他都是负数。SQLERRM返回文本描述的错误信息。为了获得用户自定义异常返回的SQLERRM和SQLCODE，你需要使用RAISE_APPLICATION_ERROR函数给自定义异常标注错误号。

　　给自定义错误标注号码

　　RAISE_APPLICATION_ERROR内建函数用于抛出一个异常并给异常赋予一个错误号以及错误信息。自定义异常的缺省错误号是+1,缺省信息是User_Defined_Exception。来自未处理的异常的一般信息对于识别导致错误的原因没有帮助，RAISE_APPLICATION_ERROR函数能够在pl/sql程序块的执行部分和异常部分调用，显式抛出带特殊错误号的命名异常。

RAISE_APPLICATION_ERROR(error_name,error_message[,{TRUE|| FALSE}]);

　　错误号的范围是-20,999到-20,999。错误信息是文本字符串，最多为2048字节。TRUE和FALSE表示是添加(TRUE)进错误堆(ERROR STACK)还是覆盖(overwrite)错误堆(FALSE)。缺省情况下是FALSE。

IF product_not_found THEN
　　RAISE_APPLICATION_ERROR(-20123,'Invald product code' TRUE);
END IF;

[jiezhi]

概念和其它語言裡面是一致的。
一個例子：
DECLARE
v_ErrorCode NUMBER; -- Code for the error
v_ErrorMsg VARCHAR2(200); -- Message text for the error
v_CurrentUser VARCHAR2(8); -- Current database user
v_Information VARCHAR2(100); -- Information about the error
BEGIN
/* Code which processes some data here */
NULL;
EXCEPTION
WHEN OTHERS THEN
-- Assign values to the log variables, using built-in
-- functions.
v_ErrorCode := SQLCODE;
v_ErrorMsg := SQLERRM;
v_CurrentUser := USER;
v_Information := 'Error encountered on ' ||
TO_CHAR(SYSDATE) || ' by database user ' || v_CurrentUser;
-- Insert the log message into log_table.
INSERT INTO log_table (code, message, info)
VALUES (v_ErrorCode, v_ErrorMsg, v_Information);
END;
/

[yangqingdelphi]

看一例子就知道了
FUNCTION company_name
(id_in IN NUMBER, access_type_in IN VARCHAR2)
RETURN VARCHAR2
IS
/* Return value of the function */
return_value VARCHAR2 (60);

/* Our own exception - used to represent bad data NO_DATA_FOUND. */
bad_data_in_select EXCEPTION;

BEGIN
/* Retrieve company name from the database */
IF access_type_in = 'DBMS'
THEN
/* Place the SELECT inside its own BEGIN-END. */
BEGIN
SELECT name INTO return_value
FROM company
WHERE company_id = id_in;
RETURN return_value;

/* Now it can have its OWN exception section too ! */
EXCEPTION
/* This NO_DATA_FOUND is only from the SELECT. */
WHEN NO_DATA_FOUND
THEN
/*
|| Raise my exception to propagate to
|| the main body of the function.
*/
RAISE bad_data_in_select;
END;

/* Retrieve company name from an in-memory PL/SQL table */
ELSIF access_type_in = 'MEMORY'
THEN
/*
|| Direct access from table. If this ID is not defined
|| then the NO_DATA_FOUND exception is raised.
*/
RETURN company_name_table (id_in);
END IF;
EXCEPTION
/*
|| This exception occurs only when NO_DATA_FOUND was raised by
|| the implicit cursor inside its own BEGIN-END.
*/
WHEN bad_data_in_select
THEN
DBMS_OUTPUT.PUT_LINE
(' Unable to locate company in database!');
/*
|| This exception occurs only when we have not previously placed
|| the company name for company id id_in in the table.
*/
WHEN NO_DATA_FOUND
THEN
DBMS_OUTPUT.PUT_LINE
(' Unable to locate company in memorized table!');
END;