想要实现的数据操作功能!

moleboy 2004-09-10 01:17:36

1.创建 "ID" "用户名" "密码" 字段的数据库文件
2.添加 "01" "小命" "123123" 到相应字段中的数据库文件中!
3.删除指定ID 整行的数据行!
3.可以根据 ID 用户名密码查询数据库!
4.清空数据库,保留字段!

...全文

111 点赞收藏 20

写回复

20 条回复

切换为时间正序

当前发帖距今超过3年，不再开放新的回复

发表回复

moleboy 2004-09-11

如何读取指定字段下的某行内容！

回复赞

moleboy 2004-09-11

顶！如何批量添加啊！
每次添加都提示文件打开不让操作！

回复赞

xxl0123 2004-09-11

幫忙啊!急!
多謝了!
在ACCESS裡面為甚麼下面的程序算出GetResidualW的值為7.629395E-06,為甚麼不是為零
Dim sngPileThick As Single
Dim sngUnitW As Single
Dim intQ As Integer
sngUnitW = 21.6
sngWeight = 2332.8
intQ = 108
GetResidualW = sngWeight - intQ * sngUnitW

回复赞

xxl0123 2004-09-11

在ACCESS裡面為甚麼下面的程序算出GetResidualW的值為7.629395E-06,為甚麼不是為零
Dim sngPileThick As Single
Dim sngUnitW As Single
Dim intQ As Integer
sngUnitW = 21.6
sngWeight = 2332.8
intQ = 108
GetResidualW = sngWeight - intQ * sngUnitW

回复赞

moleboy 2004-09-11

如何批量添加啊！
每次添加都提示文件打开不让操作！

回复赞

moleboy 2004-09-11

那如何把所有指定ID的所有整行内容提取到listview中！

回复赞

RUKYO 2004-09-10

对象关系时不允许操作！
=========
不好意思，改成这样吧：

Private Sub Form_Unload(Cancel As Integer)
If mRst.State = adStateOpen Then
mRst.Close
Set mRst = Nothing
End If
End Sub

回复赞

RUKYO 2004-09-10

你要用Access建一个空数据库，名为db1.mdb

回复赞

moleboy 2004-09-10

Private Sub Form_Unload(Cancel As Integer)
mRst.Close
Set mRst = Nothing
End Sub
对象关系时不允许操作！

回复赞

G10 2004-09-10

我已经把这页收入－－收藏夹

回复赞

G10 2004-09-10

先有的mdb文件，不过你也可以自己用creat 创建

回复赞

moleboy 2004-09-10

知道了！那怎么删除表和里面的字段？
不好意思我根本不会数据库！

回复赞

helanshan 2004-09-10

晕啊，你没有建立数据库，怎么连接啊。。

回复赞

moleboy 2004-09-10

mCat.ActiveConnection = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & App.Path & "\db1.mdb" & ";Persist Security Info=False"
这里出错！提示找不到文件，难道要事先有mdb数据库文件吗？

回复赞

RUKYO 2004-09-10

'工程->引用Microsoft ActiveX Data Objects 2.x Library
'工程->引用Microsoft ADO Ext. 2.x for DDL and Security
'在窗体上有1个DataGrid、6个CommandButton、3个TextBox

Option Explicit
Public mCnnString As String
Dim mRst As New ADODB.Recordset

Private Sub Command1_Click() '1.创建 "ID" "用户名" "密码" 字段的数据库文件
Dim mTbl As New Table
Dim mIdx As New ADOX.Index
Dim mCat As New ADOX.Catalog

' 打开目录。
mCat.ActiveConnection = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & App.Path & "\db1.mdb" & ";Persist Security Info=False"

' 定义表并将其追加到目录
mTbl.Name = "UserPassWord"
mTbl.ParentCatalog = mCat
mTbl.Columns.Append "ID", adVarWChar
mTbl.Columns.Append "用户名", adVarWChar
mTbl.Columns.Append "密码", adVarWChar
mCat.Tables.Append mTbl

' 定义多列索引
mIdx.Name = "MultiColIdx"
mIdx.Columns.Append "ID"

' 将索引追加到表上
mTbl.Indexes.Append mIdx
End Sub

Private Sub Command2_Click() '2.添加 "01" "小命" "123123" 到相应字段中的数据库文件中
Dim mCon As New ADODB.Connection
mCon.CursorLocation = adUseClient
mCon.Open mCnnString
mCon.Execute "Insert Into UserPassWord Values('" & "01'," & " '" & "小庆'," & " '126123" & "')"
mCon.Close
Set mCon = Nothing
End Sub

Private Sub Command3_Click() '3.删除指定ID(Text1.Text)整行的数据行
Dim mCon As New ADODB.Connection
mCon.CursorLocation = adUseClient
mCon.Open mCnnString
mCon.Execute "Delete From UserPassWord Where ID = '" & Trim(Text1.Text) & "'"
mCon.Close
Set mCon = Nothing
End Sub

Private Sub Command4_Click() '4.根据用ID(Text2.Text)查询数据库
If mRst.State = adStateOpen Then mRst.Close
mRst.CursorLocation = adUseClient
mRst.Open "Select * From UserPassWord Where ID = '" & Trim(Text2.Text) & "'", mCnnString, adOpenStatic, adLockOptimistic, adCmdText
Set DataGrid1.DataSource = mRst
End Sub

Private Sub Command5_Click() '4.根据用户名(Text3.Text)查询数据库
If mRst.State = adStateOpen Then mRst.Close
mRst.CursorLocation = adUseClient
mRst.Open "Select * From UserPassWord Where 用户名 = '" & Trim(Text3.Text) & "'", mCnnString, adOpenStatic, adLockOptimistic, adCmdText
Set DataGrid1.DataSource = mRst
End Sub

Private Sub Command6_Click() '5.清空数据表,保留字段
Dim mCon As New ADODB.Connection
mCon.CursorLocation = adUseClient
mCon.Open mCnnString
mCon.Execute "Delete From UserPassWord Where True"
mCon.Close
Set mCon = Nothing
End Sub

Private Sub Form_Load()
mCnnString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & App.Path & "\db1.mdb" & ";Persist Security Info=False"
End Sub

Private Sub Form_Unload(Cancel As Integer)
mRst.Close
Set mRst = Nothing
End Sub

回复赞