求一条查询语句！！！！！！

[wg168]

表结构如下

Pro_ID Num_In Num_Out Stor_ID
0011 1 0 001
0002 2 1 001
0023 5 0 001
0011 20 1 002
0002 2 4 002

我想统计为
Pro_ID Stor1_In Stor1_Out Stor2_In Stor2_Out Stor3_In Stor3_Out
0011 1 0 20 1 0 0
0002 2 1 2 4 0 0
0023 5 0 0 0 0 0

[pengdali]

declare @sql varchar(8000)
set @sql = 'select Pro_ID'
select @sql = @sql + ',sum(case Stor_ID when '''+Stor_ID+''' then Num_In else 0 end) ['+cast(Stor_ID+0 as varchar(10))+'_In],sum(case Stor_ID when '''+Stor_ID+''' then Num_Out else 0 end) ['+cast(Stor_ID+0 as varchar(10))+'_Out]'
from (select distinct Stor_ID from 表) as a
select @sql = @sql+' from 表 group by Pro_ID'

exec(@sql)
go

[pengdali]

原理：

交叉数据报表
有时候需要旋转结果以便在水平方向显示列，而在垂直方向显示行。这就是所谓的创建 PivotTable®、创建交叉数据报表或旋转数据。

假定有一个表 Pivot，其中每季度占一行。对 Pivot 的 SELECT 操作在垂直方向上列出这些季度：

Year Quarter Amount
---- ------- ------
1990 1 1.1
1990 2 1.2
1990 3 1.3
1990 4 1.4
1991 1 2.1
1991 2 2.2
1991 3 2.3
1991 4 2.4

生成报表的表必须是这样的，其中每年占一行，每个季度的数值显示在一个单独的列中，如：

Year
Q1
Q2
Q3
Q4

1990
1.1
1.2
1.3
1.4

1991
2.1
2.2
2.3
2.4



下面的语句用于创建 Pivot 表并在其中填入第一个表中的数据：

USE Northwind
GO

CREATE TABLE Pivot
( Year SMALLINT,
Quarter TINYINT,
Amount DECIMAL(2,1) )
GO
INSERT INTO Pivot VALUES (1990, 1, 1.1)
INSERT INTO Pivot VALUES (1990, 2, 1.2)
INSERT INTO Pivot VALUES (1990, 3, 1.3)
INSERT INTO Pivot VALUES (1990, 4, 1.4)
INSERT INTO Pivot VALUES (1991, 1, 2.1)
INSERT INTO Pivot VALUES (1991, 2, 2.2)
INSERT INTO Pivot VALUES (1991, 3, 2.3)
INSERT INTO Pivot VALUES (1991, 4, 2.4)
GO

下面是用于创建旋转结果的 SELECT 语句：

SELECT Year,
SUM(CASE Quarter WHEN 1 THEN Amount ELSE 0 END) AS Q1,
SUM(CASE Quarter WHEN 2 THEN Amount ELSE 0 END) AS Q2,
SUM(CASE Quarter WHEN 3 THEN Amount ELSE 0 END) AS Q3,
SUM(CASE Quarter WHEN 4 THEN Amount ELSE 0 END) AS Q4
FROM Northwind.dbo.Pivot
GROUP BY Year
GO

该 SELECT 语句还处理其中每个季度占多行的表。GROUP BY 语句将 Pivot 中一年的所有行合并成一行输出。当执行分组操作时，SUM 聚合中的 CASE 函数的应用方式是这样的：将每季度的 Amount 值添加到结果集的适当列中，在其它季度的结果集列中添加 0。

如果该 SELECT 语句的结果用作电子表格的输入，那么电子表格将很容易计算每年的合计。当从应用程序使用 SELECT 时，可能更易于增强 SELECT 语句来计算每年的合计。例如：

SELECT P1.*, (P1.Q1 + P1.Q2 + P1.Q3 + P1.Q4) AS YearTotal
FROM (SELECT Year,
SUM(CASE P.Quarter WHEN 1 THEN P.Amount ELSE 0 END) AS Q1,
SUM(CASE P.Quarter WHEN 2 THEN P.Amount ELSE 0 END) AS Q2,
SUM(CASE P.Quarter WHEN 3 THEN P.Amount ELSE 0 END) AS Q3,
SUM(CASE P.Quarter WHEN 4 THEN P.Amount ELSE 0 END) AS Q4
FROM Pivot AS P
GROUP BY P.Year) AS P1
GO

带有 CUBE 的 GROUP BY 和带有 ROLLUP 的 GROUP BY 都计算与本例显示相同的信息种类，但格式稍有不同。

[txlicenhe]

declare @sql varchar(8000)
set @sql = 'select Pro_ID'
select @sql = @sql + ',sum(case Stor_ID when '''+Stor_ID+''' then Num_In else 0 end) ['+cast(Stor_ID+0 as varchar(10))+'_In],sum(case Stor_ID when '''+Stor_ID+''' then Num_Out else 0 end) ['+cast(Stor_ID+0 as varchar(10))+'_Out]'
from (select distinct Stor_ID from 表) as a
select @sql = @sql+' from 表 group by Pro_ID'

exec(@sql)
go



http://expert.csdn.net/Expert/topic/2440/2440306.xml?temp=.6941645
[交流]行列转换

[wg168]

上面的查询结果能否保存到一个表变量中？

[pengdali]

declare @sql varchar(8000)
set @sql = 'select Pro_ID'
select @sql = @sql + ',sum(case Stor_ID when '''+Stor_ID+''' then Num_In else 0 end) ['+cast(Stor_ID+0 as varchar(10))+'_In],sum(case Stor_ID when '''+Stor_ID+''' then Num_Out else 0 end) ['+cast(Stor_ID+0 as varchar(10))+'_Out]'
from (select distinct Stor_ID from 表) as a
select @sql = @sql+' into ##全局临时表 from 表 group by Pro_ID'

exec(@sql)


select * from ##全局临时表
go
drop table ##全局临时表

[zjcxc]

--如果sortid很多,可以用下面的方法,避免数据处理错误:

declare @sql varchar(8000)
set @sql = 'select Pro_ID'
select @sql = @sql + ',sum(case Stor_ID when '''+Stor_ID+''' then Num_In else 0 end) ['+cast(Stor_ID+0 as varchar(10))+'_In],sum(case Stor_ID when '''+Stor_ID+''' then Num_Out else 0 end) ['+cast(Stor_ID+0 as varchar(10))+'_Out]'
from (select distinct Stor_ID from 表) as a
select @sql = @sql+' from 表 group by Pro_ID'

exec(@sql)
go


declare @sqlhead varchar(8000),@sqlend varchar(8000)
,@sql1 varchar(8000),@sql2 varchar(8000),@sql3 varchar(8000),@sql4 varchar(8000)
,@i int,@ic varchar(20)

--生成数据处理临时表
select id=identity(int,0,1),gid=0
,a= ',sum(case Stor_ID when '''+Stor_ID
+''' then Num_In else 0 end) ['
+cast(Stor_ID+0 as varchar(10))
+'_In],sum(case Stor_ID when '''
+Stor_ID+''' then Num_Out else 0 end) ['
+cast(Stor_ID+0 as varchar(10))+'_Out]'
into # from(select distinct Stor_ID from 表) a

--判断需要多少个变量来处理
select @i=max(len(a)) from #
set @i=7800/@i

--分组临时表
update # set gid=id/@i
select @i=max(gid) from #

--生成数据处理语句
select @sqlhead='''select Pro_ID'''
,@sqlend=''' from 表 group by Pro_ID'''
,@sql1='',@sql2='select ',@sql3='',@sql4=''

while @i>=0
select @ic=cast(@i as varchar),@i=@i-1
,@sql1='@'+@ic+' varchar(8000),'+@sql1
,@sql2=@sql2+'@'+@ic+'='''','
,@sql3='select @'+@ic+'=@'+@ic+'+a from # where gid='+@ic
+char(13)+@sql3
,@sql4=@sql4+',@'+@ic

select @sql1='declare '+left(@sql1,len(@sql1)-1)+char(13)
,@sql2=left(@sql2,len(@sql2)-1)+char(13)
,@sql3=left(@sql3,len(@sql3)-1)
,@sql4=substring(@sql4,2,8000)

--执行
exec( @sql1+@sql2+@sql3+'
exec('+@sqlhead+'+'+@sql4+'+'+@sqlend+')'
)

--删除临时表
drop table #

[zjcxc]

--而生成表只需要调用数据处理语句

--生成数据处理语句
select @sqlhead='''select Pro_ID'''
,@sqlend=''' into 表名 from 表 group by Pro_ID''' --改这句
,@sql1='',@sql2='select ',@sql3='',@sql4=''

--就可以生成名为:表名 的表