交叉表查询的问题,请教

[anbywang]

有个表tab1
userid homeco mobile(不是int,是varchar型)
5001 1 13070991234
5001 2 62501234
5001 3 963251234
5002 1 13070991255
5002 2 62501255
5003 1 13070991288
5003 2 62501288

想得到查询结果：
userid mobile1 mobile2 mobile3
5001 13070991234 62501234 963251234
5002 13070991255 62501255
5003 13070991288 62501288
请问怎么才能实现?

[txlicenhe]

Select userid,(case when homeco = 1 then mobile else '' end) as mobile1,
(case when homeco = 2 then mobile else '' end) as mobile2,
(case when homeco = 3 then mobile else '' end) as mobile3
from 表

[pengdali]

交叉数据报表
有时候需要旋转结果以便在水平方向显示列，而在垂直方向显示行。这就是所谓的创建 PivotTable®、创建交叉数据报表或旋转数据。

假定有一个表 Pivot，其中每季度占一行。对 Pivot 的 SELECT 操作在垂直方向上列出这些季度：

Year Quarter Amount
---- ------- ------
1990 1 1.1
1990 2 1.2
1990 3 1.3
1990 4 1.4
1991 1 2.1
1991 2 2.2
1991 3 2.3
1991 4 2.4

生成报表的表必须是这样的，其中每年占一行，每个季度的数值显示在一个单独的列中，如：

Year
Q1
Q2
Q3
Q4

1990
1.1
1.2
1.3
1.4

1991
2.1
2.2
2.3
2.4



下面的语句用于创建 Pivot 表并在其中填入第一个表中的数据：

USE Northwind
GO

CREATE TABLE Pivot
( Year SMALLINT,
Quarter TINYINT,
Amount DECIMAL(2,1) )
GO
INSERT INTO Pivot VALUES (1990, 1, 1.1)
INSERT INTO Pivot VALUES (1990, 2, 1.2)
INSERT INTO Pivot VALUES (1990, 3, 1.3)
INSERT INTO Pivot VALUES (1990, 4, 1.4)
INSERT INTO Pivot VALUES (1991, 1, 2.1)
INSERT INTO Pivot VALUES (1991, 2, 2.2)
INSERT INTO Pivot VALUES (1991, 3, 2.3)
INSERT INTO Pivot VALUES (1991, 4, 2.4)
GO

下面是用于创建旋转结果的 SELECT 语句：

SELECT Year,
SUM(CASE Quarter WHEN 1 THEN Amount ELSE 0 END) AS Q1,
SUM(CASE Quarter WHEN 2 THEN Amount ELSE 0 END) AS Q2,
SUM(CASE Quarter WHEN 3 THEN Amount ELSE 0 END) AS Q3,
SUM(CASE Quarter WHEN 4 THEN Amount ELSE 0 END) AS Q4
FROM Northwind.dbo.Pivot
GROUP BY Year
GO

该 SELECT 语句还处理其中每个季度占多行的表。GROUP BY 语句将 Pivot 中一年的所有行合并成一行输出。当执行分组操作时，SUM 聚合中的 CASE 函数的应用方式是这样的：将每季度的 Amount 值添加到结果集的适当列中，在其它季度的结果集列中添加 0。

如果该 SELECT 语句的结果用作电子表格的输入，那么电子表格将很容易计算每年的合计。当从应用程序使用 SELECT 时，可能更易于增强 SELECT 语句来计算每年的合计。例如：

SELECT P1.*, (P1.Q1 + P1.Q2 + P1.Q3 + P1.Q4) AS YearTotal
FROM (SELECT Year,
SUM(CASE P.Quarter WHEN 1 THEN P.Amount ELSE 0 END) AS Q1,
SUM(CASE P.Quarter WHEN 2 THEN P.Amount ELSE 0 END) AS Q2,
SUM(CASE P.Quarter WHEN 3 THEN P.Amount ELSE 0 END) AS Q3,
SUM(CASE P.Quarter WHEN 4 THEN P.Amount ELSE 0 END) AS Q4
FROM Pivot AS P
GROUP BY P.Year) AS P1
GO

带有 CUBE 的 GROUP BY 和带有 ROLLUP 的 GROUP BY 都计算与本例显示相同的信息种类，但格式稍有不同。

[wzh1215]

楼上的只能针对知道字段homeco的最大值的情况下！

[pengdali]

动态：

declare @sql varchar(8000)
set @sql = 'select userid'
select @sql = @sql + ',max(case homeco when '''+cast(homeco as varchar(10))+''' then mobile end) [homeco'+cast(homeco as varchar(10))+']'
from (select distinct homeco from 表) as a
select @sql = @sql+' from 表 group by userid'

exec(@sql)
go

[shuiniu]

declare @sql varchar(8000)
set @sql = 'select userid'
select @sql = @sql + ',case homeco when '+cast(homeco as varchar)+' then mobile else '''' end) mobile'+cast(homeco as varchar)
from (select distinct homeco from tab1) as a
select @sql = @sql+' from tab1'
select @sql
exec(@sql)

[anbywang]

TO: txlicenhe(马可)
你的语句查询的接口会变成
userid mobile1 mobile2 mobile3
5001 13070991234
5001 62501234
5001 963251234
5002 13070991255
5002 62501255
5003 13070991288
5003 62501288

[zjcxc]

declare @s varchar(8000)
set @s = ''
select @s = @s+',[homeco'+homeco+']=max(case homeco when '+homeco+' then mobile else '''' end)'
from (select distinct homeco=cast(homeco as varchar) from tab1) as a
exec('select userid'+@sql+' from tab1 group by userid')

[zjcxc]

--上面的错了一点,改一下:
declare @s varchar(8000)
set @s = ''
select @s = @s+',[homeco'+homeco+']=max(case homeco when '+homeco+' then mobile else '''' end)'
from (select distinct homeco=cast(homeco as varchar) from tab1) as a
exec('select userid'+@s+' from tab1 group by userid')

[zjcxc]

--下面是数据测试

--创建测试表
create table tab1(userid varchar(4),homeco int,mobile varchar(15))
insert into tab1
select '5001',1,'13070991234'
union all select '5001',2,'62501234'
union all select '5001',3,'963251234'
union all select '5002',1,'13070991255'
union all select '5002',2,'62501255'
union all select '5003',1,'13070991288'
union all select '5003',2,'62501288'

--数据处理
declare @s varchar(8000)
set @s = ''
select @s = @s+',[homeco'+homeco+']=max(case homeco when '+homeco+' then mobile else '''' end)'
from (select distinct homeco=cast(homeco as varchar) from tab1) as a
exec('select userid'+@s+' from tab1 group by userid')

go
--删除测试环境
drop table tab1


/*--测试结果:

userid homeco1 homeco2 homeco3
------ --------------- --------------- ---------------
5001 13070991234 62501234 963251234
5002 13070991255 62501255
5003 13070991288 62501288

--*/

[anbywang]

pengdali(大力 V3.0) 大力的方法可以,谢谢了:)
shuiniu(用泪水灌溉幸福) 你的方法运行有错误,,,同样谢谢你!

[anbywang]

非常感谢zjcxc(邹建),你很热心:)
你的方法不错,,再次感谢!