双11狂欢大促

盲盒赢 定制羽绒服

开启惊喜盲盒，抽取你的专属好礼

— 惊喜奖品抢先看 —

超级年卡50元券

周边70元券

手机支架

一拖三数据线

雨伞

运动毛巾

电动牙刷

VIP月卡

机械键盘

定制羽绒服

超级年卡50元券

周边70元券

手机支架

一拖三数据线

雨伞

运动毛巾

电动牙刷

VIP月卡

机械键盘

定制羽绒服

如何知道一个文件有多少行？

2004-03-16 05:08:23 155 阅读 AI 写同款 · GEO 优化AI 选题数据监测一键分发 ›

fernery 墨衍会员 · AI 创作全网分发关注 + 加入社区

文件中随机读取行问题 1. 有一个文件，如何在不知道有多少行的情况下读取该文件，从中随机选择并输出一行当我们读取第 i (i > 0) 行时，以 1 / i 的概率选择第 i 行，并替换掉原来选的行。即总选择第一行，并以概率 1 / 2 选择第 2 行，以概率 1 / 3 选择第 3 行，依次类推。到文件结束时，每个行被选中的概率都相等。 #include #include #include 阅读详情

i=0
Do While Not EOF(1)
Line Input #1, str1
i=i+1
loop
close #1
这个方法可行，但是太慢有无其他方法可以快速知道文件有多少？

...全文

python读取文件指定行的三种方法本文通过4个测试案例分析了在python中读取文件指定行内容的方案，并得到了一些运行耗时的数据。从需求上来说，如果是对于小规模的数据，比如几百行规模的数据，建议使用readline循环遍历来操作，速度也相当不错，或者是linecache中的函数实现也是可以的，甚至可以直接用readlines将整个文本内容加载到内存中。但是对于数据规模比较大的场景，比如超过了千万行的级别，那么使用sed指令的方式对指定行内容进行读取的方式，应该是所有方式中最快速的。阅读详情

fernery

VB基础类 7,788 成员 197,583 内容

+ 关注 + 加入社区

切换为时间正序

Hanan 2004-03-17

打赏
举报

先将文件读如一个缓存，strBuffer

然后：

　　intLines = Len(strBuffer) - Len(Replace(strBuffer, vbCr, "")) + 1

flyingZFX 2004-03-17

打赏
举报

太好了，先UP一下

reminious 2004-03-17

打赏
举报

'注释 file.path=app.path
'对当前某个文件的行数的读取计算
Dim hT1 As Integer, hCount As Integer, hFreeNumber As Integer
Dim tmp As String
tmp = ""
hCount = 0
For hT1 = 0 To File.ListCount - 1
If File.Selected(hT1) = True Then
hFreeNumber = FreeFile
If Len(dir.Path) > 3 Then
Open dir.Path + "\" + File.List(hT1) For Input As #hFreeNumber
Else
Open dir.Path + File.List(hT1) For Input As #hFreeNumber
End If

While Not EOF(hFreeNumber)
Line Input #hFreeNumber, tmp
hCount = hCount + 1
If tmp = "" Then hCount = hCount - 1
Wend

Close #hFreeNumber
End If
Next
MsgBox "计算完毕!"
labTot.Caption = "档案总共行数" + Chr$(13) + Chr$(10) + Str$(hCount)

vikingleo 2004-03-17

打赏
举报

mark

mmcgzs 2004-03-17

打赏
举报

高手如云

KiteGirl 2004-03-16

打赏
举报

以下是测试数据：

tText = TextGetByFile("SY2.txt")
Text1.Text = TextLineCountGet(tText)

编译前：1.375秒
编译后：0.328125（简易版）

tText = TextGetByFile("SY2.txt")
Text1.Text = UBound(Split(tText, Chr(13) & Chr(10)))

编译前：0.1640625
编译后：0.171875

由此可见，用Split函数是最快的办法。

KiteGirl 2004-03-16

打赏
举报

测试语句：（SY2.txt为金庸《神雕侠侣》全文，1863K，8493行。编译后速度很快。）
tText = TextGetByFile("SY2.txt") '从文件获得文本
Text1.Text = TextLineCountGet(tText) '测试文本的行数
Text2.Text = TextLineCountGet_ForView(tText, Text2) '测试文本的行数，并在工作的同时于Text2显示百分比进度。

Function TextLineCountGet(ByVal pText As String) As Long
'简易版
Dim tOutLng As Long
Dim tBytes() As Byte
Dim tIndex As Long
Dim tIndexOver As Long

tBytes() = StrConv(pText, vbFromUnicode)
tIndexOver = UBound(tBytes)

For tIndex = 0 To tIndexOver
tOutLng = tOutLng + ((tBytes(tIndex) = 13) And 1)
'以上相当于语句：If tBytes(tIndex) = 13 Then tOutLng = tOutLng + 1
Next

TextLineCountGet = tOutLng
End Function

Function TextLineCountGet_ForView(ByVal pText As String, Optional pViewTextBox As TextBox) As Long
'进度指示版。可完全按照TextLineCountGet来用，当你指定pViewTextBox后，会在该TextBox显示进度。
Dim tOutLng As Long
Dim tBytes() As Byte
Dim tIndex As Long
Dim tIndexOver As Long
Dim tEventStep As Long

tOutLng = (Len(pText) > 1) And 1

If CBool(tOutLng) Then

tBytes() = StrConv(pText, vbFromUnicode)
tIndexOver = UBound(tBytes)

tEventStep = (tIndexOver \ 100) + ((tIndexOver < 100) And 1)
'显示刷新步长计算：本算法可防止tEventStep=0

For tIndex = 0 To tIndexOver
tOutLng = tOutLng + ((tBytes(tIndex) = 13) And 1)
'以上相当于语句：If tBytes(tIndex) = 13 Then tOutLng = tOutLng + 1

If Not CBool(tIndex Mod tEventStep) Then
If Not pViewTextBox Is Nothing Then
pViewTextBox.Text = tIndex * 100 \ tIndexOver
DoEvents
End If
End If
Next

End If

TextLineCountGet_ForView = tOutLng
End Function

Function TextGetByFile(ByVal pFileName As String) As String
'从文件获得多行文本。
Dim tOutText As String
Dim tFileNumber As Integer
Dim tBytes() As Byte
tFileNumber = FreeFile
Open pFileName For Binary As #tFileNumber
If CBool(LOF(tFileNumber)) Then
ReDim tBytes(LOF(tFileNumber) - 1)
Get tFileNumber, 1, tBytes()
tOutText = StrConv(tBytes, vbUnicode)
Else
MsgBox "警告：文件" & pFileName & "是空的！", vbOKOnly, "文件无内容"
End If
Close #tFileNumber
TextGetByFile = tOutText
End Function

KiteGirl 2004-03-16

打赏
举报

还可以这样：
Private Sub Command2_Click()
Dim tBytes() As Byte
Dim tFileSize As Long
Dim tIndex As Long
Dim tIndexOver As Long
Dim tLineCount As Long
Open "SY.txt" For Binary As #1
tFileSize = LOF(1) - 1
ReDim tBytes(tFileSize)
tIndexOver = tFileSize
Get #1, 1, tBytes()
Close #1
For tIndex = 0 To tIndexOver
tLineCount = tLineCount + ((tBytes(tIndex) = 13) And 1)
Next
Text1.Text = tLineCount
End Sub
稍后给你函数。

pigpag 2004-03-16

打赏
举报

应该不会。

一般，做成普通文件和数据库，两者速度上有本质区别。否则无论用什么手段，速度基本上不会有本质提高。因为其本质是要找一个文件中有多少换行符Chr(10)

TIANHEI 2004-03-16

打赏
举报

用filesystemobject会不会快些？

yoki 2004-03-16

打赏
举报

Dim cn As New ADODB.Connection
Dim rs As New ADODB.Recordset
cn.CursorLocation = adUseClient
cn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=c:\;Extended Properties=Text;Persist Security Info=False;Mode=Share Deny None"
rs.Open "select 1 from [test#txt]", cn
Debug.Print "文本c:\test.txt共有行数为：" & rs.RecordCount
rs.Close
cn.Close
Set rs = Nothing
Set cn = Nothing

rainstormmaster 2004-03-16

打赏
举报

如果文件特别大的话，建议以数据库方式进行操作，这样速度会有根本性的提高

rainstormmaster 2004-03-16

打赏
举报

dim mfile as string
mfile="c:\test.txt"
dim buff() as byte
dim i as long
i=filelen(mfile)
redim buff(i-1)
open mfile for binary as #1
get #1,,buff
close #1
dim s as string
s=strconv(buff,vbunicode)
erase buff
dim arr() as string
arr=split(s,vbcrlf)
msgbox "文件共有行数："+cstr(ubound(arr)+1)

✦双11狂欢大促✦

如何知道一个文件有多少行？

相关推荐

双11狂欢大促