在用api访问注册表时,需要声明大量的函数和常数.有没有简单的办法??

[zebulon]

我在书上看到这样的提示:

在VB菜单的工具-->添加代码片断-->注册表访问中,可以自动添加到程序中..

但是,我没有找到上述的菜单项呀..

求救!!

[落伍者]

关于注册表的访问，好象vb的安装盘上有个模块的，上面有所有相关api的声明和常量

[aohan]

' 这个模块用于读和写注册表关键字。
' 不同于VB 的内部注册表访问方法，它可以
' 通过字符串的值来读和写任何注册表关键字。


Option Explicit
'---------------------------------------------------------------
'-注册表 API 声明...
'---------------------------------------------------------------
Private Declare Function RegCloseKey Lib "advapi32" (ByVal hKey As Long) As Long
Private Declare Function RegCreateKeyEx Lib "advapi32" Alias "RegCreateKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal Reserved As Long, ByVal lpClass As String, ByVal dwOptions As Long, ByVal samDesired As Long, ByRef lpSecurityAttributes As SECURITY_ATTRIBUTES, ByRef phkResult As Long, ByRef lpdwDisposition As Long) As Long
Private Declare Function RegOpenKeyEx Lib "advapi32" Alias "RegOpenKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal ulOptions As Long, ByVal samDesired As Long, ByRef phkResult As Long) As Long
Private Declare Function RegQueryValueEx Lib "advapi32" Alias "RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, ByRef lpType As Long, ByVal lpData As String, ByRef lpcbData As Long) As Long
Private Declare Function RegSetValueEx Lib "advapi32" Alias "RegSetValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, ByVal lpData As String, ByVal cbData As Long) As Long

'---------------------------------------------------------------
'- 注册表 Api 常数...
'---------------------------------------------------------------
' Reg Data Types...
Const REG_SZ = 1 ' Unicode空终结字符串
Const REG_EXPAND_SZ = 2 ' Unicode空终结字符串
Const REG_DWORD = 4 ' 32-bit 数字

' 注册表创建类型值...
Const REG_OPTION_NON_VOLATILE = 0 ' 当系统重新启动时，关键字被保留

' 注册表关键字安全选项...
Const READ_CONTROL = &H20000
Const KEY_QUERY_VALUE = &H1
Const KEY_SET_VALUE = &H2
Const KEY_CREATE_SUB_KEY = &H4
Const KEY_ENUMERATE_SUB_KEYS = &H8
Const KEY_NOTIFY = &H10
Const KEY_CREATE_LINK = &H20
Const KEY_READ = KEY_QUERY_VALUE + KEY_ENUMERATE_SUB_KEYS + KEY_NOTIFY + READ_CONTROL
Const KEY_WRITE = KEY_SET_VALUE + KEY_CREATE_SUB_KEY + READ_CONTROL
Const KEY_EXECUTE = KEY_READ
Const KEY_ALL_ACCESS = KEY_QUERY_VALUE + KEY_SET_VALUE + _
KEY_CREATE_SUB_KEY + KEY_ENUMERATE_SUB_KEYS + _
KEY_NOTIFY + KEY_CREATE_LINK + READ_CONTROL

' 注册表关键字根类型...
Const HKEY_CLASSES_ROOT = &H80000000
Const HKEY_CURRENT_USER = &H80000001
Const HKEY_LOCAL_MACHINE = &H80000002
Const HKEY_USERS = &H80000003
Const HKEY_PERFORMANCE_DATA = &H80000004

' 返回值...
Const ERROR_NONE = 0
Const ERROR_BADKEY = 2
Const ERROR_ACCESS_DENIED = 8
Const ERROR_SUCCESS = 0

'---------------------------------------------------------------
'- 注册表安全属性类型...
'---------------------------------------------------------------
Private Type SECURITY_ATTRIBUTES
nLength As Long
lpSecurityDescriptor As Long
bInheritHandle As Boolean
End Type

'-------------------------------------------------------------------------------------------------
'sample usage - Debug.Print UpodateKey(HKEY_CLASSES_ROOT, "keyname", "newvalue")
'-------------------------------------------------------------------------------------------------
Public Function UpdateKey(KeyRoot As Long, KeyName As String, SubKeyName As String, SubKeyValue As String) As Boolean
Dim rc As Long ' 返回代码
Dim hKey As Long ' 处理一个注册表关键字
Dim hDepth As Long '
Dim lpAttr As SECURITY_ATTRIBUTES ' 注册表安全类型

lpAttr.nLength = 50 ' 设置安全属性为缺省值...
lpAttr.lpSecurityDescriptor = 0 ' ...
lpAttr.bInheritHandle = True ' ...

'------------------------------------------------------------
'- 创建/打开注册表关键字...
'------------------------------------------------------------
rc = RegCreateKeyEx(KeyRoot, KeyName, _
0, REG_SZ, _
REG_OPTION_NON_VOLATILE, KEY_ALL_ACCESS, lpAttr, _
hKey, hDepth) ' 创建/打开//KeyRoot//KeyName

If (rc <> ERROR_SUCCESS) Then GoTo CreateKeyError ' 错误处理...

'------------------------------------------------------------
'- 创建/修改关键字值...
'------------------------------------------------------------
If (SubKeyValue = "") Then SubKeyValue = " " ' 要让RegSetValueEx() 工作需要输入一个空格...

' 创建/修改关键字值
rc = RegSetValueEx(hKey, SubKeyName, _
0, REG_SZ, _
SubKeyValue, LenB(StrConv(SubKeyValue, vbFromUnicode)))

If (rc <> ERROR_SUCCESS) Then GoTo CreateKeyError ' 错误处理
'------------------------------------------------------------
'- 关闭注册表关键字...
'------------------------------------------------------------
rc = RegCloseKey(hKey) ' 关闭关键字

UpdateKey = True ' 返回成功
Exit Function ' 退出
CreateKeyError:
UpdateKey = False ' 设置错误返回代码
rc = RegCloseKey(hKey) ' 试图关闭关键字
End Function

[aohan]

'-------------------------------------------------------------------------------------------------
'sample usage - Debug.Print GetKeyValue(HKEY_CLASSES_ROOT, "COMCTL.ListviewCtrl.1\CLSID", "")
'-------------------------------------------------------------------------------------------------
Public Function GetKeyValue(KeyRoot As Long, KeyName As String, SubKeyRef As String) As String
Dim i As Long ' 循环计数器
Dim rc As Long ' 返回代码
Dim hKey As Long ' 处理打开的注册表关键字
Dim hDepth As Long '
Dim sKeyVal As String
Dim lKeyValType As Long ' 注册表关键字数据类型
Dim tmpVal As String ' 注册表关键字的临时存储器
Dim KeyValSize As Long ' 注册表关键字变量尺寸

' 在 KeyRoot {HKEY_LOCAL_MACHINE...} 下打开注册表关键字
'------------------------------------------------------------
rc = RegOpenKeyEx(KeyRoot, KeyName, 0, KEY_ALL_ACCESS, hKey) ' 打开注册表关键字

If (rc <> ERROR_SUCCESS) Then GoTo GetKeyError ' 处理错误...

tmpVal = String$(1024, 0) ' 分配变量空间
KeyValSize = 1024 ' 标记变量尺寸

'------------------------------------------------------------
' 检索注册表关键字的值...
'------------------------------------------------------------
rc = RegQueryValueEx(hKey, SubKeyRef, 0, _
lKeyValType, tmpVal, KeyValSize) ' 获得/创建关键字的值

If (rc <> ERROR_SUCCESS) Then GoTo GetKeyError ' 错误处理

tmpVal = Left$(tmpVal, InStr(tmpVal, Chr(0)) - 1)

'------------------------------------------------------------
' 决定关键字值的转换类型...
'------------------------------------------------------------
Select Case lKeyValType ' 搜索数据类型...
Case REG_SZ, REG_EXPAND_SZ ' 字符串注册表关键字数据类型
sKeyVal = tmpVal ' 复制字符串的值
Case REG_DWORD ' 四字节注册表关键字数据类型
For i = Len(tmpVal) To 1 Step -1 ' 转换每一位
sKeyVal = sKeyVal + Hex(Asc(Mid(tmpVal, i, 1))) ' 一个字符一个字符地生成值。
Next
sKeyVal = Format$("&h" + sKeyVal) ' 转换四字节为字符串
End Select

GetKeyValue = sKeyVal ' 返回值
rc = RegCloseKey(hKey) ' 关闭注册表关键字
Exit Function ' 退出

GetKeyError: ' 错误发生过后进行清除...
GetKeyValue = vbNullString ' 设置返回值为空字符串
rc = RegCloseKey(hKey) ' 关闭注册表关键字
End Function

[韧恒]

Visual Basic 提供了一个标准的注册位置（主键）以存储创建于 Visual Basic 的应用程序的程序信息：

　　 HKEY_CURRENT_USER\Software\VB and VBA Program Settings\

　　 下面的所有函数所读写的注册表路径都是以这个路径为根的相对位置。

　　 SaveSetting

　　 这个函数用来向注册表数据库写入一些数据

　　 SaveSetting appname, section, key, setting

　　 appname

　　 在向注册表写入数据之前，你必须计划好一个用在整个应用程序中的appname 。可以把注册表的内容比作一台计算机，那么appname就是驱动器。它必须是一个字符串，也可以用数字，不过要用CStr 函数把它转换成字符串格式。事实上它代表的是应用程序或工程的名称。一般来说，appname在整个应用程序中应该保持不便。

　　 section

　　 section可以说是这个模型中的目录，就向一台计算机上的目录一样。它用来把设置分类，可以包含Key或者子section。如果给它传递vbNullChar 这个值的话，就表示要操作的键是在根目录下的，也就是在appname下面的。

　　 key

　　 相当于一个文件名。

　　 setting

　　 它代表文件中的信息，可以是一个数字或者字符串。

　　 执行完后，在注册表的HKEY_CURRENT_USER\Software\VB and VBA Program Settings\appname\section\"主键下面的名为“key”的键将被赋值为“setting”，如果相应的主键或者键名不存在，将会被创建。

　　 GetSetting

　　 这个函数用来从注册表中提取数据。

　　 GetSetting(appname, section, key[, default])

　　 Appname，section和key的含义和上面的一样。

　　 default

　　 如果Visual Basic没有找到指定的键，函数将返回参数default中得值。这个参数是可选的，但是对错误情况的处理很方便。如果没有选用这个参数，而指定的键的名称不存在，函数将返回一个长度为0的字符串。

　　 下面看看例子：
SaveSetting "Logon Master", "Users\User0", _
"Name", "John"
注释：这将把数据"John"储存到注册表的 "Logon Master\Users\User0\Name"
注释：不过这是相对路径，相对于一个根

Debug.Print GetSetting("Logon Master", _
"Users\User0", "Name", "Anonymous"
注释：这将显示"John"

Debug.Print GetSetting("Logon Master", _
"Users\User1", "Name", "Anonymous"
注释：这次显示的将是"Anonymous"，因为在
注释："Logon Master\Users\User1\Name"没有预先储存值。
GetAllSettings



　　 这个函数用来提取某个目录（主键）下面的所有文件（子键）。

　　 GetAllSettings(appname, section)

　　 参数的含义和其他的函数都是一样的。但这个函数和其他几个比起来更为复杂。他返回的的是一个2维字符串数组，包含了所有的子键名称和乡音的子键值。看看下面这个例子，你很容易的就能搞清楚：
注释： 定义一个Variant类型的变量来保存GetAllSettings返回的二维数组

注释： Interger类型值用来计数
Dim MySettings As Variant, intSettings As Integer

注释：先在注册表中填入一些值
SaveSetting "Logon Master", "Users\User0", _
"Name", "John"
SaveSetting "Logon Master", "Users\User0", _
"Priviledges", "Supervisor"

注释：提取预先设定的数据
MySettings = GetAllSettings("Logon Master", _
"Users\User0")

注释：显示出来
For intSettings = LBound(MySettings, 1) _
To UBound(MySettings, 1)

注释：MySettings(x,0)中包含的是键名，
注释：而MySettings(x,1) 中包含的是键值
Debug.Print MySettings(intSettings, 0), _
MySettings(intSettings, 1)
Next intSettings



　　 注意：GetAllSettings并不返回目录名，只是返回键名和相应的键值。

　　 DeleteSetting

　　 除了保存和提取数据，我们还要能够删除注册表中的注册项。这就要用到DeleteSetting函数了。

　　 DeleteSetting appname[, section[, key]]

　　 这个函数用来删除主键或者键。如果要删除的是键，要给出它所在的键名。如果要删除的是主键，这它下面所有的键和子主键都会被删除。如果你要删除应用程序所有的注册表信息，就只用指定appname就可以了。

　　 例如：
DeleteSetting "Logon Master", "Users\User0", "Name"
注释：这将删除Name键。
DeleteSetting "Logon Master", "Users"
注释：这将删除"Logon Master\Users"主键和其下的所有内容。
DeleteSetting "Logon Master"
注释：这将删除应用程序"Logon Master"下面的所有内容。

[freedomjim]

多加一个模块就是了

[cso]

读本机“计算机名”

Private Sub Form_Load()
Dim ReadComputerName
Set ReadComputerName = CreateObject("WScript.Shell")
Dim ComputerName, RegPath
RegPath = "HKLM\System\CurrentControlSet\Control\ComputerName\ComputerName\ComputerName"
ComputerName = ReadComputerName.RegRead(RegPath)
MsgBox ("计算机名为" & ComputerName)
End Sub

[cso]

用VBScript实现对Windows注册表的修改
http://www.farwen.com/readnews.asp?NewsID=2037

[zebulon]

感谢老兄了..

不过,我问的是: 如何通过在VB菜单的工具-->添加代码片断-->注册表访问中,将API声明自动添加到程序中..
因为,我没有在"工具"菜单上找到"添加代码片断"呀!!!!1

[aiirii]

有个 winapi text.exe 的vb带的工具，不是可以查询，copy api的声明吗？/

[cso]

我的没有,估计是你用了某个Addins

[DemonLoveLizzy]

在设计时选择添加模块，然后选VB目录里的“VB98\Template\Code\注册表访问.bas”就可以了。

[dxj1234]

点vb的AddIn菜单，选择你要的那个插件就行了。

[BlueBeer]

用WSH（Windows Script Host）最容易掌握

Set Reg = CreateObject("Wscript.Shell")

Reg.RegWrite "要写入的值的名称","值"
Reg.RegRead "要读取的值的名称"
Reg.RegDelete "要删除的键名或值名"

例：修改IE主页

Dim Reg As Object
Set Reg = CreateObject("Wscript.Shell")
Reg.RegWrite "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Main\start page", "www.csdn.net"


注意：WSH认为，结尾带有“\”的是一个键的名称，否则是值的名称

[zebulon]

终于有人说对了..非常感谢!!!