如何把备份的.bak文件还原到一个新的数据库！

2003-12-17 05:07:48 2.6万阅读 AI 写同款 · GEO 优化AI 选题数据监测一键分发 ›

esheng 墨衍会员 · AI 创作全网分发关注 + 加入社区

SQL Server 2016 bak文件还原 Sql Server 2016 bak文件还原数据库完整备份还原--差异备份还原--事务日志备份还原阅读详情

如何把备份的.bak文件还原到一个新的数据库，也就是把它复制成另外一个数据库，程序只要换库就可以用了！

...全文

SQL2000如何还原数据库备份bak文件？ 1.右击SQL Server 2000实例下的“数据库”文件夹。就是master等数据库上一级的那个图标。选择“所有任务”，“还原数据库” 2.在“还原为数据库”中填上你希望恢复的数据库名字。这个名字应该与你的源码中使用的数据库名字一致。 3.在弹出的对话框中，选“从设备” 4.点击“选择设备” 5.点击“添加” 6.点击“文件名”文本框右侧的“...”按钮，选中你的“.BAK”文件，并点击确定回阅读详情

esheng

MS-SQL Server 34,876 成员 254,635 内容

+ 关注 + 加入社区

切换为时间正序

CrazyFor 2003-12-17

打赏
举报

先建立一个数据库,和你备份的库同名,物理文件名也要相同,位置可以是你需要的地方.

到企业管理器->到刚才新建的库上右键,->所有任务->恢复数据库->

1,输入新的数据库名,并打开你的备份文件.
2,在选项中,选中在现有数据库上强制恢复,并在下面输入刚才建的数据库的物理目录.

bluesky1980 2003-12-17

打赏
举报

恩,企业管理器是很直截了当的方法

mfjun007 2003-12-17

打赏
举报

使用企业管理器吧，应该还容易实现吧！

sdhdy 2003-12-17

打赏
举报

SQL SERVER企业管理器—》右键数据库目录-》所有任务-》还原数据库-》常规页还原为数据库：填上或从下拉列表中选择要还原的数据库名，选从设备点选择设备按钮-》填加-》选择文件名，点右边的小按钮-》选择备份的文件名-》确定-》确定-》确定-》如果是在现有数据库基础上还原-》选项页，选中在现有数据库强制还原，如果你不想把数据文件（.mdf和.ldf）放在系统默认的路径下，你可以修改移至物理文件名，修改以下两个路径，再确定就可以了。

yun198183 2003-12-17

打赏
举报

学习
copy

zjcxc 元老 2003-12-17

打赏
举报

--如果是将一个数据库复制成另一个数据库.

/*--将一个数据库完整复制成另一个数据库

--邹建 2003.10--*/

/*--调用示例
exec p_CopyDb @ddbname='test'
--*/

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_CopyDb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_CopyDb]
GO

create proc p_CopyDb
@sdbname sysname='', --定义要复制的数据库名,默认为当前数据库
@ddbname sysname, --定义复制后生成的数据库名
@overexist bit=1, --是否覆盖已经存在的数据库
@killuser bit=1 --是否关闭用户使用进程,仅@overexist=1时有效
as
declare @sql varchar(8000),@bpath varchar(8000),@rpath varchar(8000)

--得到要复制的数据库名
if isnull(@sdbname,'')='' set @sdbname=db_name()

--得到临时备份数据目录及文件名
select @bpath=rtrim(reverse(filename)) from master..sysfiles where name='master'
select @bpath=substring(@bpath,charindex('\',@bpath)+1,8000)
,@bpath=reverse(substring(@bpath,charindex('\',@bpath),8000))+'BACKUP\'
+@sdbname+'_'+convert(varchar,getdate(),112)
+'_'+replace(convert(varchar,getdate(),108),':','')
+'.bak'

--生成数据库备份语句,进行数据库备份
set @sql='backup database '+@sdbname
+' to disk='''+@bpath
+''' with NOINIT'
exec(@sql)

--根据备份文件恢复成新的数据库(完成复制工作)
set @sql='restore database '+@ddbname
+' from disk='''+@bpath+''''
+' with file=1'
+case when @overexist=1 then ',replace' else '' end

--得到数据库存放的默认目录
--得到SQL安装时设置的数据文件路径
select @rpath=rtrim(reverse(filename)) from master..sysfiles where name='master'
select @rpath=reverse(substring(@rpath,charindex('\',@rpath),8000))

--添加移动逻辑文件的处理
--从备份文件中获取逻辑文件名
declare @lfn nvarchar(128),@tp char(1),@i int

--创建临时表,保存获取的信息
create table #tb(ln nvarchar(128),pn nvarchar(260),tp char(1),fgn nvarchar(128),sz numeric(20,0),Msz numeric(20,0))
--从备份文件中获取信息
insert into #tb exec('restore filelistonly from disk='''+@bpath+'''')
declare #f cursor for select ln,tp from #tb
open #f
fetch next from #f into @lfn,@tp
set @i=0
while @@fetch_status=0
begin
select @sql=@sql+',move '''+@lfn+''' to '''+@rpath+@ddbname+cast(@i as varchar)
+case @tp when 'D' then '.mdf''' else '.ldf''' end
,@i=@i+1
fetch next from #f into @lfn,@tp
end
close #f
deallocate #f

--关闭用户进程处理
if @overexist=1 and @killuser=1
begin
declare @spid varchar(20)
declare #spid cursor for
select spid=cast(spid as varchar(20)) from master..sysprocesses where dbid=db_id(@ddbname)
open #spid
fetch next from #spid into @spid
while @@fetch_status=0
begin
exec('kill '+@spid)
fetch next from #spid into @spid
end
close #spid
deallocate #spid
end

--恢复数据库
exec(@sql)

--删除备份的临时文件
set @sql='del "'+@bpath+'"'
exec master..xp_cmdshell @sql,no_output
select @sql,@bpath,@rpath
go

zjcxc 元老 2003-12-17

打赏
举报

--或者用下面的存储过程.

/*--恢复数据库

--邹建 2003.10--*/

/*--调用示例
--完整恢复数据库
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db'

--差异备份恢复
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db',@retype='DBNOR'
exec p_backupdb @bkfile='c:\db_20031015_df.bak',@dbname='db',@retype='DF'

--日志备份恢复
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db',@retype='DBNOR'
exec p_backupdb @bkfile='c:\db_20031015_log.bak',@dbname='db',@retype='LOG'

--*/

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_RestoreDb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_RestoreDb]
GO

create proc p_RestoreDb
@bkfile nvarchar(1000), --定义要恢复的备份文件名
@dbname sysname='', --定义恢复后的数据库名,默认为备份的文件名
@dbpath nvarchar(260)='', --恢复后的数据库存放目录,不指定则为SQL的默认数据目录
@retype nvarchar(10)='DB', --恢复类型:'DB'完事恢复数据库,'DBNOR' 为差异恢复,日志恢复进行完整恢复,'DF' 差异备份的恢复,'LOG' 日志恢复
@filenumber int=1, --恢复的文件号
@overexist bit=1, --是否覆盖已经存在的数据库,仅@retype为'DB'/'DBNOR'是有效
@killuser bit=1 --是否关闭用户使用进程,仅@overexist=1时有效
as
declare @sql varchar(8000)

--得到恢复后的数据库名
if isnull(@dbname,'')=''
select @sql=reverse(@bkfile)
,@sql=case when charindex('.',@sql)=0 then @sql
else substring(@sql,charindex('.',@sql)+1,1000) end
,@sql=case when charindex('\',@sql)=0 then @sql
else left(@sql,charindex('\',@sql)-1) end
,@dbname=reverse(@sql)

--得到恢复后的数据库存放目录
if isnull(@dbpath,'')=''
begin
select @dbpath=rtrim(reverse(filename)) from master..sysfiles where name='master'
select @dbpath=reverse(substring(@dbpath,charindex('\',@dbpath),4000))
end

--生成数据库恢复语句
set @sql='restore '+case @retype when 'LOG' then 'log ' else 'database ' end+@dbname
+' from disk='''+@bkfile+''''
+' with file='+cast(@filenumber as varchar)
+case when @overexist=1 and @retype in('DB','DBNOR') then ',replace' else '' end
+case @retype when 'DBNOR' then ',NORECOVERY' else ',RECOVERY' end

--添加移动逻辑文件的处理
if @retype='DB' or @retype='DBNOR'
begin
--从备份文件中获取逻辑文件名
declare @lfn nvarchar(128),@tp char(1),@i int

--创建临时表,保存获取的信息
create table #tb(ln nvarchar(128),pn nvarchar(260),tp char(1),fgn nvarchar(128),sz numeric(20,0),Msz numeric(20,0))
--从备份文件中获取信息
insert into #tb exec('restore filelistonly from disk='''+@bkfile+'''')
declare #f cursor for select ln,tp from #tb
open #f
fetch next from #f into @lfn,@tp
set @i=0
while @@fetch_status=0
begin
select @sql=@sql+',move '''+@lfn+''' to '''+@dbpath+@dbname+cast(@i as varchar)
+case @tp when 'D' then '.mdf''' else '.ldf''' end
,@i=@i+1
fetch next from #f into @lfn,@tp
end
close #f
deallocate #f
end

--关闭用户进程处理
if @overexist=1 and @killuser=1
begin
declare @spid varchar(20)
declare #spid cursor for
select spid=cast(spid as varchar(20)) from master..sysprocesses where dbid=db_id(@dbname)
open #spid
fetch next from #spid into @spid
while @@fetch_status=0
begin
exec('kill '+@spid)
fetch next from #spid into @spid
end
close #spid
deallocate #spid
end

--恢复数据库
exec(@sql)

go

zjcxc 元老 2003-12-17

打赏
举报

还原数据库
企业管理器中的操作:

企业管理器--右键"数据库"--所有任务--还原数据库
--"还原为数据库库"中输入还原后的数据库名
--还原选择"从设备"--选择设备--添加--添加你的备份文件--确定,回到数据库还原的界面
--选项--将"移至物理文件名"中的物理文件名修改为你的数据文件要存放的文件名
--如果要还原的数据库已经存在,选择"在现有数据库上强制还原"-
-确定

gmlxf 2003-12-17

打赏
举报

企业管理期》》右键》恢复数据库

yujohny 2003-12-17

打赏
举报

在企业管理里选择“数据库”——》“还原数据库”——》起一个数据库名
——》选择“从设备”——》选择你的ba'k文件位置，然后按确定还原就可以了

或者用语句

restore database NewDatabase from disk='c:/dbname.bak' with replace

gmlxf 2003-12-17

打赏
举报

use master
restore database 数据库名 from disk='c:/dbname.bak' with REPLACE

或:

还原修改数据库路径:
RESTORE DATABASE 数据库名
FROM disk='c:/dbname.bak'
WITH MOVE 'test' TO 'c:\Program Files\Microsoft SQL Server\MSSQL\Data\test.mdf',
MOVE 'test_log' TO 'c:\Program Files\Microsoft SQL Server\MSSQL\Data\'test_log.ldf'

gmlxf 2003-12-17

打赏
举报

restore database dbname from disk='c:/dbname.bak' with replace

如何把备份的.bak文件还原到一个新的数据库！

相关推荐