急问：API函数Shell_NotifyIcon的使用问题！！！！！

[cemma]

我在使用Shell_NotifyIcon时发现删除图标总是失败，图标总是无法由应用程序去除。

全局的模块变量声明有：
Public NIM_data As NOTIFYICONDATA

窗口LOAD事件中初始化NIM_data并执行Shell_NotifyIcon成功添加图标。

窗口TERMINATE事件中为如下代码：
NIM_data.uFlags = 0&
NIM_data.cbSize = Len(NIM_data)
lngReturn = Shell_NotifyIcon(NIM_DELETE, NIM_data)
发现返回值lngReturn为0，但GETLASTERROR返回0。

程序的其他代码部分没有修改NIM_data。

我查看MSDN样例程序，不见我的程序有什么异常。
请问什么原因导致Shell_NotifyIcon(NIM_DELETE, NIM_data)失败。

[zyl910]

hwnd和id填好没有

[zyl910]

TERMINATE事件是VB类析构事件
此时窗口已经卸载了
导致Shell_NotifyIcon因为无效窗口句柄而报错

应该写在Unload事件中

[cemma]

谢谢，我也发现了，
现在写在UNLOAD事件里，就不报错了，

[bugouku]

'给一个完整的添加图标到任务栏的类模块
' To use on form:
' Public myTrayIcon As New clsSysTrayIcon
' myTrayIcon.RemoveIcon Me
' myTrayIcon.ShowIcon Me
' myTrayIcon.ChangeIcon Me, (Image, Picture Box, Etc)
' myTrayIcon.ChangeToolTip Me, InputBox("Enter Tool Tip")
'
' ****** Tray Menu Source ****** (Drop In Form)
'
'Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
' Remember..... The value of X will be different if the icon is minimised
' to the system tray. The values in this case will be as follows,
' 7680 ' MouseMove
' 7695 ' Left MouseDown
' 7710 ' Left MouseUp
' 7725 ' Left DoubleClick
' 7740 ' Right MouseDown
' 7755 ' Right MouseUp
' 7770 ' Right DoubleClick
'If myTrayIcon.bRunningInTray Then 'Check to see if form is in the system tray
' Select Case X 'If it is, use X to get message value
' Case 7710: PopupMenu Me.mnuBar1, vbPopupMenuRightButton 'Show a menubar
' Case 7725: myTrayIcon.RemoveIcon Me
' End Select
'End If
'
'End Sub

Option Explicit

Private Type NOTIFYICONDATA
cbSize As Long
hwnd As Long
uId As Long
uFlags As Long
ucallbackMessage As Long
hIcon As Long
szTip As String * 64
End Type

Private FormHandle As Long
Private mvarbRunningInTray As Boolean
Private SysIcon As NOTIFYICONDATA
Private Declare Function Shell_NotifyIcon Lib "shell32" Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, lpData As NOTIFYICONDATA) As Long

Private Property Let bRunningInTray(ByVal vData As Boolean)
mvarbRunningInTray = vData
End Property


Property Get bRunningInTray() As Boolean
bRunningInTray = mvarbRunningInTray
End Property

Public Sub ShowIcon(ByRef sysTrayForm As Form)
SysIcon.cbSize = Len(SysIcon)
SysIcon.hwnd = sysTrayForm.hwnd
SysIcon.uId = vbNull
SysIcon.uFlags = 7
SysIcon.ucallbackMessage = 512
SysIcon.hIcon = sysTrayForm.Icon
SysIcon.szTip = sysTrayForm.Caption + Chr(0)
Shell_NotifyIcon 0, SysIcon
mvarbRunningInTray = True
End Sub

Public Sub RemoveIcon(sysTrayForm As Form)
SysIcon.cbSize = Len(SysIcon)
SysIcon.hwnd = sysTrayForm.hwnd
SysIcon.uId = vbNull
SysIcon.uFlags = 7
SysIcon.ucallbackMessage = vbNull
SysIcon.hIcon = sysTrayForm.Icon
SysIcon.szTip = Chr(0)
Shell_NotifyIcon 2, SysIcon
'If sysTrayForm.Visible = False Then sysTrayForm.Show 'Incase user can't see form
mvarbRunningInTray = False
End Sub

Public Sub ChangeIcon(sysTrayForm As Form, picNewIcon As ListImage)

If mvarbRunningInTray = True Then 'If running in the tray
SysIcon.cbSize = Len(SysIcon)
SysIcon.hwnd = sysTrayForm.hwnd
'SysIcon.uId = vbNull
'SysIcon.uFlags = 7
'SysIcon.ucallbackMessage = 512
SysIcon.hIcon = picNewIcon.Picture
'SysIcon.szTip = sysTrayForm.Caption + Chr(0)
Shell_NotifyIcon 1, SysIcon
End If

End Sub

Public Sub ChangeToolTip(sysTrayForm As Form, strNewTip As String)

If mvarbRunningInTray = True Then 'If running in the tray
SysIcon.cbSize = Len(SysIcon)
SysIcon.hwnd = sysTrayForm.hwnd
SysIcon.szTip = strNewTip & Chr(0)
Shell_NotifyIcon 1, SysIcon
End If

End Sub