请问：如何在ListView6.0控件中添加记录？

[cloudchina]

Dim itmX As ListView
Set itmX = ListView1.ListSubItems.Add(, , sFileName) '添加第一项

这个在ListView6.0控件中使用好象有错误，然后添加后面的项，应该如何做？

[myhgyp]

'添加 ColumnHeaders。列宽度等于控件宽度
'除以 ColumnHeader 对象的数目。
ListView1.ColumnHeaders.Add , , "Author", ListView1.Width / 3
ListView1.ColumnHeaders.Add , , "Author ID", ListView1.Width / 3, lvwColumnCenter
ListView1.ColumnHeaders.Add , , "Birthdate", ListView1.Width / 3
ListView1.GridLines = True
' Set View property to Report.
ListView1.View = lvwReport
Dim itemX As ListItem
Set itemX = ListView1.ListItems.Add(, "m1", "第一项第一列")
itemX.SubItems(1) = "第一项第二列"
itemX.SubItems(2) = "第一项第三列"

[3q2008Com]

'我敢接触这个控件时写的 希望对你有用
Private Sub Command1_Click()

Dim i, mRow As ListItem
lsvEMail.SmallIcons = ImageList1 '关联图标

' For i = 1 To 10
' lsvEMail.ListItems.Add i, , i & "aa"
' lsvEMail.ListItems(i).SubItems(1) = i & "bb"
' lsvEMail.ListItems(i).SubItems(2) = i & "cc"
' lsvEMail.ListItems(i).ListSubItems.Item(2).ReportIcon = 2 '将 第2列加入图标
' lsvEMail.ListItems(i).SubItems(3) = i & "ddd"
' lsvEMail.ListItems(i).SmallIcon = i
' Next
'

For i = 1 To 20
Set mRow = lsvEMail.ListItems.Add(, , i)
mRow.SubItems(1) = i & "bb"
mRow.SubItems(2) = i & "cc"

mRow.ListSubItems.Item(2).ReportIcon = 2
'将 第2列加入图标
mRow.SubItems(3) = i & "ddd"
Next

For j = 1 To lsvEMail.ListItems(2).ListSubItems.Count '第2列变粗体
lsvEMail.ListItems(2).ListSubItems.Item(j).Bold = True
Next

End Sub

Private Sub Form_Load()
lsvEMail.HideSelection = 0
lsvEMail.View = lvwReport
Dim i
For i = 0 To 5
lsvEMail.ColumnHeaders.Add , , "标题" & i, 1800
Next

End Sub


Private Sub lsvEMail_DblClick()
' lsvEMail.MultiSelect
'lsvEMail.SelectedItem.Index '对应行的索引
MsgBox lsvEMail.SelectedItem.ListSubItems(2).Text
End Sub

Private Sub lsvEMail_MouseUp(Button As Integer, Shift As Integer, x As Single, y As Single)
' lsvEMail.ListItems(lsvEMail.HitTest(x, y).Index).ForeColor = &HFF&
' Text1.Left = ListView1.ListItems(ListView1.HitTest(x, y).Index).Left + ListView1.Left
'Text1.Top = ListView1.ListItems(ListView1.HitTest(x, y).Index).Top + ListView1.Top
'Text1.Height = ListView1.ListItems(ListView1.HitTest(x, y).Index).Height
'Text1.Width = ListView1.ListItems(ListView1.HitTest(x, y).Index).Width
lsvEMail.ListItems.Remove (lsvEMail.HitTest(x, y).Index)
End Sub

[threenewbee]

Dim itmX As ListView 错了，是 Dim itmX As ListItem
或 Dim itmX As Object

[射天狼]

Dim lv_Item As ListItem

Set lv_Item = lvTelphone.ListItems.Add(, Trim(rs!ID), Trim(txtZhuCeHao.Text), 1, 1)
lv_Item.ListSubItems.Add , , Trim(txtMingCheng.Text)
lv_Item.ListSubItems.Add , , Trim(txtXingMing.Text)
lv_Item.ListSubItems.Add , , Trim(txtXingShi.Text)
lv_Item.ListSubItems.Add , , Trim(txtChangSuo.Text)
lv_Item.ListSubItems.Add , , Trim(txtJingYingFangShi.Text)
lv_Item.ListSubItems.Add , , Trim(txtYouXiaoQi1.Text)
lv_Item.ListSubItems.Add , , Trim(txtYouXiaoQi2.Text)
lv_Item.ListSubItems.Add , , Trim(txtFaZhaoRiQi.Text)

[还想懒够]

Dim itmX As ListView

改为Dim itmX As ListItem