有关INI文件的操作问题----在线等.及时给分

[yunfengh]

在一个窗体中有一个comtab,主要记录当前的数据表
现我要把它保存在INI文件中.

r1 = WritePrivateProfileString("MAXxlh", "MAXxlh", entry1, iniPath)
现我要把maxxlh 变成动态的COMTAB中的值

不知怎样在WritePrivateProfileString中用.请教一下.最好给出完整的代码.

[SoHo_Andy]

'使用INI的方式存取文件参数
'在d盘根目录新建 aaa.ini文件

'模拟程序
'模块中
Option Explicit

'-------------------------
'声明
Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long
Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long

'获得设置
Public Function MyGetSetting(Section As String, KeyName As String, DefaultValue As String) As String

Dim X As Long
Dim Holder As String * 255

X = GetPrivateProfileString(Section, KeyName, DefaultValue, Holder, 254, "d:\aaa.ini")
MyGetSetting = Left$(Holder, InStr(Holder, Chr$(0)) - 1)

End Function

'保存设置
Public Sub MySetSetting(Section As String, KeyName As String, KeyValue As String)

Dim X As Long

X = WritePrivateProfileString(Section, KeyName, KeyValue, "d:\aaa.ini")

End Sub

'窗体中
Private Sub Command1_Click()
'保存变量
MySetSetting "表名", "表名", comtab.text
MsgBox "保存成功"
End Sub

Private Sub Command2_Click()
'取出变量
MsgBox MyGetSetting("表名", "表名", "")
End Sub

[yunfengh]

谢谢.问题已经。