为什么这个存储过程没有结果？

[DTWUJP]

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_getlinkinfo]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_getlinkinfo]
GO

/*--获取连接SQL服务器的信息

所有连接本机的:操作的数据库名,计算机名,用户名,网卡物理地址,IP地址,程序名
--邹建 2003.11--*/

/*--调用示例
--显示所有本机的连接信息
exec p_getlinkinfo

--显示所有本机的连接信息,包含ip地址
exec p_getlinkinfo @includeip=1

--显示连接指定数据库的信息
exec p_getlinkinfo '客户资料'
--*/
create proc p_getlinkinfo
@dbname sysname=null, --要查询的数据库名,默认查询所有数据库的连接信息
@includeip bit=0 --是否显示IP地址,因为查询IP地址比较费时,所以增加此控制
as
declare @dbid int
set @dbid=db_id(@dbname)

create table #tb(id int identity(1,1),dbname sysname,hostname nchar(128),loginname nchar(128),net_address nchar(12),net_ip nvarchar(15),prog_name nchar(128))
insert into #tb(hostname,dbname,net_address,loginname,prog_name)
select distinct hostname,db_name(dbid),net_address,loginame,program_name from master..sysprocesses
where hostname<>'' and (@dbid is null or dbid=@dbid)

if @includeip=0 goto lb_show --如果不显示IP地址,就直接显示

declare @sql varchar(500),@hostname nchar(128),@id int
create table #ip(hostname nchar(128),a varchar(200))
declare tb cursor local for select distinct hostname from #tb
open tb
fetch next from tb into @hostname
while @@fetch_status=0
begin
set @sql='ping '+@hostname+' -a -n 1 -l 1'
insert #ip(a) exec master..xp_cmdshell @sql
update #ip set hostname=@hostname where hostname is null
fetch next from tb into @hostname
end

update #tb set net_ip=left(a,patindex('%:%',a)-1)
from #tb a inner join (
select hostname,a=substring(a,patindex('Ping statistics for %:%',a)+20,20) from #ip
where a like 'Ping statistics for %:%') b on a.hostname=b.hostname

lb_show:
select id,数据库名=dbname,客户机名=hostname,用户名=loginname
,网卡物理地址=net_address,IP地址=net_ip,应用程序名称=prog_name from #tb

go



以上是邹健提供的一段存储过程，我在VB中调用但没有任何结果显示，

Public Function Getlinkinfo() As ADODB.Recordset
Dim rst As ADODB.Recordset
Dim cmd As ADODB.Command
Set cmd = New ADODB.Command

With cmd
.ActiveConnection = cnntodata
.CommandTimeout = 60
.CommandType = adCmdStoredProc
.CommandText = "p_getlinkinfo"

End With
'Dim sql As String
''sql = "exec p_getlinkinfo"
'sql = "select * from revmain"
'Set rst = cnntodata.Execute(sql)

Set GetUSERinfo = cmd.Execute
'MsgBox GetUSERinfo.RecordCount
'MsgBox IsEmptyRecordset(rst)------运行到这里报错：对象关闭不能执行操作
'End With
End Function

在from_load中
Set GhGrid.DataSource = Getlinkinfo

cnntodata是一个全局的Connection对象，GHGRID是vsflexgrid控件,但执行其他存储过程都没有问题，能正常显示。

[DTWUJP]

Public Function IsEmptyRecordset(ByVal TempRs As ADODB.Recordset) As Boolean

If TempRs Is Nothing Then
IsEmptyRecordset = True
Exit Function
End If


With TempRs

If .BOF = True And .EOF = True Then
IsEmptyRecordset = True
Exit Function
End If


If .RecordCount = 0 Then
IsEmptyRecordset = True
Else
IsEmptyRecordset = False
End If
End With

End Function
这是判断是否是空记录的函数.

请各位给找出错误，vb6.0sp6,mssqlserver企业版

[netcoder]

这样：
if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_getlinkinfo]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_getlinkinfo]
GO

/*--获取连接SQL服务器的信息

所有连接本机的:操作的数据库名,计算机名,用户名,网卡物理地址,IP地址,程序名
--邹建 2003.11--*/

/*--调用示例
--显示所有本机的连接信息
exec p_getlinkinfo

--显示所有本机的连接信息,包含ip地址
exec p_getlinkinfo @includeip=1

--显示连接指定数据库的信息
exec p_getlinkinfo '客户资料'
--*/
create proc p_getlinkinfo
@dbname sysname=null, --要查询的数据库名,默认查询所有数据库的连接信息
@includeip bit=0 --是否显示IP地址,因为查询IP地址比较费时,所以增加此控制
as
------------------
---注意：增加这一句
-----------------
set nocount on

declare @dbid int
set @dbid=db_id(@dbname)

create table #tb(id int identity(1,1),dbname sysname,hostname nchar(128),loginname nchar(128),net_address nchar(12),net_ip nvarchar(15),prog_name nchar(128))
insert into #tb(hostname,dbname,net_address,loginname,prog_name)
select distinct hostname,db_name(dbid),net_address,loginame,program_name from master..sysprocesses
where hostname<>'' and (@dbid is null or dbid=@dbid)

if @includeip=0 goto lb_show --如果不显示IP地址,就直接显示

declare @sql varchar(500),@hostname nchar(128),@id int
create table #ip(hostname nchar(128),a varchar(200))
declare tb cursor local for select distinct hostname from #tb
open tb
fetch next from tb into @hostname
while @@fetch_status=0
begin
set @sql='ping '+@hostname+' -a -n 1 -l 1'
insert #ip(a) exec master..xp_cmdshell @sql
update #ip set hostname=@hostname where hostname is null
fetch next from tb into @hostname
end

update #tb set net_ip=left(a,patindex('%:%',a)-1)
from #tb a inner join (
select hostname,a=substring(a,patindex('Ping statistics for %:%',a)+20,20) from #ip
where a like 'Ping statistics for %:%') b on a.hostname=b.hostname

lb_show:
select id,数据库名=dbname,客户机名=hostname,用户名=loginname
,网卡物理地址=net_address,IP地址=net_ip,应用程序名称=prog_name from #tb

------------------
---注意：增加这一句
-----------------

set nocount off
go