在Delphi里怎么使用函数指针？

[onehawk]

在Delphi里怎么使用函数指针？
尤其是这个函数指针要当作一个函数的参数的时候？

[manfeng]

type
funcptr=function(param1:word):integer;

var
f:funcptr;

function fun(param1:word):integer;
function acceptfun(funparam:funcptr):integer;

f:=fun;

funcptr就是一个函数指针类型,f就是一个函数指针f:=fun就把函数指针f指向fun;
acceptfun就是一个接受函数指针的函数acceptfun(fun)就是把函数fun作为函数指针参数传递给acceptfun;

[onehawk]

我查了好多资料都查不到，用Pascal的方式又不行，
请问 manfeng() 兄是从那得来的资料，还是您自己摸出来的？
因为我还有一些类似的小问题，我想系统的学一下Delphi指针方面的知识。

[manfeng]

怎么会，这种语法标准pascal就支持

[onehawk]

pascal形式:
function fun1(x:real):real;
function fun2(x:real):real;
function acceptfun(function f(x:real):real;a,b:real)real;

这种形式在delphi里不行的

[manfeng]

是的，turbo pascal一直都需要把函数指针型变量声明为一个类型才能用，不能直接在函数参数里面声明，这个一直没改变。这可能和pascal的强类型有关，因为不先声明为一个类型那么即使两个变量的声明方法一直都作为两种不同类型，这个要注意

[lwk_hlj]

delphi内部调用全是指针形式的
据说当年那个设计者有 全是指针先生的 称谓啊

manfeng说的差不多，

Pacal的指针

原文(nicrosoft于2001/08/26 21:19粘贴)

浅谈Object Pascal的指针

--------------------------------------------------------------------------------

　

浅谈Object Pascal的指针

Nicrosoft([e-mail]) 2001.8.26

(http://www.sunistudio.com/asp/sunidoc.asp)

大家都认为，C语言之所以强大，以及其自由性，很大部分体现在其灵活的指针运用上。因此，说指针是C语言的灵魂，一点都不为过。同时，这种说法也让很多人产生误解，似乎只有C语言的指针才能算指针。Basic不支持指针，在此不论。其实，Pascal语言本身也是支持指针的。从最初的Pascal发展至今的Object Pascal，可以说在指针运用上，丝毫不会逊色于C语言的指针。

以下内容分为八部分，分别是

一、类型指针的定义

二、无类型指针的定义

三、指针的解除引用

四、取地址（指针赋值）

五、指针运算

六、动态内存分配

七、字符数组的运算

八、函数指针

　

一、类型指针的定义。对于指向特定类型的指针，在C中是这样定义的：

int *ptr;

char *ptr;

与之等价的Object Pascal是如何定义的呢？

var

ptr : ^Integer;

ptr : ^char;

其实也就是符号的差别而已。

二、无类型指针的定义。C中有void *类型，也就是可以指向任何类型数据的指针。Object Pascal为其

定义了一个专门的类型：Pointer。于是，

ptr : Pointer;

就与C中的

void *ptr;

等价了。

三、指针的解除引用。要解除指针引用（即取出指针所指区域的值），C 的语法是 (*ptr)，Object

Pascal则是 ptr^。

四、取地址（指针赋值）。取某对象的地址并将其赋值给指针变量，C 的语法是

ptr = &Object;

Object Pascal 则是

ptr := @Object;

也只是符号的差别而已。

五、指针运算。在C中，可以对指针进行移动的运算，如：

char a[20];

char *ptr=a;

ptr++;

ptr+=2;

当执行ptr++;时，编译器会产生让ptr前进sizeof(char)步长的代码，之后，ptr将指向a

[1]。ptr+=2;这句使得ptr前进两个sizeof(char)大小的步长。同样，我们来看一下Object Pascal中如何实

现：

var

a : array [1..20] of Char;

ptr : PChar; //PChar 可以看作 ^Char

begin

ptr := @a;

Inc(ptr); // 这句等价于 C 的 ptr++;

Inc(ptr, 2); //这句等价于 C 的 ptr+=2;

end;

只是，Pascal中，只允许对有类型的指针进行这样的运算，对于无类型指针是不行的。

六、动态内存分配。C中，使用malloc()库函数分配内存，free()函数释放内存。如这样的代码：

int *ptr, *ptr2;

int i;

ptr = (int*) malloc(sizeof(int) * 20);

ptr2 = ptr;

for (i=0; i<20; i++){

*ptr = i;

ptr++;

}

free(ptr2);

Object Pascal中，动态分配内存的函数是GetMem()，与之对应的释放函数为FreeMem()（传统

Pascal中获取内存的函数是New()和 Dispose()，但New()只能获得对象的单个实体的内存大小，无法取得连

续的存放多个对象的内存块）。因此，与上面那段C的代码等价的Object Pascal的代码为：

var ptr, ptr2 : ^integer;

i : integer;

begin

GetMem(ptr, sizeof(integer) * 20);

//这句等价于C的 ptr = (int*) malloc(sizeof(int) * 20);

ptr2 := ptr; //保留原始指针位置

for i := 0 to 19 do

begin

ptr^ := i;

Inc(ptr);

end;

FreeMem(ptr2);

end;

对于以上这个例子（无论是C版本的，还是Object Pascal版本的），都要注意一个问题，就是分配

内存的单位是字节（BYTE），因此在使用GetMem时，其第二个参数如果想当然的写成 20，那么就会出问题

了（内存访问越界）。因为GetMem(ptr, 20);实际只分配了20个字节的内存空间，而一个整形的大小是四个

字节，那么访问第五个之后的所有元素都是非法的了（对于malloc()的参数同样）。

七、字符数组的运算。C语言中，是没有字符串类型的，因此，字符串都是用字符数组来实现，于是也

有一套str打头的库函数以进行字符数组的运算，如以下代码：

char str[15];

char *pstr;

strcpy(str, "teststr");

strcat(str, "_testok");

pstr = (char*) malloc(sizeof(char) * 15);

strcpy(pstr, str);

printf(pstr);

free(pstr);

而在Object Pascal中，有了String类型，因此可以很方便的对字符串进行各种运算。但是，有时

我们的Pascal代码需要与C的代码交互（比如：用Object Pascal的代码调用C写的DLL或者用Object Pascal

写的DLL准备允许用C写客户端的代码）的话，就不能使用String类型了，而必须使用两种语言通用的字符数

组。其实，Object Pascal提供了完全相似C的一整套字符数组的运算函数，以上那段代码的Object Pascal

版本是这样的：

var str : array [1..15] of char;

pstr : PChar; //Pchar 也就是 ^Char

begin

StrCopy(@str, 'teststr'); //在C中，数组的名称可以直接作为数组首地址指针来用

//但Pascal不是这样的，因此 str前要加上取地址的运算符

StrCat(@str, '_testok');

GetMem(pstr, sizeof(char) * 15);

StrCopy(pstr, @str);

Write(pstr);

FreeMem(pstr);

end;

八、函数指针。在动态调用DLL中的函数时，就会用到函数指针。假设用C写的一段代码如下：

typedef int (*PVFN)(int); //定义函数指针类型

int main()

{

HMODULE hModule = LoadLibrary("test.dll");

PVFN pvfn = NULL;

pvfn = (PVFN) GetProcAddress(hModule, "Function1");

pvfn(2);

FreeLibrary(hModule);

}

就我个人感觉来说，C语言中定义函数指针类型的typedef代码的语法有些晦涩，而同样的代码在

Object Pascal中却非常易懂：

type PVFN = Function (para : Integer) : Integer;

var

fn : PVFN;

//也可以直接在此处定义，如：fn : function (para:Integer):Integer;

hm : HMODULE;

begin

hm := LoadLibrary('test.dll');

fn := GetProcAddress(hm, 'Function1');

fn(2);

FreeLibrary(hm);

end;


你看看

[lwk_hlj]

一个回调例子
如何捕获TTreeView中滚动条滚动的动作
好不丫给你骂一顿，我招你了老哥？咱给您写段吧，“喷嚏震天响”兄的方法也行，您也可

以用他的方法写个VCL控件，可以添加进两个事件响应句柄。其实还有几个方法，但咱这个

比较简单，写个回调函数就完事了。咱没有试着用（没有装Delphi），纯粹瞎掰，不好使您

别骂我。

申明部分：

...

private

FClientInstance,

FPrevClientProc : TFarProc;

procedure ClientWndProc(var Message: TMessage);

...

实现部分：

procedure TForm1.FormCreate(Sender: TObject);

begin

FClientInstance := MakeObjectInstance(ClientWndProc);

FPrevClientProc := Pointer(GetWindowLong(TreeView1.Handle, GWL_WNDPROC));

{ 保存默认窗口回调函数指针，TreeView1.Handle 是需要监控的TreeView的句柄 }

SetWindowLong(ClientHandle, GWL_WNDPROC, LongInt(FClientInstance));

{ 设置自定义窗口回调函数 }

end;

procedure TForm1.ClientWndProc(var Message: TMessage);

begin

case Message.Msg of

WM_VSCROLL:

begin

{ 干您的好事，处理WM_VSCROLL消息，垂直滚动条变化消息 }

end;

WM_HSCROLL:

begin

{ 干您的好事，处理WM_HSCROLL消息，水平滚动条变化消息 }

end;

else

Result := CallWindowProc(FPrevClientProc, ClientHandle, Msg, wParam,

lParam);

{ 调用默认窗口回调函数处理其它消息 }

end;

end;

*********************

unit Unit1;

interface

uses

Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,

ComCtrls;

type

TForm1 = class(TForm)

TreeView1: TTreeView;

procedure FormCreate(Sender: TObject);

private

FClientInstance,

FPrevClientProc : TFarProc;

procedure ClientWndProc(var Message: TMessage);

public

{ Public declarations }

end;

var

Form1: TForm1;

implementation

{$R *.DFM}

procedure TForm1.FormCreate(Sender: TObject);

begin

FClientInstance := MakeObjectInstance(ClientWndProc);

FPrevClientProc := Pointer(GetWindowLong(TreeView1.Handle, GWL_WNDPROC));

SetWindowLong(TreeView1.Handle, GWL_WNDPROC, LongInt(FClientInstance));

end;

procedure TForm1.ClientWndProc(var Message: TMessage);

begin

case Message.Msg of

WM_VSCROLL:

begin

ShowMessage ('wm_vscroll 事件');

end;

WM_HSCROLL:

begin

ShowMessage ('wm_hscroll 事件');

end;

end;

Message.Result := CallWindowProc(FPrevClientProc,

ClientHandle, Message.Msg, Message.wParam, Message.lParam);

end;

end.

不好意思，前面回答的代码段没有调试就是有好多问题，以上代码调试通过，不过好像点击

一次滚动条会激活两次 WM_xSCROLL消息，你可以做一个判断来过虑。

　



这个对你应该有帮助

[onehawk]

谢谢manfeng和lwk_hlj.
你们的说明对我帮助很大。