还原数据库的时候报有人连接数据库无法还原怎么处理？

[Northwindrocker]

如题！我在企业管理器里面也没办法改数据库状态怎么办？

[zjcxc]

--查询分析器中执行下面的语句,断开用户连接,然后再还原.

/*
关闭用户打开的进程处理
*/
use master
go

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_killspid]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_killspid]
GO

create proc p_killspid
@dbname varchar(200) --要关闭进程的数据库名
as
declare @sql nvarchar(500)
declare @spid nvarchar(20)

declare #tb cursor for
select spid=cast(spid as varchar(20)) from master..sysprocesses where dbid=db_id(@dbname)
open #tb
fetch next from #tb into @spid
while @@fetch_status=0
begin
exec('kill '+@spid)
fetch next from #tb into @spid
end
close #tb
deallocate #tb
go

--用法
exec p_killspid '数据库名'

[zjcxc]

--或者用我这个存储过程来还原,可以自动断开用户连接

use master
go

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_RestoreDb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_RestoreDb]
GO

/*--恢复数据库的通用存储过程

--邹建 2003.10--*/

/*--调用示例
--完整恢复数据库
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db'

--差异备份恢复
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db',@retype='DBNOR'
exec p_backupdb @bkfile='c:\db_20031015_df.bak',@dbname='db',@retype='DF'

--日志备份恢复
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db',@retype='DBNOR'
exec p_backupdb @bkfile='c:\db_20031015_log.bak',@dbname='db',@retype='LOG'

--*/

create proc p_RestoreDb
@bkfile nvarchar(1000), --定义要恢复的备份文件名
@dbname sysname='', --定义恢复后的数据库名,默认为备份的文件名
@dbpath nvarchar(260)='', --恢复后的数据库存放目录,不指定则为SQL的默认数据目录
@retype nvarchar(10)='DB', --恢复类型:'DB'完事恢复数据库,'DBNOR' 为差异恢复,日志恢复进行完整恢复,'DF' 差异备份的恢复,'LOG' 日志恢复
@filenumber int=1, --恢复的文件号
@overexist bit=1, --是否覆盖已经存在的数据库,仅@retype为'DB'/'DBNOR'是有效
@killuser bit=1, --是否关闭用户使用进程,仅@overexist=1时有效
@password nvarchar(20)='' --备份文件的密码(仅sql2000支持),如果备份时设置了密码,必须提供此密码
as
declare @sql varchar(8000)

--得到恢复后的数据库名
if isnull(@dbname,'')=''
select @sql=reverse(@bkfile)
,@sql=case when charindex('.',@sql)=0 then @sql
else substring(@sql,charindex('.',@sql)+1,1000) end
,@sql=case when charindex('\',@sql)=0 then @sql
else left(@sql,charindex('\',@sql)-1) end
,@dbname=reverse(@sql)

--得到恢复后的数据库存放目录
if isnull(@dbpath,'')=''
begin
select @dbpath=rtrim(reverse(filename)) from master..sysfiles where name='master'
select @dbpath=reverse(substring(@dbpath,charindex('\',@dbpath),4000))
end

--生成数据库恢复语句
set @sql='restore '+case @retype when 'LOG' then 'log ' else 'database ' end+@dbname
+' from disk='''+@bkfile+''''
+' with file='+cast(@filenumber as varchar)
+case when @overexist=1 and @retype in('DB','DBNOR') then ',replace' else '' end
+case @retype when 'DBNOR' then ',NORECOVERY' else ',RECOVERY' end
+case isnull(@password,'') when '' then '' else ',PASSWORD='''+@password+'''' end

--添加移动逻辑文件的处理
if @retype='DB' or @retype='DBNOR'
begin
--从备份文件中获取逻辑文件名
declare @lfn nvarchar(128),@tp char(1),@i int,@s varchar(1000)

--创建临时表,保存获取的信息
create table #tb(ln nvarchar(128),pn nvarchar(260),tp char(1),fgn nvarchar(128),sz numeric(20,0),Msz numeric(20,0))
--从备份文件中获取信息
set @s='restore filelistonly from disk='''+@bkfile+''''
++case isnull(@password,'') when '' then '' else ' with PASSWORD='''+@password+'''' end
insert into #tb exec(@s)
declare #f cursor for select ln,tp from #tb
open #f
fetch next from #f into @lfn,@tp
set @i=0
while @@fetch_status=0
begin
select @sql=@sql+',move '''+@lfn+''' to '''+@dbpath+@dbname+cast(@i as varchar)
+case @tp when 'D' then '.mdf''' else '.ldf''' end
,@i=@i+1
fetch next from #f into @lfn,@tp
end
close #f
deallocate #f
end

--关闭用户进程处理
if @overexist=1 and @killuser=1
begin
declare @spid varchar(20)
declare #spid cursor for
select spid=cast(spid as varchar(20)) from master..sysprocesses where dbid=db_id(@dbname)
open #spid
fetch next from #spid into @spid
while @@fetch_status=0
begin
exec('kill '+@spid)
fetch next from #spid into @spid
end
close #spid
deallocate #spid
end

--恢复数据库
exec(@sql)

go

[progress99]

重啟服務，再用你的代碼恢復。

[progress99]

(黄山光明顶)
你是可以通过KILL @SPID来断开所有的CLIENT的连接,不过这样做非常的不安全,你可以
通过将SQL SERVER配置为单用户模式来达到这样的目的,这样操作的好处是:
1.安全;
2.可以指定进行事务回滚;
3.可以指定时间;

比如:
1.通过使用ROLLBACK IMMEDIATE命令,可以在将数据库置于单用户时立即断开所有的连
接:
ALTER DATABASE NORTHWIND
SET SINGLE_USER
with rollback immediate

2.最好的方式时提供一段时间,以便CLIENT可以完成事务(下面延迟60s):
ALTER DATABASE NORTHWIND
SET SINGLE_USER
with ROLLBACK AFTER 60 SECONDS

3.完成修复或备份之后,可以在恢复多用户模式:
ALTER DATABASE NORTHWIND
SET MULTI_USER
4.REBOOT 服务器;

[Northwindrocker]

邹大侠，我昨天晚上看了所有的这里关于数据库还原的帖子！还是没有办法把数据库置于 single user状态！你的procdure我用了没作用，看了其他的帖子
如下面的关于怎么把数据库置于single user 的状态
*********************************************************
如何恢复系统数据库？

关于系统数据库的恢复总结如下:
　　在SQL Server数据库中，系统信息存储在系统数据库中，主要的系统数据库包括：
　　master-从整体上控制用户数据库和SQL Server操作，在创建了任何用户定义的对象后，都要备份它
　　model-为新数据库提供模版和原型
　　msdb-包含了有关作业、报警及操作员等信息如果包含系统数据库的介质变了，那么必须重建系统数据库，如果你仍然可以启动SQL Server服务，则可以通过RESTORE语句从系统数据库的备份中恢复数据库。
　　如果master坏了，不能启动系统,可以按照下面步骤进行恢复
1 重建系统数据库 运行c:\mssql7\binn\rebuildm.exe，按照提示进行即可，过

程中需要系统数据库样本的路径，可在安装光盘中找到；

2 重建系统数据库后，启动SQL Server服务，用系统数据库的备份恢复数据库就

行了通常恢复顺序为master->msdb->model
在恢复master的备份时要注意：必须在single user模式下进行，有以下几种方法

进入单用户模式：
1 可以在命令行模式下输入sqlservr -c -f -m或者输入sqlservr -m
其中：-c 可以缩短启动时间，SQL Server 不作为Windows NT的服务启动
-f 用最小配置启动SQL Server
-m 单用户模式启动SQL Server
2 可以在控制面板-服务-MSSQLServer的启动参数中输入-c -f -m或者输入-m,点

击开始

3 还有一种更灵活的启动方法：用存在注册表里的启动参数启动
在MSSQLServer项下添加项SingleUser,具体内容如下所示：
HKEY_LOCAL_MACHINE
\Software
\Microsoft
\MSSQLServer
\SingleUser
\Parameters
SQLArg0 : REG_SZ : -dC:\MSSQL7\DATA\MASTER.DAT
SQLArg1 : REG_SZ : -eC:\MSSQL7\LOG\ERRORLOG
SQLArg2 : REG_SZ : -lC:\MSSQL7\DATA\MASTLOG.DAT
SQLArg3 : REG_SZ : -m
在命令行下输入SQLServr -c -sSingleUser,注意：必须是在命令行下进入单用户模式后启动 Query Analyzer执行语句：
RESTORE DATABASE master form disk='c:\(具体的备份文件名）
**********************************
我用第一种办法成功了，但是在single user 的状态下面没办法恢复master以外的其他数据库！
用其他的办法恢复这里有的我都试过！EM里面，QA里面用restore都没有作用！昨天晚上就为了这个还原搞到12：30还是没结果！不知道怎么办好！

[javaCandelaboy]

还不如重新启动sql服务器，然后还原就没有问题了

[Northwindrocker]

************************************************
黄山光明顶)
你是可以通过KILL @SPID来断开所有的CLIENT的连接,不过这样做非常的不安全,你可以
通过将SQL SERVER配置为单用户模式来达到这样的目的,这样操作的好处是:
1.安全;
2.可以指定进行事务回滚;
3.可以指定时间;

比如:
1.通过使用ROLLBACK IMMEDIATE命令,可以在将数据库置于单用户时立即断开所有的连
接:
ALTER DATABASE NORTHWIND
SET SINGLE_USER
with rollback immediate

2.最好的方式时提供一段时间,以便CLIENT可以完成事务(下面延迟60s):
ALTER DATABASE NORTHWIND
SET SINGLE_USER
with ROLLBACK AFTER 60 SECONDS

3.完成修复或备份之后,可以在恢复多用户模式:
ALTER DATABASE NORTHWIND
SET MULTI_USER
4.REBOOT 服务器;
****************************************************

这个方法是有效的，我搞不懂了！我用sp_dboption不能用但是今天早上用上面的alter database却没问题！！！！我靠！M$!!!!!!!!!通过上面的alter database改变为单用户状态后还原没问题!
我日！！！！！！

[Northwindrocker]

javaCandelaboy(java初学着)

还不如重新启动sql服务器，然后还原就没有问题了
**************************************
你真这么还原个数据库试试！！！：）