如何使commondialog对话框居中

[BuilderEm]

commondialog在ShowOpen对话框时,窗口在左上角,请教如何使其居中?

[jobs002]

MSDN 搜索CommonDialog
注意 无法指定对话框显示在什么地方

[上官云峰]

无法控制commondialog是否居中

[faysky2]

居中在屏幕：

模块:
Option Explicit
Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" (ByVal idHook As Long, ByVal lpfn As Long, ByVal hmod As Long, ByVal dwThreadId As Long) As Long
Declare Function UnhookWindowsHookEx Lib "user32" (ByVal hHook As Long) As Long
Declare Function CallNextHookEx Lib "user32" (ByVal hHook As Long, ByVal nCode As Long, ByVal wParam As Long, lparam As Any) As Long
Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String, ByVal cch As Long) As Long
Declare Function SetWindowText Lib "user32" Alias "SetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String) As Long
Declare Function EnumChildWindows Lib "user32" (ByVal hWndParent As Long, ByVal lpEnumFunc As Long, ByVal lparam As Long) As Long
Declare Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hwnd As Long, ByVal lpClassName As String, ByVal nMaxCount As Long) As Long
Public Declare Function MoveWindow Lib "user32" (ByVal hwnd As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal bRepaint As Long) As Long
Public Declare Function GetWindowRect Lib "user32" (ByVal hwnd As Long, lpRect As RECT) As Long
Public Type RECT
Left As Long
Top As Long
Right As Long
Bottom As Long
End Type

Public Const HCBT_ACTIVATE = 5
Public Const WH_CBT = 5

Public hHook As Long

Public Sub EnableHook()
If hHook = 0 Then
hHook = SetWindowsHookEx(WH_CBT, AddressOf HookProc, 0, App.ThreadID)
End If
End Sub
Public Sub FreeHook()
If hHook <> 0 Then
Call UnhookWindowsHookEx(hHook)
hHook = 0
End If
End Sub

Public Function HookProc(ByVal nCode As Long, ByVal wParam As Long, ByVal lparam As Long) As Long
If nCode < 0 Then
HookProc = CallNextHookEx(hHook, nCode, wParam, lparam)
Exit Function
End If
If nCode = HCBT_ACTIVATE Then
Dim str5 As String
Dim len5 As Long, i As Long
str5 = String(255, 0)
len5 = 256
i = GetWindowText(wParam, str5, len5)
str5 = Left(str5, InStr(1, str5, Chr(0)) - 1)
'设置颜色对话框居中显示
If str5 = "颜色" Then
Dim RT As RECT
GetWindowRect wParam, RT
Dim mWidth As Long
Dim mHeight As Long
Dim mLeft As Long
Dim mTop As Long
mWidth = RT.Right - RT.Left
mHeight = RT.Bottom - RT.Top
mLeft = Screen.Width \ Screen.TwipsPerPixelX
mLeft = (mLeft - mWidth) \ 2
mTop = Screen.Height \ Screen.TwipsPerPixelY
mTop = (mTop - mHeight) \ 2
MoveWindow wParam, mLeft, mTop, mWidth, mHeight, True
End If
End If
HookProc = 0 '令待完成的动作继续完成，若为1，则取消原本要完成的动作
End Function

窗体,只有一个按钮和一个CommonDialog控件:
Option Explicit

Private Sub Command1_Click()
EnableHook
CommonDialog1.ShowColor
FreeHook
End Sub

[of123]

如果是在C++或Delphi中，可以使用钩子(hook)函数，然后在钩子函数中设置对话框的位置。不过在VB中使用钩子(hook)函数就麻烦了，这是VB的弱项。不过VB也有自己的办法。要想解决这个问题，首先要找出CommonDialog是如何设置其对话框位置。首先在一个Form中放置一个CommonDialog控件，然后不断移动Form在屏幕的位置，并激活CommonDialog。你会发现CommonDialog总是出现在Form的左上角，当Form出现在屏幕的左侧或上部时，这一点非常明显。但当Form出现在屏幕下方或右侧时，CommonDialog会稍微做调整，以确保整个对话框都能显示在屏幕范围内。如果你的Form比较靠近屏幕中心，那么CommonDialog自然也会出现在屏幕中心。利用这一特点，我们可以建立一个空窗体，称为MyCDForm，然后在其上放置一个CommonDialog控件。这个MyCDForm只用来放置CommonDialog控件，没有其他用途。然后输入下面这个函数。
Private Function ChooseFile(argLeft As Single, argTop As Single) As Boolean
' 设置为没有文件被选择
ChooseFile = False
' 移动MyCDForm位置
MyCDForm.Left = argLeft
MyCDForm.Top = argTop
' 设置CommonDialog控件
MyCDForm!CommonDialog1.CancelError = True
On Error GoTo OpenError
' 显示CommonDialog
MyCDForm!CommonDialog1.ShowOpen
' 卸载MyCDForm
Unload MyCDForm
ChooseFile = True
Exit Function
OpenError:
' 用户按下Cancel键
Unload MyCDForm
Exit Function
End Function
当你的程序需要调用Open对话框时，使用ChooseFile就可以了。argLeft和argTop是Open对话框在屏幕上出现的位置的左上角的坐标。从这个函数可以看出，实际上我们是将MyCDForm的位置该为argLeft和argTop，而利用Open对话框的位置总是出现在其父窗口的左上角这一特性来改变Open对话框的屏幕位置。类似地，你也可以显示其他的对话框。如果你想让对话框出现在屏幕中央，则argLeft = (Screen.Width - 对话框宽度) \ 2，argTop = (Screen.Height - 对话框高度) \ 2。对于屏幕大小为800*600个像素，显示Open对话框的情况，这两个值大致均为1500。