请问如何动态填加listview控件啊。不管该控件有没有在工程中引用。

[cinderella1]

添加标准控件我到会，但listview。。。。

[northwolves]

Dim WithEvents ListView1 As VBControlExtender
Private Sub Form_Load()
Licenses.Add "Comctl.ListViewctrl.1", "x"
Set ListView1 = Me.Controls.Add("Comctl.ListViewctrl.1", "listview1", Me)
ListView1.Visible = True
ListView1.Move 0, 0, 3000, 2000
End Sub

[winehero]

来晚了，只好先顶一下。。。

分也不能白蹭，在此楼上已经说得很清楚使用VBControlExtender对象来处理。下面偶说一下新创建的控件其事件脚本如何处理（以楼上创建出的ListView1）。
在VB编辑器上方左边控件列表中选取ListView1，右边事件列表中选取ObjectEvent，该事件中可处理动态创建控件的所有事件，其中Info为事件对象参数Info.Name为事件名称，而Info.EventParameters为事件参数集合对象。故事件脚本可实现如下：
Private Sub ListView1_ObjectEvent(Info As EventInfo)
Select Case Info.Name
Case "BeforeLabelEdit"
If 你想取消LabelEdit then
Info.EventParameters (1)=True 'Info.EventParameters (1)就是该事件的Cancel参数
else
end if
Case "Click"
Case "ItemClick"
End Select
Debug.Print Info.Name & "事件触发了"
End Sub

[laviewpbt]

Dim WithEvents ListView1 As VBControlExtender
Private Sub Form_Load()
Licenses.Add "msComctllib.ListViewctrl.2", "x"
Set ListView1 = Me.Controls.Add("msComctllib.ListViewctrl.2", "listview1", Me)
ListView1.Visible = True
ListView1.Move 0, 0, 3000, 2000
End Sub

[faysky2]

蹭分
-----------------------
Dim WithEvents ListView1 As VBControlExtender
Private Sub Form_Load()
Licenses.Add "msComctllib.ListViewctrl.2", "x"
Set ListView1 = Me.Controls.Add("msComctllib.ListViewctrl.2", "listview1", Me)
ListView1.Visible = True
ListView1.Move 0, 0, 3000, 2000
End Sub
---------------------
Add 方法（Controls 集合）


在 Controls 集合中添加一个控件并返回一个对该控件的引用。

语法

object.Add (ProgID, name, container)

Add 方法语法有这些部分:

部分 描述
Object 必需的。一个对象表达式，其值是“应用于”列表中的一个对象。
ProgID 必需的。一个标识控件的字符串。大多数控件的 ProgID 都可通过查看对象浏览器来决定。控件的 ProgID 是由控件的库和类组成的。例如，CommandButton 控件的 ProgID 是 VB.CommandButton。在 ProgID 与对象浏览器中所显示的不一样的情况下，Visual Basic 将显示一个包括正确 ProgId 的错误信息。
name 必要的。一个字符串，用来标识集合的成员。
container 可选的。一个对象引用，它指定控件的容器。如果没有指定或为 NULL，缺省值为 Controls 集合所属的容器。通过指定该参数，可以把一个控件放置在任何现存的容器控件（如 Frame 控件）中。用户控件或 ActiveX 文档也可以作为一个容器。


说明

注意 Controls 集合是后期绑定的集合。这意味着编译器不能预先决定集合以及它们的对象或它们的界面包含哪些控件。没有这些信息，自动语句生成器不能工作。

该方法允许您在运行时向应用程序中添加控件。即使在应用程序已经被编译与部署之后，动态控件添加也可以用来向应用程序添加一个控件的功能。例如，您可能有几个复杂的用户控件，每个适合于一个不同的任务。由于外部因素不同，如时间或日期或用户输入，不同的用户控件可以被添加到一个应用程序中的某个现存窗体。您也可以利用这个方法的 container 参数来指定一个容器控件（如 Frame 控件）来放置这个控件。或您可以设计一个自动读取文件、数据库或注册表项来加载新控件的应用程序。用这种方法，您可以修改一个应用程序而不必重新部署它。

重点 当您添加一个未引用的需要许可证的控件到一个现存的（已部署好的）应用程序时，在使用 Add 方法之前您必须也添加这个控件的许可证关键字。关于什么时候和如何添加许可证有关信息，请参阅“请参阅”列表中的“Licenses 集合”。
************************************************************
*****************************************
在运行时添加未引用的控件
您也可以利用 Add 方法来动态添加一个在工程中没有被引用的控件。(“未引用的”控件是不出现在 Toolbox 中的控件)。为此，您必须也把控件的 License 关键字添加到 Licenses 集合中。下面的示例中在添加控件本身之前添加了控件的许可证关键字：

Option Explicit
Private WithEvents extCtl As VBControlExtender

Private Sub Form_Load()
Licenses.Add "prjWeeks.WeeksCtl", "xydsfasfjewfe"
Set extCtl = Form1.Controls.Add("prjWeeks.WeeksCtl", "ctl1")
extCtl.Visible = True ' The control is invisible by default.
End Sub

注意 请参阅关于检索控件许可证关键字的详细信息的“请参阅”列表中的“增加方法 (Licenses 集合) ”。

但是，为了编程这样一个未引用控件的事件，您必须使用 WithEvents 关键字声明一个对象变量为VBControlExtender 对象(如上)，并且设置该对象变量到 Add 方法返回的引用上。然后，利用VBControlExtender 对象的 ObjectEvent 事件来编程该控件的事件。下面是一个简单的例子。

Option Explicit
Dim WithEvents objExt As VBControlExtender '声明 Extender 变量

Private Sub LoadControl()
Licenses.Add "Project1.Control1", "xydsfasfjewfe"
Set objExt = Controls.Add("Project1.Control1", "myCtl")
objExt.Visible = True
End Sub

Private Sub extObj_ObjectEvent(Info As EventInfo)
'使用 Select Case 编程控件的事件。
Select Case Info.Name
Case "Click"
'这里处理 Click 事件。
'现在显示其他的 case
Case Else '未知事件
'这里处理未知事件。
End Select
End Sub

Note 不能把一个固有的控件指定给这个 VBControlExtender 变量; 任何这种试图将引起类型不匹配错误。

但是，您也可以通过使用 WithEvents 关键字声明一个对象变量，并且设置该方法返回的引用为该变量，从而编程一个动态添加控件的事件，如下所示。

Option Explicit
'声明对象变量为 CommandButton 。
Private WithEvents cmdObject As CommandButton

Private Sub Form_Load()
Set cmdObject = Form1.Controls.Add("VB.CommandButton", "cmdOne")
cmdObject.Visible = True
cmdObject.Caption = "Dynamic CommandButton"
End Sub

Private Sub cmdObject_Click()
Print "This is a dynamically added control"
End Sub

如果希望添加一个用户控件或任何 ActiveX 控件到您的窗体，必须或者把这个控件添加到“工具箱”，或者把控件的 License 关键字添加到 Licenses 集合中。有关详细信息请参阅“增加方法 (Licenses 集合)”。

注意 如果您添加一个 ActiveX 或用户控件到您的工程，但是没有在窗体中使用它，您也必须不要选定“工程属性”对话框的“生成” 选项卡上的“删除有关未使用的 ActiveX 控件”选项。如果您的应用程序试图添加该控件，那么该 Add 方法将失败，因为必需的信息已经被丢弃。

**************************************
删除控件
要删除动态添加的控件，用“移除”方法。请注意，您只能删除那些用“添加”方法添加的控件（与用“Load”语句添加的控件进行对比)下面的示例删除一个动态添加的控件：

Form1.Controls.Remove "ctl1" ' 该控件的名称为 ctl1。

[chenyu5188]

UP

同意楼上各位