水晶报表的格式化

[liuxing23]

在水晶报表中怎样才能给text中的数据格式化
如数据是20041118
显示为2004年11月18日

[myhgyp]

应该是只能用代码来控制，步骤如下：
1、定义一个显示区对象：Dim WithEvents CrSecRH As Section
设置：Set CrSecRH = carp.Sections("PageHeaderSection1")
2、取该区的text对象：
Dim mytxt As CRAXDRT.TextObject
设置：Set mytxt = CrSecRH.ReportObjects("mytxt")
3、通过该区的format事件来控制text对象的显示格式
Private Sub CrSecRH_Format(ByVal pFormattingInfo As Object)
'changes the textbox in the Report Header
mytxt.SetText Format(mytxt.Text, "####年##月##日")
End Sub

[liuxing23]

可不可以详细一点阿！
如：从建工程到添加crystal report的步骤阿！

[myhgyp]

'*****************************************************************
'*crystal report 的使用示例
'*适用版本：9.0
'*制作人：马亚红
'*制作时间：2004年12月28日
'*注：如要引用该代码，请带上出处
'*好多朋友有这个问题：报表显示后数据没有刷新
'*解决方法如下：在报表的设计界面，菜单“文件”--》“选项”--》“建立报表”选项卡--》把“将数据与报表一起保存”前的勾去掉后保存即可
'*****************************************************************
Option Explicit
Dim Report As New CrystalReport1
Dim wjfilesys As FileSystemObject 'FSO 对象，用于文件操作
Dim WithEvents CrSecRH As Section '报表显示区对象
Dim capp As New CRAXDDRT.Application '报表集合对象
Dim carp As New CRAXDRT.Report '报表集合中的报表对象
Dim carsubp As New CRAXDRT.Report '报表集合对象中的子报表对象
Dim Pic2 As OLEObject '报表对象中的Ole对象
Dim mytxt As CRAXDRT.TextObject '报表对象中的Textbox对象


Private Sub Combo1_Change() '放大（缩小）比例
CRViewer91.Zoom (CInt(Combo1.Text))
End Sub



Private Sub Command1_Click() '显示第一页
CRViewer91.ShowFirstPage
End Sub



Private Sub Command10_Click() '打印报表
CRViewer91.PrintReport
End Sub

Private Sub Command2_Click() '刷新报表
CRViewer91.Refresh
End Sub

Private Sub Command3_Click() '显示上一页
CRViewer91.ShowPreviousPage
End Sub
Private Sub Command4_Click() '显示下一页
CRViewer91.ShowNextPage
End Sub

Private Sub Command5_Click() '显示最后一页
CRViewer91.ShowLastPage
End Sub

Private Sub Command6_Click() '在报表内容内搜索
If (txtSearch.Text <> "") Then
CRViewer91.SearchForText (txtSearch.Text)
End If
txtSearch.Text = ""
End Sub

Private Sub Command7_Click() '导入出PDF

Dim myExportFile As String
myExportFile = App.Path + "\temp.pdf"
If wjfilesys.FileExists(myExportFile) Then

wjfilesys.DeleteFile (myExportFile)
End If
Report.ExportOptions.DiskFileName = myExportFile
Report.ExportOptions.FormatType = crEFTPortableDocFormat
Report.ExportOptions.DestinationType = crEDTDiskFile
Report.ExportOptions.PDFExportAllPages = True
Report.Export (False)

End Sub

Private Sub Command8_Click() '导出到Excel
Dim myExportFile As String
myExportFile = App.Path + "\temp.xls"
If wjfilesys.FileExists(myExportFile) Then

wjfilesys.DeleteFile (myExportFile)
End If
Report.ExportOptions.DiskFileName = myExportFile
Report.ExportOptions.FormatType = crEFTExcel97
Report.ExportOptions.DestinationType = crEDTDiskFile
Report.ExportOptions.PDFExportAllPages = True
Report.Export (False)

End Sub

Private Sub Command9_Click() '导出到WORD
Dim myExportFile As String
myExportFile = App.Path + "\temp.doc"
If wjfilesys.FileExists(myExportFile) Then

wjfilesys.DeleteFile (myExportFile)
End If
Report.ExportOptions.DiskFileName = myExportFile
Report.ExportOptions.FormatType = crEFTWordForWindows
Report.ExportOptions.DestinationType = crEDTDiskFile
Report.ExportOptions.PDFExportAllPages = True
Report.Export (False)
End Sub

Private Sub Form_Load()
Screen.MousePointer = vbHourglass
'''显示方式一：情况为报表直接在工程设计器中制作（Dsr文件）
'---------------------
''CRViewer91.ReportSource = Report
''CRViewer91.ViewReport
'----------------------
'显示方式二：情况为报表在水晶报表软件中制作（rpt文件）
Dim cn As New ADODB.Connection
Dim rs As New ADODB.Recordset
Dim strsql As String
Dim i As Integer
If cn.State = adStateOpen Then cn.Close
''SQL SERVER连接方式
'With cn
'.Provider = "sqloledb"
'.ConnectionString = "data source=dd;initial catalog=dfd;user id=sa;password=aaa"
'.Open
'End With
'Mdb的连接方式
With cn
.Provider = "Microsoft.Jet.OLEDB.4.0"
.ConnectionString = "Data Source=" + App.Path + "\Test.mdb;Persist Security Info=False"
.Open
End With

strsql = "select * from carsort"
If rs.State = adStateOpen Then rs.Close
With rs
.ActiveConnection = cn
.CursorLocation = adUseClient
.Open strsql, cn, adOpenDynamic, adLockOptimistic
End With

Set carp = capp.OpenReport(App.Path + "\CryStalTest.rpt") '取报表对象
Set carsubp = carp.OpenSubreport("myhgyp") '取子报表对象
Set CrSecRH = carp.Sections("PageHeaderSection1") '取报表头显示区对象
Set Pic2 = carp.Sections("PageHeaderSection1").ReportObjects("picture1") '取报表头显示区中的Ole对象
Set mytxt = CrSecRH.ReportObjects("mytxt")

For i = 1 To carp.Database.Tables.Count '设置报表的数据源
If carp.Database.Tables.Item(i).Name = "carsort" Then
carp.Database.Tables(i).SetDataSource rs
End If
Next
For i = 1 To carsubp.Database.Tables.Count '设置子报表的数据源
If carp.Database.Tables.Item(i).Name = "carsort" Then
carsubp.Database.Tables(i).SetDataSource rs
End If
Next
Screen.MousePointer = vbHourglass
'第一种设置参数的方式
''carp.ParameterFields(1).ClearCurrentValueAndRange
''carp.ParameterFields(1).AddCurrentValue ("myhgyp")
''carp.ParameterFields(2).ClearCurrentValueAndRange
''carp.ParameterFields(2).AddCurrentValue (CInt("3"))
'第二种设置参数的方式
carp.ParameterFields.GetItemByName("gg").ClearCurrentValueAndRange
carp.ParameterFields.GetItemByName("gg").AddCurrentValue ("myh11" & Chr(13) & Chr(10) & "-2gyp")
carp.ParameterFields.GetItemByName("ff").ClearCurrentValueAndRange
carp.ParameterFields.GetItemByName("ff").AddCurrentValue (CInt("673"))
CRViewer91.ReportSource = carp
CRViewer91.ViewReport
Screen.MousePointer = vbDefault
CRViewer91.Zoom 100
'----------------------
Screen.MousePointer = vbDefault
Set wjfilesys = CreateObject("Scripting.FileSystemObject")
End Sub
Private Sub CrSecRH_Format(ByVal pFormattingInfo As Object) '格式化报表头显示区中的对象
Set Pic2.FormattedPicture = LoadPicture(App.Path & "\tsconfig.bmp") 'changes the pic in the Report Header
mytxt.SetText Format(mytxt.Text, "####年##月##日")
End Sub

Private Sub Form_Resize() '设置报表显示区域
CRViewer91.Top = 0
CRViewer91.Left = 0
CRViewer91.Height = ScaleHeight
CRViewer91.Width = ScaleWidth
End Sub

[liuxing23]

在VB6中可以双击就可以直接进入code编辑页面，.net中怎样进入阿？

[myhgyp]

在VB6中可以双击就可以直接进入code编辑页面，.net中也一样啊

[liuxing23]

to myhgyp
我的情况是在.net中
新建立一个工程（appliction)之后,在project菜单中选windows form添加项，打开对话框后选crystalreport项，向工程中添加一个crystalreport，此时水晶报表编辑器自动打开，但是我在编辑器中添加text等项后，在page header 或details等section中双击不会进到代码编辑页中（在vb6中我试过好使），我在我的工程中看到了跟我的.rpt文件相同的.vb文件（应该就是报表的代码文件）但是在工程中添加不进来。
请问是什么原因？

[TBenq]

up

[snowmiao2002]

（9.0）在设计时可以指定
字段 属性 （按类型排）

Datetime 或 日期时间
有年/月/日/时/分/秒 各是否显示，前缀后缀，分割符等。

其实，很多直都可以在这里设定，如数据的千分位，分割符。小数点，小数位数
等等。