又碰到写不出的SQL语句了,高手教教我

csutzs 2003-11-19 11:25:46
现有表
订单日期orderdate 运费carriage 车队keytrans 商品编号keyunit 商品名称name
2003-10-10 10 400006 13 冰箱
2003-10-11 12 400004 12 电视
2003-10-09 11 400003 11 手机
....

要求报表格式如下:

日期 09 10 11
洗衣机 30 12 32
冰柜 20 33 2
电视 10 112 3
电视柜 10 32 55

表以日期为列,商品种类为行,表格内容为该日该种类商品运费合计,这个SQL语句该怎么写啊?
...全文
25 15 打赏 收藏 转发到动态 举报
写回复
用AI写文章
15 条回复
切换为时间正序
请发表友善的回复…
发表回复
csutzs 2003-11-20
  • 打赏
  • 举报
回复
还有就是那个表里的数据其实是个视图,数据是从几个表里得到的,我运行了SQL语句后提示列名无效
pengdali 2003-11-20
  • 打赏
  • 举报
回复
declare @开始时间 datetime,@结束时间 datetime
select @开始时间='2003-1-1',@结束时间='2003-10-1'



declare @sql varchar(8000)
set @sql = 'select name'
select @sql = @sql + ',sum(case CONVERT(varchar(10),orderdate,120) when '''+orderdate+''' then carriage else 0 end) ['+orderdate+']'
from (select distinct CONVERT(varchar(10),orderdate,120) orderdate from 表 where orderdate between @开始时间 and @结束时间) as a
select @sql = @sql+' from 表 where orderdate between '''+CONVERT(varchar(10),@开始时间,120)+''' and '''+CONVERT(varchar(10),@结束时间,120)+''' group by name'

exec(@sql)
go
csutzs 2003-11-20
  • 打赏
  • 举报
回复
谢谢大家,我还有个难题是客户要求报表统计的是选择某月的前月21日到该月20日的统计格式,
年、月数据是在界面上选择后传到SQL语句的
也就是说
固定了标题是
21 22 23 24.......20
这有办法做到么?
pengdali 2003-11-20
  • 打赏
  • 举报
回复
原理是:

交叉数据报表
有时候需要旋转结果以便在水平方向显示列,而在垂直方向显示行。这就是所谓的创建 PivotTable®、创建交叉数据报表或旋转数据。

假定有一个表 Pivot,其中每季度占一行。对 Pivot 的 SELECT 操作在垂直方向上列出这些季度:

Year Quarter Amount
---- ------- ------
1990 1 1.1
1990 2 1.2
1990 3 1.3
1990 4 1.4
1991 1 2.1
1991 2 2.2
1991 3 2.3
1991 4 2.4

生成报表的表必须是这样的,其中每年占一行,每个季度的数值显示在一个单独的列中,如:

Year
Q1
Q2
Q3
Q4

1990
1.1
1.2
1.3
1.4

1991
2.1
2.2
2.3
2.4



下面的语句用于创建 Pivot 表并在其中填入第一个表中的数据:

USE Northwind
GO

CREATE TABLE Pivot
( Year SMALLINT,
Quarter TINYINT,
Amount DECIMAL(2,1) )
GO
INSERT INTO Pivot VALUES (1990, 1, 1.1)
INSERT INTO Pivot VALUES (1990, 2, 1.2)
INSERT INTO Pivot VALUES (1990, 3, 1.3)
INSERT INTO Pivot VALUES (1990, 4, 1.4)
INSERT INTO Pivot VALUES (1991, 1, 2.1)
INSERT INTO Pivot VALUES (1991, 2, 2.2)
INSERT INTO Pivot VALUES (1991, 3, 2.3)
INSERT INTO Pivot VALUES (1991, 4, 2.4)
GO

下面是用于创建旋转结果的 SELECT 语句:

SELECT Year,
SUM(CASE Quarter WHEN 1 THEN Amount ELSE 0 END) AS Q1,
SUM(CASE Quarter WHEN 2 THEN Amount ELSE 0 END) AS Q2,
SUM(CASE Quarter WHEN 3 THEN Amount ELSE 0 END) AS Q3,
SUM(CASE Quarter WHEN 4 THEN Amount ELSE 0 END) AS Q4
FROM Northwind.dbo.Pivot
GROUP BY Year
GO

该 SELECT 语句还处理其中每个季度占多行的表。GROUP BY 语句将 Pivot 中一年的所有行合并成一行输出。当执行分组操作时,SUM 聚合中的 CASE 函数的应用方式是这样的:将每季度的 Amount 值添加到结果集的适当列中,在其它季度的结果集列中添加 0。

如果该 SELECT 语句的结果用作电子表格的输入,那么电子表格将很容易计算每年的合计。当从应用程序使用 SELECT 时,可能更易于增强 SELECT 语句来计算每年的合计。例如:

SELECT P1.*, (P1.Q1 + P1.Q2 + P1.Q3 + P1.Q4) AS YearTotal
FROM (SELECT Year,
SUM(CASE P.Quarter WHEN 1 THEN P.Amount ELSE 0 END) AS Q1,
SUM(CASE P.Quarter WHEN 2 THEN P.Amount ELSE 0 END) AS Q2,
SUM(CASE P.Quarter WHEN 3 THEN P.Amount ELSE 0 END) AS Q3,
SUM(CASE P.Quarter WHEN 4 THEN P.Amount ELSE 0 END) AS Q4
FROM Pivot AS P
GROUP BY P.Year) AS P1
GO

带有 CUBE 的 GROUP BY 和带有 ROLLUP 的 GROUP BY 都计算与本例显示相同的信息种类,但格式稍有不同。
pengdali 2003-11-20
  • 打赏
  • 举报
回复
或:

declare @sql varchar(8000)
set @sql = 'select name'
select @sql = @sql + ',sum(case CONVERT(varchar(10),orderdate,120) when '''+orderdate+''' then carriage else 0 end) ['+orderdate+']'
from (select distinct CONVERT(varchar(10),orderdate,120) orderdate from 表) as a
select @sql = @sql+' from 表 group by name'

exec(@sql)
go
pengdali 2003-11-20
  • 打赏
  • 举报
回复
--应为有年月日,建议楼主:

declare @sql varchar(8000)
set @sql = 'select name'
select @sql = @sql + ',sum(case CONVERT(varchar(10),orderdate,120) when '''+cast(orderdate as varchar(10))+''' then carriage else 0 end) ['+cast(orderdate as varchar(10))+']'
from (select distinct CONVERT(varchar(10),orderdate,120) orderdate from 表) as a
select @sql = @sql+' from 表 group by name'

exec(@sql)
go
lvltt 2003-11-20
  • 打赏
  • 举报
回复
declare @sql varchar(8000)
set @sql = 'select name'
select @sql = @sql + ',sum(case day(orderdate) when '''+cast(orderdate as varchar(10))+''' then carriage else 0 end) ['+cast(orderdate as varchar(10))+']'
from (select distinct day(orderdate) orderdate from 表) as a
select @sql = @sql+' from 表 group by name'

exec(@sql)
go
txlicenhe 2003-11-20
  • 打赏
  • 举报
回复
declare @sql varchar(8000)
set @sql = 'select name'
select @sql = @sql + ',sum(case day(orderdate) when '''+cast(day(orderdate) as varchar(2))+''' then carriage else 0 end) ['
+cast(day(orderdate) as varchar(2))+']'
from (select distinct day(orderdate) orderdate from 表) as a
select @sql = @sql+' from 表 group by name'

exec(@sql)
go
zjcxc 元老 2003-11-20
  • 打赏
  • 举报
回复
测试结果:

name 09 10 11
---------- ----------- ----------- -----------
冰箱 0 10 0
电视 0 0 12
手机 11 0 0

zjcxc 元老 2003-11-20
  • 打赏
  • 举报
回复
--下面是数据测试

--创建测试数据
create table #t(orderdate datetime,carriage int,keytrans varchar(10),keyunit int,name varchar(10))
insert into #t
select '2003-10-10','10','400006','13','冰箱'
union all select '2003-10-11','12','400004','12','电视'
union all select '2003-10-09','11','400003','11','手机'

--数据处理
declare @s varchar(8000)
set @s=''
select @s=@s+',['+dt+']=sum(case day(orderdate) when '
+dt+' then carriage else 0 end)'
from(select distinct dt=right(convert(varchar(10),orderdate,120),2) from #t) a order by dt
exec('select name'+@s+' from #t group by name')
go

--删除测试环境
drop table #t
zjcxc 元老 2003-11-20
  • 打赏
  • 举报
回复
--上面的错了一点,调整一下:
declare @s varchar(8000)
set @s=''
select @s=@s+',['+dt+']=sum(case day(orderdate) when '
+dt+' then carriage else 0 end)'
from(select distinct dt=right(convert(varchar(10),orderdate,120),2) from 表) a order by dt
exec('select name'+@s+' from 表 group by name')
txlicenhe 2003-11-20
  • 打赏
  • 举报
回复
http://expert.csdn.net/Expert/topic/2440/2440306.xml?temp=.6941645
[交流]行列转换
zjcxc 元老 2003-11-20
  • 打赏
  • 举报
回复
--交叉表
declare @s varchar(8000)
set @s=''
select @s=@s+',['+dt+']=sum(case day(orderdate) when '
+dt+' then carriage else 0 end)'
from(select distinct dt=cast(day(orderdate) as varcahr) from 表) a
exec('select name'+@s+' from 表 group by name')
MaDaHai 2003-11-20
  • 打赏
  • 举报
回复
學習
pengdali 2003-11-19
  • 打赏
  • 举报
回复
declare @sql varchar(8000)
set @sql = 'select name'
select @sql = @sql + ',sum(case day(orderdate) when '''+cast(orderdate as varchar(10))+''' then carriage else 0 end) ['+cast(orderdate as varchar(10))+']'
from (select distinct day(orderdate) orderdate from 表) as a
select @sql = @sql+' from 表 group by name'

exec(@sql)
go

34,606

社区成员

发帖
与我相关
我的任务
社区描述
MS-SQL Server相关内容讨论专区
社区管理员
  • 基础类社区
  • 二月十六
  • 卖水果的net
加入社区
  • 近7日
  • 近30日
  • 至今
社区公告
暂无公告

试试用AI创作助手写篇文章吧