如何使用代码来向窗体添加控件，

[ym1980325]

各位大侠我有一个小问题向各位求教就是：
如何使用代码来向窗体添加控件，
请帮忙解答谢谢了。

[daisy8675]

Option Explicit

Dim WithEvents cmdMyCommand As VB.CommandButton

'在下面的定义中，程序定义了一个TextBox控件、一个CommandButton控件
'和一个附加控件。
Dim WithEvents ctlDynamic As VBControlExtender
Dim WithEvents ctlText As VB.TextBox
Dim WithEvents ctlCommand As VB.CommandButton
Dim WithEvents ctlCommandDel As VB.CommandButton
Private Sub ctlCommandDel_Click()
Dim i As Integer

'将控件的许可证信息删除
Licenses.Remove "MSComctlLib.TreeCtrl"
If MsgBox("是否删除所有控件", vbYesNo) = vbYes Then
For i = 1 To Form1.Controls.Count
Controls.Remove 0
Next i
End If
End Sub
Private Sub ctlCommand_Click()
ctlText.Text = "你点击的是控制按钮"
End Sub

Private Sub ctlDynamic_ObjectEvent(Info As EventInfo)
'当点击树形控件的某一个条目后，在ctlText中显示条目。
If Info.Name = "Click" Then
ctlText.Text = "你点击的条目是 " & _
ctlDynamic.object.selecteditem.Text
End If
End Sub

Private Sub Form_Load()
Dim i As Integer
' 将树形控件的许可证信息加入到许可证集合中
' 如果许可证已经存在，则会返回错误信息732
Licenses.Add "MSComctlLib.TreeCtrl"

' 在Form中动态的加入一个树形控件，如果你想树形控件建立到不同的
'容器中，象一个Frame控件或者PictureBox控件，你只要将Controls.Add
'函数的第三个参数改为特定的容器名就可以了
Set ctlDynamic = Controls.Add("MSComctlLib.TreeCtrl", _
"myctl", Form1)
'设置树形控件的位置和尺寸
ctlDynamic.Move 1, 1, 2500, 3500
'在树形控件中加入10个节点
For i = 1 To 10
ctlDynamic.object.nodes.Add Key:="Test" & Str(i), _
Text:="Test" & Str(i)
ctlDynamic.object.nodes.Add Relative:="Test" & Str(i), _
Relationship:=4, Text:="TestChild" & Str(i)
Next i
'使树形控件可见
ctlDynamic.Visible = True

'加入一个TextBox
Set ctlText = Controls.Add("VB.TextBox", "ctlText1", Form1)
'设置TextBox的位置和尺寸
ctlText.Move (ctlDynamic.Left + ctlDynamic.Width + 50), _
1, 2500, 100
'将textBox的背景色设置为蓝色并将前景色设置为白色
ctlText.BackColor = vbBlue
ctlText.ForeColor = vbWhite
'使TextBox可见
ctlText.Visible = True

'加入一个CommandButton
Set ctlCommand = Controls.Add("VB.CommandButton", _
"ctlCommand1", Form1)
'设置CommandButton的位置和尺寸
ctlCommand.Move (ctlDynamic.Left + ctlDynamic.Width + 50), _
ctlText.Height + 50, 1500, 500
'设置CommandButton的标题
ctlCommand.Caption = "点击"
'使CommandButton可见
ctlCommand.Visible = True

'建立一个删除按钮
Set ctlCommandDel = Controls.Add("VB.CommandButton", _
"ctlCommand2", Form1)
ctlCommandDel.Move (ctlDynamic.Left + ctlDynamic.Width + 50), _
ctlText.Height + 650, 1500, 500
ctlCommandDel.Caption = "删除所有控件"
ctlCommandDel.Visible = True
End Sub

[hsghxm]

新建一个Class Modules，代码：
Option Explicit
Public WithEvents ctlText As VB.TextBox
Public WithEvents ctlLabel As VB.Label

在窗体里,添加一个Frame控件：
Option Explicit
Private pclass As Class1
Private Sub Form_Load()
Set pclass = New Class1
Set pclass.ctlLabel = Controls.Add("VB.Label", "lblName", Frame1)
pclass.ctlLabel.Move 250, 550, 1200, 400
pclass.ctlLabel.ForeColor = vbBlack
pclass.ctlLabel.Caption = "就这样添加的"
pclass.ctlLabel.Visible = True
Set pclass.ctlText = Controls.Add("VB.TextBox", "txtName", Frame1)
pclass.ctlText.Move 250 + 1200, pclass.ctlLabel.Top, 3500, 400
pclass.ctlText.BackColor = &H80000005
pclass.ctlText.ForeColor = vbBlack
pclass.ctlText.Font.Size = 10
pclass.ctlText.Visible = True
End Sub

[hsghxm]

或者直接在窗体中这样写，就可以添加一个textbox 和label了
Option Explicit
Dim WithEvents ctlText As VB.TextBox
Dim WithEvents ctlLabel As VB.Label

Private Sub Form_Load()
Set ctlLabel = Controls.Add("VB.Label", "lblName", Form1)
ctlLabel.Move 250, 550, 1200, 400
ctlLabel.ForeColor = vbBlack
ctlLabel.Caption = "就这样添加的"
ctlLabel.Visible = True
Set ctlText = Controls.Add("VB.TextBox", "txtName", Form1)
ctlText.Move 250 + 1200, ctlLabel.Top, 3500, 400
ctlText.BackColor = &H80000005
ctlText.ForeColor = vbBlack
ctlText.Font.Size = 10
ctlText.Visible = True
End Sub

[hr88rong]

支持,我顶......我学习...... :)

[wosirius]

mark

[wudeqing]

up

[wudeqing]

Option Explicit
Private pclass As Class1
Private Sub Form_Load()
Set pclass = New Class1
Set pclass.ctlLabel = Controls.Add("VB.Label", "lblName", Frame1)
pclass.ctlLabel.Move 250, 550, 1200, 400
pclass.ctlLabel.ForeColor = vbBlackpclass.ctlLabel.Visible = True
Set pclass.ctlText = Controls.Add("VB.TextBox", "txtName", Frame1)
pclass.ctlText.Move 250 + 1200, pclass.ctlLabel.Top, 3500, 400
pclass.ctlText.BackColor = &H80000005
pclass.ctlText.ForeColor = vbBlack
pclass.ctlText.Font.Size = 10
pclass.ctlText.Visible = True
End Sub

[curio2]

好 啊！！
正是我想要的