vb中如何用系统打印机打印啊？保证给分

2004-04-12 09:00:48 122 阅读 AI 写同款 · GEO 优化AI 选题数据监测一键分发 ›

归并排序与原地归并排序归并排序的思想：假设初始序列含有n个记录，则可以看成是n个有序的子序列，每个子序列的长度为1，然后两两归并，得到[n/2]个长度为2或1的有序子序列；再两两归并，如此重复，直至得到一个长度为n的有序序列为止，这种排序方法称为2-路归并排序。其核心操作是将一个一维数组的前后相邻的两个子序列合并为一个有序序列。下图为一个2路归并排序的例子。阅读详情

我想在用VB实现打印功能，可是打印的列总是对不齐，有谁能提供一段代码吗？谢谢！

...全文

分而治之篇1--归并排序 1.问题背景杠铃增重问题每位参赛运动员向组委会提交排好序的三次试举重量为便于杠铃拆卸，组委会需对所有试举重量递增排序杠铃增重顺序：125 130 132 123 127 129 117 121 126 116 120 122 问题：组委会如何根据试举重量安排杠铃增重顺序? 选择排序从待排序元素中迭代选出最小值并排序比较次数：???????? 次插... 阅读详情

donner123

VB基础类 7,788 成员 197,583 内容

+ 关注 + 加入社区

切换为时间正序

donner123 2004-04-12

打赏
举报

到Printer.Print (mS)的时候提示printer error，怎么回事啊？我的打印机已经连了。

啊维 2004-04-12

打赏
举报

'在指定位置打印字符内容
'参数：打印内容，控件ID，字体，字号，起点（左上角）坐标X、Y值，终点（右下角）坐标X、Y值
' 水平对齐方式，垂直对齐方式，字距，行距
'一行当中最高的字符高度+行距作为占高
'如果宽度合计小于mX2-mX1,则只有一行；
'如果高度累计值>mY2-mY1,说明在指定的范围内无法容下全部字符，不需考虑垂直对中。

Public Sub mPrintStr(Optional mStringVal As String = "", _
Optional mFontName As String = "宋体", Optional mFontSize As Single = 10, Optional mX1 As Single = 0, _
Optional mY1 As Single = 0, Optional mX2 As Single = 0, Optional mY2 As Single = 0, Optional mAlign_V As Integer = 0, _
Optional mAlign_H As Integer = 0, Optional mWSpace As Single = 0, Optional mLSpace As Single = 0)

'字符串 mStringVal 中字符的预号
Dim I As Long
'字符串 mStringVal 中当前指定的字符（第i个）
Dim mS As String
'宽度和高度合计
Dim mWTotal As Single, mHTotal As Single
'一行中最高的字符的高度
Dim mMaxH As Single
'第一行中最高的字符的高度
Dim mMaxHFL As Single
'最后一行的行编号
Dim mLastLineNum As Long
'最后一行的字符宽度合计
Dim mLastLineWidth As Single
'当前行第一个字符打印位置
Dim mX As Single, mY As Single
'当前打印行的编号
Dim mLine As Long

If mStringVal = "" Then Exit Sub
' mX1 = 0 Or _
' mY1 = 0 Or _
' mX2 = 0 Or _
' mY2 = 0 Then Exit Sub

' '如果有指定的控件，则要先从设定表中读入相关的参数（字体、位置...）
' '其实这一部分留给调用程序较好
' If mControlID > 0 Then
'
' End If
mMaxH = 0
mWTotal = 0
'至少打印一行？？？
mLastLineNum = 1

With Printer
'定义计算单位为 mm
' .ScaleMode = vbMillimeters
.ScaleMode = vbTwips
.FontName = mFontName
.FontSize = mFontSize

'显示用的
' frmPrintRenStat.Picture1.ScaleMode = vbMillimeters
' frmPrintRenStat.Picture1.ScaleMode = 1
' frmPrintRenStat.Picture1.FontName = .FontName
' frmPrintRenStat.Picture1.FontSize = .FontSize

'----------------------预计打印位置,求出总高度、总行数、最后一行的总宽度-----------------------------------

For I = 1 To Len(mStringVal)
'取出一个字符
mS = Mid(mStringVal, I, 1)
'若当前行还可以容下当前指定的字符，继续在当前行打印
If mWTotal <= mX2 - mX1 - .TextWidth(mS) + mWSpace Then
'取当前行最高的字符的高度值（如果当前字符高度>之前最高字符，则取当前字符作为
'本行最高字符，否则，保持原最高字符(已考虑行高调整值)
mMaxH = IIf(.TextHeight(mS) + mLSpace > mMaxH, .TextHeight(mS) + mLSpace, mMaxH)
End If

'必须换至下一行
If mWTotal > mX2 - mX1 - .TextWidth(mS) + mWSpace Then
'行高累加
mHTotal = mHTotal + mMaxH
'最后一行的编号
mLastLineNum = mLastLineNum + 1
'换到下一行
mMaxH = .TextHeight(mS) + mLSpace
mWTotal = 0
End If
'记下第一行的高度
If mLastLineNum = 1 Then
mMaxHFL = mMaxH
End If
'宽度累加
mWTotal = mWTotal + .TextWidth(mS) + mWSpace
Next I

'加上第一行高度，得到总行高
mHTotal = mHTotal + mMaxHFL
'记下最后一行的相关数据
mLastLineWidth = mWTotal

'----------------------------------------正式打印----------------------------------
mLine = 1

'若字符总高度小于给定的打印高度
If mHTotal < mY2 - mY1 Then
Select Case mAlign_H
'要求垂直方向顶端对齐的
Case 0
mY = mY1
'要求垂直方向对中的
Case 1
mY = mY1 + (mY2 - mY1 - mHTotal) / 2
'要求垂直方向底端对齐的
Case 2
mY = mY2 - mHTotal
End Select
Else
mY = mY1
End If

'若是最后一行，且水平方向要求对中的-------(更完善的方案用数组记下各行的宽度，每行都设置？)
If mLine = mLastLineNum Then
Select Case mAlign_V
'要求水平方向左对齐的
Case 0
mX = mX1
'要求水平方向对中的
Case 1
mX = mX1 + (mX2 - mX1 - mLastLineWidth) / 2
'要求水平方向右对齐的
Case 2
mX = mX2 - mLastLineWidth
End Select
Else
mX = mX1
End If

mS = ""
mMaxH = 0
mWTotal = 0
mHTotal = 0
For I = 1 To Len(mStringVal)
'取出一个字符
mS = Mid(mStringVal, I, 1)

'若当前行还可以容下当前指定的字符，继续在当前行打印
If mWTotal <= mX2 - mX1 - .TextWidth(mS) + mWSpace Then
'取当前行最高的字符的高度值（如果当前字符高度>之前最高字符，则取当前字符作为
'本行最高字符，否则，保持原最高字符(已考虑行高调整值)
mMaxH = IIf(.TextHeight(mS) + mLSpace > mMaxH, .TextHeight(mS) + mLSpace, mMaxH)

'打印当前字符
.CurrentX = mX + mWTotal
.CurrentY = mY + mHTotal
Printer.Print (mS)

'显示当前字符
' frmPrintRenStat.Picture1.CurrentX = mX + mWTotal
' frmPrintRenStat.Picture1.CurrentY = mY + mHTotal
' frmPrintRenStat.Picture1.Print (mS)
End If
If mWTotal > mX2 - mX1 - .TextWidth(mS) + mWSpace Then
'行高累加
mHTotal = mHTotal + mMaxH

'若已超出给定的高度，不再打印
If mHTotal > (mY2 - mY1) Then Exit Sub

'最后一行的编号
mLine = mLine + 1

'换到下一行
mMaxH = .TextHeight(mS) + mLSpace
mWTotal = 0

'若是最后一行，且水平方向要求对中的
If mLine = mLastLineNum Then
Select Case mAlign_V
'要求水平方向左对齐的
Case 0
mX = mX1
'要求水平方向对中的
Case 1
mX = mX1 + (mX2 - mX1 - mLastLineWidth) / 2
'要求水平方向右对齐的
Case 2
mX = mX2 - mLastLineWidth
End Select
Else
mX = mX1
End If

'打印当前字符
.CurrentX = mX + mWTotal
.CurrentY = mY + mHTotal
Printer.Print (mS)

'' 显示当前字符
' frmPrintRenStat.Picture1.CurrentX = .CurrentX
' frmPrintRenStat.Picture1.CurrentY = .CurrentY
' frmPrintRenStat.Picture1.Print (mS)
End If
'宽度累加
mWTotal = mWTotal + .TextWidth(mS) + mWSpace
Next I
' 或NewPage,在调用本过程之中，需要换页时
' .EndDoc
End With

End Sub

vb中如何用系统打印机打印啊？保证给分

相关推荐