请问SELECT能否选出这个月的第一天和最后一天分别做为两个字段？Field1=2003-01-01, Field2=2003-01-31

[jerry_huang]

请问SELECT能否选出这个月的第一天和最后一天分别做为两个字段？

一条SELECT产生如下两个字段？

Field1=2003-01-01
Field2=2003-01-31

[wzh1215]

try:

select convert(varchar(10),dateadd(day,-datepart(dd,getdate())+1,getdate()),120) as field1
select convert(varchar(10),dateadd(day,-datepart(dd,getdate()),dateadd(mm,1,getdate())),120) as field2

[gmlxf]

select dateadd(d,-day(getdate()),getdate()+1)
select dateadd(m,1,getdate())-day(getdate())

[DigJim]

一个月的第一天
SELECT DATEADD(mm, DATEDIFF(mm,0,getdate()), 0)

本月的最后一天
SELECT dateadd(ms,-3,DATEADD(mm, DATEDIFF(m,0,getdate())+1, 0))

[DigJim]

http://expert.csdn.net/Expert/FAQ/FAQ_Index.asp?id=182715

本周的星期一
SELECT DATEADD(wk, DATEDIFF(wk,0,getdate()), 0)

一年的第一天
SELECT DATEADD(yy, DATEDIFF(yy,0,getdate()), 0)

季度的第一天
SELECT DATEADD(qq, DATEDIFF(qq,0,getdate()), 0)


去年的最后一天
SELECT dateadd(ms,-3,DATEADD(yy, DATEDIFF(yy,0,getdate()), 0))

本月的最后一天
SELECT dateadd(ms,-3,DATEADD(mm, DATEDIFF(m,0,getdate())+1, 0))

本年的最后一天
SELECT dateadd(ms,-3,DATEADD(yy, DATEDIFF(yy,0,getdate())+1, 0))。

本月的第一个星期一
select DATEADD(wk, DATEDIFF(wk,0,
dateadd(dd,6-datepart(day,getdate()),getdate())
), 0)


---------------------------------------------------------------------------------
1)去掉时分秒
declare @ datetime
set @ = getdate() --'2003-7-1 10:00:00'
SELECT @,DATEADD(day, DATEDIFF(day,0,@), 0)

2）显示星期几
select datename(weekday,getdate())

3）如何取得某个月的天数
declare @m int
set @m=2 --月份
select datediff(day,'2003-'+cast(@m as varchar)+'-15' ,'2003-'+cast(@m+1 as varchar)+'-15')
另外，取得本月天数
select datediff(day,cast(month(GetDate()) as varchar)+'-'+cast(month(GetDate()) as varchar)+'-15' ,cast(month(GetDate()) as varchar)+'-'+cast(month(GetDate())+1 as varchar)+'-15')
或者使用计算本月的最后一天的脚本，然后用DAY函数区最后一天
SELECT Day(dateadd(ms,-3,DATEADD(mm, DATEDIFF(m,0,getdate())+1, 0)))

4）判断是否闰年：
SELECT case day(dateadd(mm, 2, dateadd(ms,-3,DATEADD(yy, DATEDIFF(yy,0,getdate()), 0)))) when 28 then '平年' else '闰年' end
或者
select case datediff(day,datename(year,getdate())+'-02-01',dateadd(mm,1,datename(year,getdate())+'-02-01'))
when 28 then '平年' else '闰年' end

5）一个季度多少天
declare @m tinyint,@time smalldatetime
select @m=month(getdate())
select @m=case when @m between 1 and 3 then 1
when @m between 4 and 6 then 4
when @m between 7 and 9 then 7
else 10 end
select @time=datename(year,getdate())+'-'+convert(varchar(10),@m)+'-01'
select datediff(day,@time,dateadd(mm,3,@time))

[playyuer]

declare @ datetime
set @ = getdate()

select dateadd(day,datediff(day,0,dateadd(day,-day(@)+1,@)),0)
,dateadd(day,-day(@)+1,@)
,dateadd(day,datediff(day,0,dateadd(day,-1,dateadd(month,1,dateadd(day,-day(@)+1,@)))),0)
,dateadd(day,-1,dateadd(month,1,dateadd(day,-day(@)+1,@)))