关于SQL 导入导出到 Access时使用OPENROWSET出现的问题

[binshan]

本人有一个项目需要将数据在SQL和Access中导入导出，参考了txlicenhe (马可) 的贴子：
http://search.csdn.net/Expert/topic/2341/2341997.xml?temp=.1113245
使用了下的方法：

/*************导出到Access********************/
insert into openrowset('Microsoft.Jet.OLEDB.4.0',
'x:\A.mdb';'admin';'',A表) select * from 数据库名..B表

/*************导入Access********************/
insert into B表 selet * from openrowset('Microsoft.Jet.OLEDB.4.0',
'x:\A.mdb';'admin';'',A表)

-------------------------------------------------------------------
本人试过，如果是字段少，没有出现什么题，但字段多就会出题字段类型不匹配的问题，我的Access表是用SQL的DTS 导出时自动建的，数据类型对应关系应该没有问题，但我在SQL里运行时提示并不是，字段溢出这个的错误，是提示:
"不允许从数据类型 money 到 nvarchar 的隐性转换。请使用 CONVERT 函数来运行此查询。"
或者
“
服务器: 消息 7399，级别 16，状态 1，行 1
OLE DB 提供程序 'Microsoft.Jet.OLEDB.4.0' 报错。提供程序未给出有关错误的任何信息。
OLE DB 错误跟踪［OLE/DB Provider 'Microsoft.Jet.OLEDB.4.0' IOpenRowset::OpenRowset returned 0x80004005: 提供程序未给出有关错误的任何信息。］。”
的错误：

所以小弟认为，可能是SQL 表和ACCESS表字段之间的对应顺序不正确，现在小弟有两个问题请大侠帮忙

1。如何解决上面的数据不匹配的问题。
2。有没有方法在导出到ACCESS表时，能不能像导出到文本或者EXCEL一样自动建一个数据库和表。

[binshan]

没有人会吗？顶一下！

[zjcxc]

--这是字段名对应方面出了问题,建议楼主用这样的导出,写明字段对应关系:

insert into openrowset('Microsoft.Jet.OLEDB.4.0',
'x:\A.mdb';'admin';'',A表)(写上字段列表)
select 对应的字段列表 from 数据库名..B表

[zjcxc]

用openrowset/opendatasource处理外部数据库时,并不能保证字段顺序与原表中的字段顺序完全一致(不知道是否BUG),所以在字段对就不上的时候,就出现楼主说的问题了.

[weixy]

没有导过ACCESS，建议列出对应的字段
insert into B表(a, b, c, d) selet * from openrowset('Microsoft.Jet.OLEDB.4.0',
'x:\A.mdb';'admin';'','select a, b, c, d from A表')
试试

[weixy]

呵呵，高手已经到了。

[binshan]

我想也是像邹建大哥说的那样，可能是字段对应的问题，但是我想做的是一个通用的导出功能，也就是说不能定死字段名的，不知道各位有什么更好的办法呀？


别外，有没有办法解决第二个问题？

[zjcxc]

--你可以通过系统表 syscolumns 来得到你要导入的表的字段名嘛

--示例,这样可以生成指定表名的字段名列表

declare @s varchar(8000)
set @s=''
select @s=@s+',['+name+']' from syscolumns where id=object_id(N'要查询的表名')
set @s=stuff(@s,1,1,'')

--再配合你原来的那个导数据处理的语句,就基本上是通用的了(完善的功夫你自己做)
exec('insert into openrowset(''Microsoft.Jet.OLEDB.4.0'',
''x:\A.mdb'';''admin'';'''',A表)('+@s+')
select '+@s+' from 数据库名..B表
')

[zjcxc]

--第二个问题

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_exporttb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_exporttb]
GO

/*--数据导出Access

导出查询中的数据到Access

,如果文件不存在,将自动创建文件
,如果表存在,将覆盖现有的表
,支持所有数据类型的导入

--邹建 2004.04(引用请保留此信息)--*/

/*--调用示例

p_exporttb @sqlstr='select * from sysobjects'
,@path='c:\',@fname='test.mdb',@tbname='sysobjects'
--*/
create proc p_exporttb
@sqlstr varchar(8000), --查询语句,如果查询语句中使用了order by ,请加上top 100 percent
@path nvarchar(1000), --文件存放目录
@fname nvarchar(250), --文件名
@tbname varchar(250)='', --要创建的表名,默认为文件名
@password varchar(20)='', --ACCESS数据库的密码
@s_user sysname='', --如果提示连接错误,则需要提供登陆sql服务器的用户名及密码
@s_password varchar(50)=''
as
set nocount on
declare @err int,@src nvarchar(255),@desc nvarchar(255),@out int
declare @obj int,@constr nvarchar(1000),@sql varchar(8000)

--参数检测
if isnull(@fname,'')='' set @fname='temp.mdb'
if isnull(@tbname,'')='' set @tbname=replace(@fname,'.','#')

--检查文件是否已经存在
if right(@path,1)<>'\' set @path=@path+'\'
create table #tb(a bit,b bit,c bit)
set @sql=@path+@fname
insert into #tb exec master..xp_fileexist @sql

--数据库创建
select @sql=@path+@fname
,@constr='Provider=Microsoft.Jet.OLEDB.4.0;Data Source='+@sql
+case isnull(@password,'') when '' then ''
else ';Jet OLEDB:Database Password='+@password end

if not exists(select 1 from #tb where a=1)
begin
exec @err=sp_oacreate 'ADOX.Catalog',@obj out
if @err<>0 goto lberr

exec @err=sp_oamethod @obj,'Create',null,@constr
if @err<>0 goto lberr

exec @err=sp_oadestroy @obj
if @err<>0 goto lberr
end

--连接数据库
exec @err=sp_oacreate 'adodb.connection',@obj out
if @err<>0 goto lberr

exec @err=sp_oamethod @obj,'open',null,@constr
if @err<>0 goto lberr

--删除现有的表
set @sql='drop table ['+@tbname+']'
exec @err=sp_oamethod @obj,'execute',@out out,@sql
--if @err<>0 goto lberr

--导入表
declare @t_tbname sysname
set @t_tbname='##tmp_'+convert(varchar(38),newid())
set @sql='select * into ['+@t_tbname+'] from('+@sqlstr+') a'
exec(@sql)

if isnull(@s_user,'')=''
set @sql='SELECT * into ['+@tbname
+'] FROM [ODBC;Driver=SQL Server;Server='+ @@servername
+';database=tempdb].['+@t_tbname+']'
else
set @sql='SELECT * into ['+@tbname
+'] FROM [ODBC;Driver=SQL Server;Server='+ @@servername
+';Uid='+@s_user+';Pwd='+isnull(@s_password,'')
+';database=tempdb].['+@t_tbname+']'

exec @err=sp_oamethod @obj,'execute',@out out,@sql
if @err<>0 goto lberr

exec @err=sp_oadestroy @obj

set @sql='drop table ['+@t_tbname+']'
exec(@sql)
return

lberr:
exec sp_oageterrorinfo 0,@src out,@desc out
if @obj<>0 exec @err=sp_oadestroy @obj
lbexit:
select cast(@err as varbinary(4)) as 错误号
,@src as 错误源,@desc as 错误描述
select @sql,@constr
go

[binshan]

谢谢邹建大哥，你这个存储过程用了很多系统方法，很多看不明白，我有空自己慢慢研究吧！
这个存储过程对我帮助很大，好话就不多说了，在此小弟提一点建议，如果能改进，我也算是帮了一点小忙。

我的数据库有很多是自定义类型，还有一些是用GUID类型（即uniqueidentifier)，所以在建表的过程中出现错误了，再试一次又可以，但打开ACCESS表一看，很多字段，大部分是自定义类型的字段没有创建成功，如果可以找到自定义类型对应的原始类型，然后再建表，应该就没问题。

[zjcxc]

我的存储过程可以支持自定义类型啊
uniqueidentifier也可以导入,image/text/ntext字段也可以导入sql

[fansenhua]

zjcxc(邹建)大哥你好！我是个菜鸟我能加你QQ或邮件联络吗？

[fansenhua]

zjcxc(邹建)大哥你好！我是个菜鸟我能加你QQ或邮件联络吗？
如果可以的话我的QQ是122128801 邮件是:[e-mail]

[binshan]

我上次试了一下出错了，不知道怎么回事，我有空再试试，研究一下，总之，谢了！

另外，邹建)大哥，能不能提供一个导入SQL的存储过程呀！导出的已经有了。

我是第一次提问，谁能告诉我怎么样结贴吗？

[zjcxc]

--导入的,你自己不是都帖出来了吗?
/*************导入Access********************/

insert into B表 selet * from openrowset('Microsoft.Jet.OLEDB.4.0',
'x:\A.mdb';'admin';'',A表)

[zjcxc]

结帖方法:

帖子右上角--管理--给分--结帖.

[binshan]

多谢zjcxc(邹建)大哥，能交个朋友吗？如果可以加我的QQ：79150520

[netcoder]

又是第一次，又给了老邹了：）