datawindow导成EXCEL问题

[wz4085753]

小弟想把DATAWINDOW里面的数据导给EXCEL请问怎么解决！
我记的好象有个函数能实现！可我忘了是什么函数和用法！
请大虾指教

[wz4085753]

？？？？
我想问一下！用以上的方法！导出后DATAWINDOW里的计算列没了
怎么能让计算列跟着一起上去啊 ！

[hds8229830]

SaveAsAscii

[powerly]

直接在程序中调用这个函数即可：
string ls_path,ls_FileName
//
if GetFileSaveName('保存为',ls_path, ls_FileName, 'xls','Excel Files (*.xls),*.xls') = 1 then
if f_ExportToExcel(dw_1,ls_FileName) then
messagebox("信息","数据导出完成！",INFORMATION!,OK!)
else
messagebox("信息","数据导出失败！",STOPSIGN!,OK!)
end if
end if
//
return ci_YES
函数如下
//f_ExportToExcel
///////////////////////////////////////////////////////////////////////////
//
// Parameters : ad_dw : datawindow
// as_file : file name
// Returns : true/false : boolean
// Description : Save the datawindow as a excel file.
//
///////////////////////////////////////////////////////////////////////////
declare the local variables
long i, j, li_pos
string ls_objects, ls_obj, ls_text, ls_err, ls_sql,ls_ColType
datastore lds_saveas //导出数据窗
datastore lds_sort //获得根据 object.x 排序的 (band = detail and visible = 1) 的 column/compute
boolean lb_return //返回值
string ls_pbver //pb 版本信息
environment env //环境变量
//
SetPointer(HourGlass!)
//
getenvironment(env)
ls_pbver = string(env.pbmajorrevision)
//创建排序列 datastore
lds_sort = create datastore
ls_sql = 'column=(type=char(1) name = ztext dbname="ztext" )' + '~r~n' + &
'column=(type=char(1) name = zcol dbname="zcol" )' + '~r~n' + &
'column=(type=long name = zx dbname="zx" )' + '~r~n' + &
'column=(type=char(1) name = ztype dbname="ztype" )' + '~r~n'
ls_sql = 'release ' + ls_pbver + ';~r~ntable(' + ls_sql + ')'
lds_sort.create(ls_sql, ls_err)
if len(ls_err) > 0 then
lb_return = false
goto lab1
end if
//准备数据====================================================
//all controls
ls_objects = ad_dw.Describe("datawindow.objects")
//按~t位置作判断开始循环
do while (pos(ls_objects,"~t") > 0)
li_pos = pos(ls_objects,"~t")
ls_obj = left(ls_objects,li_pos - 1)
ls_objects = right(ls_objects,len(ls_objects) - li_pos)
//(column or compute ) at detail and visible
if (ad_dw.Describe(ls_obj+".type") = "column" or ad_dw.Describe(ls_obj+".type") = "compute" ) AND &
(ad_dw.Describe(ls_obj+".band") = "detail" ) AND &
(ad_dw.Describe(ls_obj+".visible") = "1" ) THEN
ls_text = ad_dw.describe(ls_obj + '_t.text')
if ls_text <> '!' and ls_text <> '?' then
lds_sort.insertrow(0)
lds_sort.setitem(lds_sort.rowcount(), 'ztext', ls_text)
lds_sort.setitem(lds_sort.rowcount(), 'zcol', ls_obj)
lds_sort.setitem(lds_sort.rowcount(), 'zx', long(ad_dw.describe(ls_obj + '.x')))
ls_ColType = ad_dw.Describe(ls_obj+".ColType")
choose case upper(left(ls_ColType,3))
case 'DEC','INT','LON','NUM','REA','ULO'
lds_sort.setitem(lds_sort.rowcount(), 'ztype',ls_ColType)
case else
lds_sort.setitem(lds_sort.rowcount(), 'ztype','char(1)')
end choose
end if
end if
loop
//the last control
ls_obj = ls_objects
if (ad_dw.Describe(ls_obj+".type") = "column" or ad_dw.Describe(ls_obj+".type") = "compute" ) AND &
(ad_dw.Describe(ls_obj+".band") = "detail" ) AND &
(ad_dw.Describe(ls_obj+".visible") = "1" ) THEN
ls_text = ad_dw.describe(ls_obj + '_t.text')
if ls_text <> '!' and ls_text <> '?' then
lds_sort.insertrow(0)
lds_sort.setitem(lds_sort.rowcount(), 'ztext', ls_text)
lds_sort.setitem(lds_sort.rowcount(), 'zcol', ls_obj)
lds_sort.setitem(lds_sort.rowcount(), 'zx', long(ad_dw.describe(ls_obj + '.x')))
ls_ColType = ad_dw.Describe(ls_obj+".ColType")
choose case upper(left(ls_ColType,3))
case 'DEC','INT','LON','NUM','REA','ULO'
lds_sort.setitem(lds_sort.rowcount(), 'ztype',ls_ColType)
case else
lds_sort.setitem(lds_sort.rowcount(), 'ztype','char(1)')
end choose
end if
end if
//如果没有列则跳出
if lds_sort.rowcount() < 1 then goto lab1
//根据 object.x 排序
lds_sort.setsort('zx A')
lds_sort.sort()
//创建导出 datastore
lds_saveas = create datastore
ls_sql = ''
for i = 1 to lds_sort.rowcount()
ls_obj = lds_sort.getitemstring(i, 'zcol')
ls_ColType = lds_sort.getitemstring(i, 'ztype')
ls_text = lds_sort.getitemstring(i, 'ztext')
ls_sql += 'column=(type='+ls_ColType+' dbname="' + ls_text + '" )' + '~r~n'
next
ls_sql = 'release ' + ls_pbver + ';~r~ntable(' + ls_sql + ')'
lds_saveas.create(ls_sql, ls_err)
if len(ls_err) > 0 then
lb_return = false
goto lab1
end if
//向 lds_saveas 中写数据
for i = 1 to ad_dw.rowcount()
yield()//释放消息队列, 如果数据量较大, 可以使用这个函数
lds_saveas.insertrow(0)
for j = 1 to lds_sort.rowcount()
SetPointer(HourGlass!)
ls_obj = lds_sort.getitemstring(j, 'zcol')
ls_ColType = lds_sort.getitemstring(j, 'ztype') //---------
if ad_dw.describe(ls_obj + '.type') = 'column' then
ls_text = ad_dw.describe('evaluate(~'LookUpDisplay(' + ls_obj + ')~', ' + string(i) + ')')
else
ls_text = ad_dw.describe('evaluate(~'' + ls_obj + '~',' + string(i) + ')')
end if
choose case upper(left(ls_ColType,3))
case 'DEC','REA','NUM'
lds_saveas.setitem(i, j, dec(ls_text))
case 'INT','LON','ULO'
lds_saveas.setitem(i, j, long(ls_text))
case else
lds_saveas.setitem(i, j, ls_text)
end choose
next
next
//saveas datawindow
lb_return = (lds_saveas.saveas(as_file, excel!, true) = 1)
//
lab1:
destroy lds_sort
destroy lds_saveas
SetPointer(Arrow!)
//
return lb_return

[wz4085753]

感谢大虾