RESTORE FILELISTONLY 语句返回的结果集如果传递到参数呢？请高手指教。

[kylike]

正常情况下，在查询分析器中 执行
RESTORE FILELISTONLY From disk = 'path'
会返回一个结果集。例如：
LogicalName PhysicalName Type FileGroupName Size MaxSize
-------------------------------------------------------------------------
Northwind C:\..\northwnd.mdf D PRIMARY 3407872 351843720
Northwind_log C:\..\northwnd.ldf L NULL 1048576 351843720

现在我想把 LogicalName 的值传入参数 @LogicalName , 但实现不了，请高手指教!

[zjcxc]

RESTORE FILELISTONLY 的结果有多个logicalname,你要传到那个变量中?

[zjcxc]

--可以参考我这个存储过程中的获取方法.


if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_RestoreDb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_RestoreDb]
GO

/*--恢复数据库的通用存储过程

--邹建 2003.10--*/

/*--调用示例
--完整恢复数据库
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db'

--差异备份恢复
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db',@retype='DBNOR'
exec p_RestoreDb @bkfile='c:\db_20031015_df.bak',@dbname='db',@retype='DF'

--日志备份恢复
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db',@retype='DBNOR'
exec p_RestoreDb @bkfile='c:\db_20031015_log.bak',@dbname='db',@retype='LOG'

--*/

create proc p_RestoreDb
@bkfile nvarchar(1000), --定义要恢复的备份文件名(带路径)
@dbname sysname='', --定义恢复后的数据库名,默认为备份的文件名
@dbpath nvarchar(260)='', --恢复后的数据库存放目录,不指定则为SQL的默认数据目录
@retype nvarchar(10)='DB', --恢复类型:'DB'完事恢复数据库,'DBNOR' 为差异恢复,日志恢复进行完整恢复,'DF' 差异备份的恢复,'LOG' 日志恢复
@filenumber int=1, --恢复的文件号
@overexist bit=1, --是否覆盖已经存在的数据库,仅@retype为'DB'/'DBNOR'是有效
@killuser bit=1, --是否关闭用户使用进程,仅@overexist=1时有效
@password nvarchar(20)='' --备份文件的密码(仅sql2000支持),如果备份时设置了密码,必须提供此密码
as
declare @sql varchar(8000)

--得到恢复后的数据库名
if isnull(@dbname,'')=''
select @sql=reverse(@bkfile)
,@sql=case when charindex('.',@sql)=0 then @sql
else substring(@sql,charindex('.',@sql)+1,1000) end
,@sql=case when charindex('\',@sql)=0 then @sql
else left(@sql,charindex('\',@sql)-1) end
,@dbname=reverse(@sql)

--得到恢复后的数据库存放目录
if isnull(@dbpath,'')=''
begin
select @dbpath=rtrim(reverse(filename)) from master..sysfiles where name='master'
select @dbpath=reverse(substring(@dbpath,charindex('\',@dbpath),4000))
end

--生成数据库恢复语句
set @sql='restore '+case @retype when 'LOG' then 'log ' else 'database ' end+@dbname
+' from disk='''+@bkfile+''''
+' with file='+cast(@filenumber as varchar)
+case when @overexist=1 and @retype in('DB','DBNOR') then ',replace' else '' end
+case @retype when 'DBNOR' then ',NORECOVERY' else ',RECOVERY' end
+case isnull(@password,'') when '' then '' else ',PASSWORD='''+@password+'''' end

--添加移动逻辑文件的处理
if @retype='DB' or @retype='DBNOR'
begin
--从备份文件中获取逻辑文件名
declare @lfn nvarchar(128),@tp char(1),@i int,@s varchar(1000)

--创建临时表,保存获取的信息
create table #tb(ln nvarchar(128),pn nvarchar(260),tp char(1),fgn nvarchar(128),sz numeric(20,0),Msz numeric(20,0))
--从备份文件中获取信息
set @s='restore filelistonly from disk='''+@bkfile+''''
++case isnull(@password,'') when '' then '' else ' with PASSWORD='''+@password+'''' end
insert into #tb exec(@s)
declare #f cursor for select ln,tp from #tb
open #f
fetch next from #f into @lfn,@tp
set @i=0
while @@fetch_status=0
begin
select @sql=@sql+',move '''+@lfn+''' to '''+@dbpath+@dbname+cast(@i as varchar)
+case @tp when 'D' then '.mdf''' else '.ldf''' end
,@i=@i+1
fetch next from #f into @lfn,@tp
end
close #f
deallocate #f
end

--关闭用户进程处理
if @overexist=1 and @killuser=1
begin
declare hCForEach cursor for
select s='kill '+cast(spid as varchar) from master..sysprocesses
where dbid=db_id(@dbname)
exec sp_msforeach_worker '?'
end

--恢复数据库
exec(@sql)
go

[pbsql]

参考这个简单点：
http://community.csdn.net/Expert/topic/3900/3900083.xml?temp=.2096369

[kylike]

多谢大哥指点，多个参数是不能传入多个值的。
现在我正在写批处理文件，用来实现自动还原数据库。在脚本中要取得备份文件的各项参数值来判断，所以想结果集保存到一些临时表或传入到参数。

我的想法是这样的：
RESTORE FILELISTONLY 返回的结果集插入到一张临时表，然后根据 type 中的 D 或 L 来把LogicalName传入到已定义的参数。

[zjcxc]

参考我的存储过程基本上可以解决了.

[kylike]

情况得到了完美的解决，呵呵! 学习到一项新知识，又节省下大量的时间。
强烈感谢zjcxc(邹建) 及 pbsql(风云) . 结帐了!