怎么自动给备份的文件名加上备份时候的时间!!!!!!!!!!!!!!!!!

[loulanlouzhu]

在作业中用下面语句执行备份!
backup database MSPetShop to disk='\\hp580-2\test\mspetshop.bak'

我想每次备份在mspetshop后面加上当时的时间,即mspetshop20031219.bak

[LoveSQL]

set @time=cast(datepart(year,getdate()) as varchar)+cast(datepart(month,getdate()) as varchar)+cast(datepart(day,getdate()) as varchar)+cast(datepart(hour,getdate()) as varchar)+cast(datepart(minute,getdate()) as varchar)+cast(datepart(mm,getdate()) as varchar)

[loulanlouzhu]

SET @TIME=CONVERT(varchar(10),getDate(),120)

-->>SET @TIME=CONVERT(varchar(20),getDate(),120)

为什么就不行了!@?

[lynx1111]

DECLARE @TIME AS VARCHAR(100)
DECLARE @STR AS VARCHAR(2000)
SET @TIME=CONVERT(varchar(20),getDate(),120)
SET @STR='backup database MSPetShop to disk=''\\hp580-2\test\mspetshop'+@TIME+'.bak'''
exec (@str)
有空格不是很好哦！
----------------------------
DECLARE @TIME AS VARCHAR(100)
DECLARE @STR AS VARCHAR(2000)
set @time=cast(datepart(year,getdate()) as varchar)+cast(datepart(month,getdate()) as varchar)+cast(datepart(day,getdate()) as varchar)+cast(datepart(hour,getdate()) as varchar)+cast(datepart(minute,getdate()) as varchar)+cast(datepart(mm,getdate()) as varchar)
SET @STR='backup database MSPetShop to disk=''\\hp580-2\test\mspetshop'+@TIME+'.bak'''
exec (@str)

[zjcxc]

--现成的.日期+时间+数据库名都有的

/*--备份数据库

--邹建 2003.10--*/

/*--调用示例

--备份当前数据库
exec p_backupdb @bkpath='c:\',@bkfname='\DBNAME\_\DATE\_db.bak'

--差异备份当前数据库
exec p_backupdb @bkpath='c:\',@bkfname='db_\DATE\_df.bak',@bktype='DF'

--备份当前数据库日志
exec p_backupdb @bkpath='c:\',@bkfname='db_\DATE\_log.bak',@bktype='LOG'

--*/

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_backupdb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_backupdb]
GO

create proc p_backupdb
@dbname sysname='', --要备份的数据库名称,不指定则备份当前数据库
@bkpath nvarchar(260)='', --备份文件的存放目录,不指定则使用SQL默认的备份目录
@bkfname nvarchar(260)='', --备份文件名,文件名中可以用\DBNAME\代表数据库名,\DATE\代表日期,\TIME\代表时间
@bktype nvarchar(10)='DB', --备份类型:'DB'备份数据库,'DF' 差异备份,'LOG' 日志备份
@appendfile bit=1 --追加/覆盖备份文件
as
declare @sql varchar(8000)
if isnull(@dbname,'')='' set @dbname=db_name()
if isnull(@bkpath,'')=''
begin
select @bkpath=rtrim(reverse(filename)) from master..sysfiles where name='master'
select @bkpath=substring(@bkpath,charindex('\',@bkpath)+1,4000)
,@bkpath=reverse(substring(@bkpath,charindex('\',@bkpath),4000))+'BACKUP\'
end
if isnull(@bkfname,'')='' set @bkfname='\DBNAME\_\DATE\_\TIME\.BAK'
set @bkfname=replace(replace(replace(@bkfname,'\DBNAME\',@dbname)
,'\DATE\',convert(varchar,getdate(),112))
,'\TIME\',replace(convert(varchar,getdate(),108),':',''))
set @sql='backup '+case @bktype when 'LOG' then 'log ' else 'database ' end +@dbname
+' to disk='''+@bkpath+@bkfname
+''' with '+case @bktype when 'DF' then 'DIFFERENTIAL,' else '' end
+case @appendfile when 1 then 'NOINIT' else 'INIT' end
exec(@sql)
go

[lynx1111]

DECLARE @TIME AS VARCHAR(100)
DECLARE @STR AS VARCHAR(2000)
SET @TIME=CONVERT(varchar(10),getDate(),120)

SET @STR= 'backup database ['+@name+ '] to disk=''H:\SQLDataBack\\'+@name+@TIME+'.bak'''
exec (@str)

[vileboy]

dim @tm varchar(20)
set @tm=convert(varchar(8),getdate(),112)
backup database MSPetShop to disk='\\hp580-2\test\mspetshop'+@tm+'.bak'

[txlicenhe]

楼上的都可以吧。

[loulanlouzhu]

SET @TIME=CONVERT(varchar(10),getDate(),120)

-->>SET @TIME=CONVERT(varchar(20),getDate(),120)

为什么就不行了!@?

[loulanlouzhu]

或者说时间我想精确到时分秒