〔连载〕报表的监听器使用GDI+函数，你可以绘制自己喜欢的任何形状

加菲猫的VFP 2022-03-30 01:15:34

〔连载〕报表的监听器使用GDI+函数，你可以绘制自己喜欢的任何形状

译者:Fbilo

SFReportListenerGraphic

ReportListener的OutputPage方法支持将报表页面们输出为图形文件。SFReportListener的一个子类SFReportListenerGraphic可以使这个任务更容易完成。它有两个自定义属性：cFileName被设置为将要建立的文件名，nFileType或者被设置为一个表示文件类型的数字、或者保留为0，在后一种情况下SFReportListenerGraphic将根据在cFileName中的文件名的扩展名来将之设置为正确的值。
如果ListenerType为2（“一次一页”模式并且不输出，这个类的默认值），OutputPage会在每一页被绘制后自动被调用。在这种情况下，OutputPage将处理输出到指定文件的工作。

如果ListenerType为3（“一次处理所有页”但不马上输出模式），报表页们只会在OutputPage被调用的时候才会输出，因此AfterReport方法将遍历所有被绘制好了的页，然后依次为每一页调用OutputPage。
如果指定的输出类型是一个多页的TIFF文件，要注意的是，第一页必须被输出为一个单的TIFF文件，然后后续的页将通过输出为一个多页TIFF文件的方式被添加到第一页的文件中。这里是取自AfterReport方法的代码；OutputPage与此类似但略为简单一些。（在这段代码中的LISTENER_* 是定义在FoxPro_Reporting.H文件中的常量，该文件被SFReporting.H所引用，而后者本身也是被本类的包含文件SFReportListener.H所引用的。）

local lcBaseName, lcExt, lnI, lcFileName

with This
    dodefault()
    If .ListenerType = LISTENER_TYPE_ALLPGS
        if .nFileType = 0
            .GetGraphicsType()
        endif .nFileType = 0
        lcBaseName = addbs(justpath(.cFileName)) + juststem(.cFileName)
        lcExt = justext(.cFileName)
        for lnI = 1 to .SharedOutputPageCount
            do case
            case .nFileType <> LISTENER_DEVICE_TYPE_MTIF
                lcFileName = forceext(lcBaseName + padl(lnI, 3, '0'), lcExt)
                .OutputPage(lnI, lcFileName, .nFileType)
            case not file(.cFileName)
                .OutputPage(lnI, .cFileName, LISTENER_DEVICE_TYPE_TIF)
            otherwise
                .OutputPage(lnI, .cFileName, .nFileType)
            endcase
            .DoStatus(strtran(strtran(ccSTR_PAGE_X_OF_Y, ccMSG_INSERT1, ;
                transform(lnI)), ccMSG_INSERT2, ;
            transform(.SharedOutputPageCount)))
        next lnI
        .ClearStatus()
    endif .ListenerType = LISTENER_TYPE_ALLPGS
endwith
SFReportListenerGraphic 也有一个ShowFile方法可以通过使用Windows API函数 ShellExecute 来显示这个文件，该函数会自动调用该种文件类型的注册应用程序。
TestGraphicOutput.PRG 演示了SFReportListenerGraphic是如何工作的。它结合了多个listeners的效果来实现正确的绘制这个报表（这里使用了前面你见过的同一个报表TestDynamicFormatting.FRX）并输出为图形文件。
use _samples + 'Northwind\orders'
loListener = newobject('SFReportListenerGraphic', 'SFReportListener.vcx')
loListener.cFileName = fullpath('TestReport.gif')
loListener.Successor = newobject('SFReportListenerDirective', ;
    'SFReportListener.vcx')
report form TestDynamicFormatting.FRX object loListener range 1, 6
loListener.ShowFile(1)

自定义的绘制

如果把Render方法和GDI+函数的能力整合起来，你就能够绘制任何东西来代替一个对象。比如一个常见的需求：在一个报表上绘制图表(chart)而不需要依赖于General字段和ActiveX控件。图4中显示的就是这么一个报表。其中的图表用列来表示各个产品类别的销售情况。不过在报表设计器中，在应该放图表的地方，你看到的将是一个矩形。

图4、使用GDI+函数，你可以绘制自己喜欢的任何形状(shape)

TestCustomRendering.PRG会运行TestCustomRendering.FRX报表，它使用SFColumnChartListener 类来将矩形替换成一个图表。这个类的代码就不冗述了。总之，作为一个例子，下面的代码取自DrawColumnChart方法，该方法在矩形将要被绘制的时候从BeforeRender方法中被调用。从代码中你可以看到，这里大量的使用了在FFC的 _GDIPlus.VCX中的那些类，这些类在本章的“_GDIPlus.VCX”一节中已经被讨论过了。这段代码使用了这个类的几个属性：
 aValue是一个包含着用于生成图表的数据的二维数组。数组第一列中放的是产品类别的名称，第二列中则是每个类别的销售总数；
 aColumnColors是一个包含着用于（图表中）每个列的颜色的数组；
 nSapcing是列之间的间距；
 cLegendFontName和nLegendFontSize是用于图例的字体名称和大小；
 nLegendSpacing是在图表和它的图例之间的间距；
 nLegendBoxSize是在图例中一个小方框的大小，nLegendBoxSpacing 是这些小方框之间的间距，而nLegendTextSpacing是在一个小方框和它的相关文本之间的间距。

lparameters tnLeft, tnTop, tnWidth, tnHeight
local lnMax, ;
    lnColumns, ;
    lnI, ;
    lnColumnWidth, ;
    loColumnBrush, ;
    loPen, ;
    loFont, ;
    loStringFormat, ;
    loPoint, ;
    loTextBrush, ;
    lnColors, ;
    lnColor, ;
    lnLeft, ;
    lnHeight, ;
    lnTop

with This
* 弄清楚每个列的最大值和宽度
    lnMax        = 0
    lnColumns     = alen(.aValues, 1)
    for lnI = 1 to lnColumns
        lnMax = max(lnMax, .aValues[lnI, 2])
    next lnI
    lnColumnWidth = (tnWidth - (lnColumns * .nSpacing))/lnColumns

* 建立我们将用于绘制的_GDIPlus 对象们
    loColumnBrush = newobject('GPSolidBrush',home() + 'ffc\_GDIPlus.vcx')
    loPen    = newobject('GPPen', home() + 'ffc\_GDIPlus.vcx')
    loFont    = newobject('GPFont',home() + 'ffc\_GDIPlus.vcx')
    loStringFormat=newobject('GPStringFormat',home() + 'ffc\_GDIPlus.vcx')
    loPoint    = newobject('GPPoint',    home() + 'ffc\_GDIPlus.vcx')
    loTextBrush= newobject('GPSolidBrush', home() + 'ffc\_GDIPlus.vcx')
    loPen.Create(.CreateColor(0))    && 黑色
    loFont.Create(.cLegendFontName, .nLegendFontSize, ;
        GDIPLUS_FontStyle_Regular, GDIPLUS_Unit_Point)

* 画出图表列的边框
    .oGDIGraphics.DrawLine(loPen, tnLeft, tnTop, tnLeft, ;
        tnTop + tnHeight)
    .oGDIGraphics.DrawLine(loPen, tnLeft, tnTop + tnHeight, ;
        tnLeft + tnWidth, tnTop + tnHeight)

* 画列
    lnColors = alen(.aColumnColors)
    for lnI = 1 to lnColumns
        lnColor = .aColumnColors[(lnI - 1) % lnColors + 1]
        loColumnBrush.Create(lnColor)
        lnLeft    = tnLeft + lnI * .nSpacing + (lnI - 1) * lnColumnWidth
        lnHeight = cast(tnHeight/lnMax * .aValues[lnI, 2] as Numeric(7, 2))
        lnTop    = tnTop + tnHeight - lnHeight
        .oGDIGraphics.DrawRectangle(loPen, lnLeft, lnTop, ;
            lnColumnWidth, lnHeight)
        .oGDIGraphics.FillRectangle(loColumnBrush, lnLeft, lnTop, ;
            lnColumnWidth, lnHeight)

* 画列的图例
        lnLeft = tnLeft + tnWidth + .nLegendSpacing
        lnTop    = tnTop + (lnI - 1) * (.nLegendBoxSize + .nLegendBoxSpacing)
        .oGDIGraphics.DrawRectangle(loPen, lnLeft, lnTop, ;
            .nLegendBoxSize, .nLegendBoxSize)
        .oGDIGraphics.FillRectangle(loColumnBrush, lnLeft, lnTop, ;
            .nLegendBoxSize, .nLegendBoxSize)
        lnLeft = lnLeft + .nLegendBoxSize + .nLegendTextSpacing
        loPoint.Create(lnLeft, lnTop)
        loTextBrush.Create(.CreateColor(0)) && 黑色
        .oGDIGraphics.DrawStringA(.aValues[lnI, 1], loFont, loPoint, ;
            loStringFormat, loTextBrush)
    next lnI
endwith