如何用VFP打開一個PDF文件。。。

[unlist]

在d:\abc.pdf
我想用VFP打開d:\abc.pdf
怎樣寫程序呢？

[unlist]

謝謝

[tch789]

up

[十豆三]

1、首先要安装PDF阅读工具。

2、然后利用API来调用默认关联的程序打开PDF文件，请详见：

在VFP中我们可以用run来调用由VFP自身生成的.exe文件。命令格式：
run c:\..\*.exe

当调用非VFP自身生成的.exe文件时，需要加上绝对路径和参数。
一般来说，用VFP运行非VFP自身生成的可执行文件时，会有一个黑色的窗口显示一下。可以通过加上/n来隐藏这个窗口。例如运行Windows下的扫雷游戏，命令格式如下：
RUN/n C:\Windows\Winmine.exe
下面运行一个更复杂一点的程序。用word打开c:\下的一个名为mlx.doc的word文件，命令格式如下：
run /n3 C:\Program Files\Microsoft Office\Office\Winword.exe C:\mlx.doc
参数：n 在运行时隐藏VFP的黑色窗口。
3 表示以最大化的方式运行程序。1正常方式、2最小化方式、3最大化方式

在这种情况下，虽然可以通过加上参数使程序程序能够流畅运行，但还是要指定绝对路径,而在实际开发时我们常常无法确定所需要启动的应用程序的文件名及其绝对路径。比如，在上例中，我们无法确定用户的word到底安装在什么地方，如果用户把word安装到了别的地方，上述命令便会出错。再如，一个.gif文件，有的用户喜欢用ACD See来打开，有的用户喜欢用IE来打开，有的用户喜欢用豪杰来打开,……
为了解这种情况我们可以调用Windows的文件关连来打开文件。即所有的文件都用系统默认的程序来打开。这就要调用Windows的Win32 API函数。调用方式如下：

DECLARE INTEGER ShellExecute IN shell32.DLL INTEGER HWND,;
STRING lpszOP, ;
STRING lpszFile, ;
STRING lpszParams, ;
STRING lpszDir, ;
INTEGER fsshowcmd
DECLARE INTEGER GetDesktopWindow IN win32api
HWND = GetDesktopWindow()
lpszOP = "open"
* 指定要打开的文件名
lpszFile ="c:\mlx.doc"
lpszParams = ""
lpszDir = "c:\temp"
fsshowcmd = 1
* 执行ShellExecute命令
LNRETURN = ShellExecute(HWND, lpszOP,lpszFile, lpszParams, lpszDir,fsshowcmd)

可以用任意的文件名来替换上文中的 c:\mlx.doc 。如果指定的文件名Windows无法找到相应的关连程序，这时程序将不会做出反应。有关的参数可以自行偿试进行修改,以达到最佳效果。

[shamihu]

可以直接将PDF显示在VFP Form里的，机器里事先安装好PDF reader ver 6.0
将下面程序代码保存为一个prg文件，传入PDF 文件名作为参数，运行一下看看效果便知道了。


LPARAMETERS tFile

PUBLIC oform1

oform1=NEWOBJECT("form1")

IF VARTYPE(cFile) # "U"
oForm1.cmdFile.Visible = .f.
oForm1.cmdExit.Visible = .f.
oForm1.oleControl1.Top = 12
oForm1.oleControl1.LoadFile([&cFile])
ENDIF

oform1.Show
RETURN
**********************************************************
DEFINE CLASS form1 AS form

DoCreate = .T.
Caption = "pdfForm"
Name = "Form1"

ADD OBJECT cmdfile AS commandbutton WITH ;
Top = 12, ;
Left = 12, ;
Height = 27, ;
Width = 144, ;
Caption = "Select File", ;
Name = "cmdFile"

ADD OBJECT cmdexit AS commandbutton WITH ;
Top = 12, ;
Left = 168, ;
Height = 27, ;
Width = 84, ;
Caption = "E\<xit", ;
Name = "cmdExit"

ADD OBJECT olecontrol1 AS olecontrol WITH ;
OLEClass = "PDF.PdfCtrl.5", ;
Top = 48, ;
Left = 12, ;
Height = 192, ;
Width = 348, ;
Name = "Olecontrol1"

PROCEDURE Init
ThisForm.ReSize()
ENDPROC

PROCEDURE Resize
ThisForm.Olecontrol1.Height = ThisForm.Height - 60
ThisForm.Olecontrol1.Width = ThisForm.Width - 24
ThisForm.Olecontrol1.Refresh()
ENDPROC

PROCEDURE cmdfile.Click
LOCAL cFile
cFile = GETFILE([PDF])
IF !EMPTY(cFile)
THISFORM.oleControl1.LoadFile([&cFile])
ENDIF
ENDPROC

PROCEDURE cmdexit.Click
ThisForm.Release()
ENDPROC

ENDDEFINE

[shamihu]

可惜CSDN不能贴图.

[十豆三]

PDF reader ver 6.0

这句
OLEClass = "PDF.PdfCtrl.5", ;
应为

OLEClass = "PDF.PdfCtrl.6", ;
吧

[shamihu]

to: apple_8180(十豆三)
你自己在你电脑上看看吧，到底应该是"PDF.PdfCtrl.5"还是"PDF.PdfCtrl.6", ^-^
编程序不应该想当然，你说呢？

[十豆三]

在我的机子上必须为6，5不行。

我装的是Adobe Reader 6.0

控件名称: PDF.PdfCtrl.6
版本: 5.0
状态: 已注册
ProgID: PDF.PdfCtrl.6
CLSID: {CA8A9780-280D-11CF-A24D-444553540000}
TypeLib: {CA8A9783-280D-11CF-A24D-444553540000}
文件位置: C:\PROGRA~1\Adobe\ACROBA~1.0\Reader\ActiveX\pdf.ocx
文件大小: 416224 字节
创建于: 11/03/03 14:39:10
修改于: 05/18/04
访问于: 10/24/05

[zsjiaming]

上面的代码试了一下.效果不错.

至于pdf.ocx的版本.........主要是看机子上装的是哪一个版本.我的是5.0

发布的时候也许可以连同pdf.ocx一同发布

使用前要注册,不知免费使用的pdf有没有这个控件,我装的是个100多M的完整d版.
如果免费的有个pdf控件,就没有什么破解问题.单独注册pdf.OCX使用

[Gucciwu]

请问如何将vfp的报表保存为pdf文档?