如何让一个固定大小的窗口位与屏幕中央（相对任务栏）

[superchpx]

有一个固定大小的窗体如何让它无论在任何分辨率下都左右相对屏幕边界，上下相对上屏幕边界和开始菜单任务栏边界居中？

[Lonelywolf1899]

不管在什么分辨率下，任务栏占屏幕宽度的比例是不变的。

[CatchWind]

要先取得任務欄的位置及寬度.

[CatchWind]

Option Explicit
Private Declare Function SHAppBarMessage Lib "shell32.dll" _
(ByVal dwMessage As Long, pData As APPBARDATA) As Long

Private Const ABM_GETTASKBARPOS = &H5
Private Type RECT
Left As Long
Top As Long
Right As Long
Bottom As Long
End Type
Private Type APPBARDATA
cbSize As Long
hWnd As Long
uCallbackMessage As Long
uEdge As Long
rc As RECT
lParam As Long
End Type

Private Sub Form_Load()
Dim MyData As APPBARDATA

MyData.cbSize = Len(MyData)
Call SHAppBarMessage(ABM_GETTASKBARPOS, MyData)
'任務欄有三個邊都在屏幕外2個像素
With MyData.rc
If .Top > 0 Then '任務欄在最下面
Me.Move (Screen.Width - Width) \ 2, (.Top * Screen.TwipsPerPixelY - Height) \ 2
ElseIf .Bottom < Screen.Height \ Screen.TwipsPerPixelY Then '任務欄在頂上
Me.Move (Screen.Width - Width) \ 2, (Screen.Height - Height + .Bottom * Screen.TwipsPerPixelY) \ 2
ElseIf .Left > 0 Then '在最右邊
Me.Move (.Left * Screen.TwipsPerPixelX - Width) \ 2, (Screen.Height - Height) \ 2
Else
Me.Move (Screen.Width - Width + .Right * Screen.TwipsPerPixelX) \ 2, (Screen.Height - Height) \ 2
End If
End With
End Sub

[lxgmag]

获取当前窗口大小，
获取当前显示器的分辨率，
然后定位其显示坐标。

以上就是我的思路，按此思路做试试行不行？

[viena]

StartUpPosition属性设为2不可以吗？

[ljhdi]

???

[LittleLittleBoy]

好像不行，设它和整个屏幕居中可以，要相对任务栏边界好像难啊