求数据库备份方案的模板

[Fow]

初次写一个用SQLServer2000数据库的备份方案，对格式和写法不是很了解，那位能发个例子看看，不胜感激！

[Fow]

我的email：[e-mail] 感谢各位！

[zlp321002]

/*--备份数据库

--邹建 2003.10--*/

/*--调用示例

--备份当前数据库
exec p_backupdb @bkpath='c:\',@bkfname='db_\DATE\_db.bak'

--差异备份当前数据库
exec p_backupdb @bkpath='c:\',@bkfname='db_\DATE\_df.bak',@bktype='DF'

--备份当前数据库日志
exec p_backupdb @bkpath='c:\',@bkfname='db_\DATE\_log.bak',@bktype='LOG'

--*/

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_backupdb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_backupdb]
GO

create proc p_backupdb
@dbname sysname='', --要备份的数据库名称,不指定则备份当前数据库
@bkpath nvarchar(260)='', --备份文件的存放目录,不指定则使用SQL默认的备份目录
@bkfname nvarchar(260)='', --备份文件名,文件名中可以用\DBNAME\代表数据库名,\DATE\代表日期,\TIME\代表时间
@bktype nvarchar(10)='DB', --备份类型:'DB'备份数据库,'DF' 差异备份,'LOG' 日志备份
@appendfile bit=1 --追加/覆盖备份文件
as
declare @sql varchar(8000)
if isnull(@dbname,'')='' set @dbname=db_name()
if isnull(@bkpath,'')='' set @bkpath=dbo.f_getdbpath(null)
if isnull(@bkfname,'')='' set @bkfname='\DBNAME\_\DATE\_\TIME\.BAK'
set @bkfname=replace(replace(replace(@bkfname,'\DBNAME\',@dbname)
,'\DATE\',convert(varchar,getdate(),112))
,'\TIME\',replace(convert(varchar,getdate(),108),':',''))
set @sql='backup '+case @bktype when 'LOG' then 'log ' else 'database ' end +@dbname
+' to disk='''+@bkpath+@bkfname
+''' with '+case @bktype when 'DF' then 'DIFFERENTIAL,' else '' end
+case @appendfile when 1 then 'NOINIT' else 'INIT' end
print @sql
exec(@sql)
go

----------------------------------------------------------------------
/*--恢复数据库

--邹建 2003.10--*/

/*--调用示例
--完整恢复数据库
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db'

--差异备份恢复
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db',@retype='DBNOR'
exec p_backupdb @bkfile='c:\db_20031015_df.bak',@dbname='db',@retype='DF'

--日志备份恢复
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db',@retype='DBNOR'
exec p_backupdb @bkfile='c:\db_20031015_log.bak',@dbname='db',@retype='LOG'

--*/

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_RestoreDb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_RestoreDb]
GO

create proc p_RestoreDb
@bkfile nvarchar(1000), --定义要恢复的备份文件名
@dbname sysname='', --定义恢复后的数据库名,默认为备份的文件名
@dbpath nvarchar(260)='', --恢复后的数据库存放目录,不指定则为SQL的默认数据目录
@retype nvarchar(10)='DB', --恢复类型:'DB'完事恢复数据库,'DBNOR' 为差异恢复,日志恢复进行完整恢复,'DF' 差异备份的恢复,'LOG' 日志恢复
@filenumber int=1, --恢复的文件号
@overexist bit=1, --是否覆盖已经存在的数据库,仅@retype为
@killuser bit=1 --是否关闭用户使用进程,仅@overexist=1时有效
as
declare @sql varchar(8000)

--得到恢复后的数据库名
if isnull(@dbname,'')=''
select @sql=reverse(@bkfile)
,@sql=case when charindex('.',@sql)=0 then @sql
else substring(@sql,charindex('.',@sql)+1,1000) end
,@sql=case when charindex('\',@sql)=0 then @sql
else left(@sql,charindex('\',@sql)-1) end
,@dbname=reverse(@sql)

--得到恢复后的数据库存放目录
if isnull(@dbpath,'')='' set @dbpath=dbo.f_getdbpath('')

--生成数据库恢复语句
set @sql='restore '+case @retype when 'LOG' then 'log ' else 'database ' end+@dbname
+' from disk='''+@bkfile+''''
+' with file='+cast(@filenumber as varchar)
+case when @overexist=1 and @retype in('DB','DBNOR') then ',replace' else '' end
+case @retype when 'DBNOR' then ',NORECOVERY' else ',RECOVERY' end
print @sql
--添加移动逻辑文件的处理
if @retype='DB' or @retype='DBNOR'
begin
--从备份文件中获取逻辑文件名
declare @lfn nvarchar(128),@tp char(1),@i int

--创建临时表,保存获取的信息
create table #tb(ln nvarchar(128),pn nvarchar(260),tp char(1),fgn nvarchar(128),sz numeric(20,0),Msz numeric(20,0))
--从备份文件中获取信息
insert into #tb exec('restore filelistonly from disk='''+@bkfile+'''')
declare #f cursor for select ln,tp from #tb
open #f
fetch next from #f into @lfn,@tp
set @i=0
while @@fetch_status=0
begin
select @sql=@sql+',move '''+@lfn+''' to '''+@dbpath+@dbname+cast(@i as varchar)
+case @tp when 'D' then '.mdf''' else '.ldf''' end
,@i=@i+1
fetch next from #f into @lfn,@tp
end
close #f
deallocate #f
end

--关闭用户进程处理
if @overexist=1 and @killuser=1
begin
declare @spid varchar(20)
declare #spid cursor for
select spid=cast(spid as varchar(20)) from master..sysprocesses where dbid=db_id(@dbname)
open #spid
fetch next from #spid into @spid
while @@fetch_status=0
begin
exec('kill '+@spid)
fetch next from #spid into @spid
end
close #spid
deallocate #spid
end

--恢复数据库
exec(@sql)

go

---------------然后建作业,定时执行备份方案!

[iwl]

楼上的非常好用了

[Fow]

谢谢老大，不过我想要个文档的，就是如何制定一个完善的方案，如何评估故障对数据的损失，出现故障后如何恢复，相当于看着文档进行备份设置和恢复等。

[Fow]

不是要现成的，只要个模板，主要是不知道要写到那些信息，多多指教！

[wormwormwormworm]

自己动手了，不要什么都想要现成的

[fiele]

很好用,谢谢

[zhonghuashen]

我这有份方案及测试报告，全是自己做的。不过只能给你说说。

首先要估计你备份数据库的大小是多少G的如果一个月数据不超过3G怎么备份都行
比如你可以每天做完全备份，再P4 2.4G＋512M的机子上只需2分钟左右！（如果是服务器的话，一会就好了），从性能上说应该可以了。这样的话就算你的数据库崩溃的话损失量也只有100/3000＝3.33％，从安全的角度上说应该可以承受的：）
如果数据库一个月可以达到10G的大小的话，那么只能做完全备份＋差异备份。可以半个月做一次完全备份，每隔几天做一次差异备份。
如果更大的话，那只能完全备份＋差异备份＋日志备份。这个不说的，比较繁琐。如果需要的话，可以问。

[Fow]

多谢这位兄弟的指导,有没有一个比较规范的写法,内容可以自己定义,主要是格式上!

[koposo]

学习,mark

[zhonghuashen]

这个要看你的具体需求了，不过我是先写份方案，然后根据方案，一个一个做测试，最后提交让他们去看。具体说怎么规范，我就不清楚了。主要以大家都看的懂为主。

[zhonghuashen]

你的方案：
第一、要与你的测试报告对应，不能无中生有，让人处处信服。
第二、尽可能的详细。

[zhonghuashen]

我只能给你一部分测试报告，自己去想吧
三.数据库大小：待备份的数据库库为3.1G(备份时用查询分析器select top 500 * from my_datatable可以查询，运行提取数据库程序能正常运行，速度稍慢)
1.备份方式：利用SQLSERVER2000自带的BACKUP功能，完全备份
时间：4分钟左右
说明：恢复只用了5分钟左右
备份是，其余程序都能运行自如。

2.备份方式：利用ADO.NET功能，完全备份
时间：3.05分钟
说明：恢复 分钟左右(还未测,不过可以估计与1大约相同）
备份是，其余程序都能运行自如。

3.备份方式：利用SQLDMO+.NET功能，完全备份，备份后文件大小为953M
时间：2.45分钟
说明：恢复 分钟左右(还未测,不过可以估计与1大约相同)
备份是，其余程序都能运行自如。

[Fow]

主要要涉及到那些方面?系统硬件环境,软件环境,数据库环境,需求,备份方式,还原方式,灾难损失估计还有哪些?



====CSDN 小助手 V2.0 2005年10月16日发布====
CSDN小助手是一款脱离浏览器也可以访问Csdn论坛的软件
界面：http://blog.csdn.net/Qqwwee_Com/archive/2005/10/16/504620.aspx
下载：http://szlawbook.com/csdnv2/csdnv2.rar

为神六喝彩，向所有科技工作者致敬！
拒绝日货。

[zhonghuashen]

已经很全了嘛！主要是备份方式,还原方式,灾难损失估计

[zhonghuashen]

性能是和系统硬件环境,软件环境,数据库环境有关的

[Fow]

了解了,结贴!