如何保存picturebox上的内容为图片

2006-04-05 10:44:43 641 阅读 AI 写同款 · GEO 优化AI 选题数据监测一键分发 ›

VB中PictureBox控件使用教程 PictureBox对象可以说是任何对象的原始型态，它可以加载图片、显示文字、画图外，它还能与Frame对象一样，在自己本身里头加载其它的对象而自成一个小群组，用PictureBox可以仿真出任何对象的外观，PictureBox是VB基本控件里变化最多，功能最多，也是令人最想去征服它的一个物件。 ●PictureBox与Frame对象一样，本身都能装载其它的对象而自己形成一个对象... 阅读详情

picturebox上有图形还有其他控件如command等,我如何能把它保存为图片格式的文件呢,
用SavePicture Picture1.Image, "c:\ok.jpg"只能把pictureboc上本身画的东西保存下来,可是command却没有了,我要凡是以picturebox为容器的所有可见东西都保存成一张图片

...全文

黑马程序员-用winForm开发简易文本编辑器和图片查看程序 ------- Windows Phone 7手机开发、.Net培训、期待与您交流！ ------- 用winForm开发简易文本编辑器和图片查看程序：用到的控件： 1.textBox控件（多行属性设为true）：显示和编辑文本 2.Button控件：打开新建和保存三种操作 3.openFileDialog控件和saveFileDialog控件：显示“打开”和保存文件的对话框阅读详情

fengyin520

VB基础类 7,788 成员 197,583 内容

+ 关注 + 加入社区

切换为时间正序

云路 2006-04-06

打赏
举报

不会，也看看学习一下。

fengyin520 2006-04-06

打赏
举报

to rose_886886(沙冰菲霏)
你这个方法我也会,但他只能保存picture上画的图,要保存picture上的控件或其他东西就不能了

rose_886886 2006-04-06

打赏
举报

picture1.autoredraw=true

VB.SavePicture Picture1.Image, "d:\pic.jpg"

对不?..........................

ljydomybest 2006-04-06

打赏
举报

可以用Clipboard对象，可以用一种转换网上有，自己找下，转成文本，后用ＶＢ读写操作，配合保存对话框，保存，读取时在转换读取……

vansoft 2006-04-06

打赏
举报

這個啊，我寫過的，
上次給人做畢業設計時用的。

回家找代碼給你貼上。

vansoft 2006-04-06

打赏
举报

调用如下，
Private Sub Command1_Click()
'忽略错误继续执行下一句语句
On Error Resume Next
'获取图片框1里的信息以图片形式入在图片框4里
Set Picture4.Picture = CapturePictureBox(Picture1)
'显示保存对话框
CommonDialog1.ShowSave
'保存图片
SavePicture Picture4.Picture, CommonDialog1.FileName

'同上
Set Picture4.Picture = CapturePictureBox(Picture2)
CommonDialog1.ShowSave
SavePicture Picture4.Picture, CommonDialog1.FileName
'同上
Set Picture4.Picture = CapturePictureBox(Picture3)
CommonDialog1.ShowSave
SavePicture Picture4.Picture, CommonDialog1.FileName
End Sub

这是我工程里的代码，你学习一下。
再改为你的。

vansoft 2006-04-06

打赏
举报

模块内容：
'要求变量声明
Option Explicit
'声明数组下标
Option Base 0

'本模块用来拷屏创建图片

Public Type PALETTEENTRY
peRed As Byte
peGreen As Byte
peBlue As Byte
peFlags As Byte
End Type

Public Type LOGPALETTE
palVersion As Integer
palNumEntries As Integer
palPalEntry(255) As PALETTEENTRY
End Type

Public Type GUID
Data1 As Long
Data2 As Integer
Data3 As Integer
Data4(7) As Byte
End Type

Public Const RASTERCAPS As Long = 38
Public Const RC_PALETTE As Long = &H100
Public Const SIZEPALETTE As Long = 104

Public Type RECT
Left As Long
Top As Long
Right As Long
Bottom As Long
End Type

Public Declare Function CreateCompatibleDC Lib "GDI32" (ByVal hDC As Long) As Long
Public Declare Function CreateCompatibleBitmap Lib "GDI32" (ByVal hDC As Long, ByVal nWidth As Long, ByVal nHeight As Long) As Long
Public Declare Function GetDeviceCaps Lib "GDI32" (ByVal hDC As Long, ByVal iCapabilitiy As Long) As Long
Public Declare Function GetSystemPaletteEntries Lib "GDI32" (ByVal hDC As Long, ByVal wStartIndex As Long, ByVal wNumEntries As Long, lpPaletteEntries As PALETTEENTRY) As Long
Public Declare Function CreatePalette Lib "GDI32" (lpLogPalette As LOGPALETTE) As Long
Public Declare Function SelectObject Lib "GDI32" (ByVal hDC As Long, ByVal hObject As Long) As Long
Public Declare Function BitBlt Lib "GDI32" (ByVal hDCDest As Long, ByVal XDest As Long, ByVal YDest As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hDCSrc As Long, ByVal XSrc As Long, ByVal YSrc As Long, ByVal dwRop As Long) As Long
Public Declare Function DeleteDC Lib "GDI32" (ByVal hDC As Long) As Long
Public Declare Function GetForegroundWindow Lib "USER32" () As Long
Public Declare Function SelectPalette Lib "GDI32" (ByVal hDC As Long, ByVal hPalette As Long, ByVal bForceBackground As Long) As Long
Public Declare Function RealizePalette Lib "GDI32" (ByVal hDC As Long) As Long
Public Declare Function GetWindowDC Lib "USER32" (ByVal hWnd As Long) As Long
Public Declare Function GetDC Lib "USER32" (ByVal hWnd As Long) As Long
Public Declare Function GetWindowRect Lib "USER32" (ByVal hWnd As Long, lpRect As RECT) As Long
Public Declare Function ReleaseDC Lib "USER32" (ByVal hWnd As Long, ByVal hDC As Long) As Long
Public Declare Function GetDesktopWindow Lib "USER32" () As Long

Public Type PicBmp
Size As Long
Type As Long
hBmp As Long
hPal As Long
Reserved As Long
End Type

Public Declare Function OleCreatePictureIndirect Lib "olepro32.dll" (PicDesc As PicBmp, RefIID As GUID, ByVal fPictureOwnsHandle As Long, IPic As IPicture) As Long

'以图片框内容创建一幅图片
Public Function CapturePictureBox(PicBox As PictureBox) As Picture
Set CapturePictureBox = CaptureWindow(PicBox.hWnd, False, 0, 0, PicBox.ScaleX(PicBox.Width, vbTwips, vbPixels), PicBox.ScaleY(PicBox.Height, vbTwips, vbPixels))
End Function

Public Function CaptureWindow(ByVal hWndSrc As Long, ByVal Client As Boolean, ByVal LeftSrc As Long, ByVal TopSrc As Long, ByVal WidthSrc As Long, ByVal HeightSrc As Long) As Picture

Dim hDCMemory As Long
Dim hBmp As Long
Dim hBmpPrev As Long
Dim r As Long
Dim hDCSrc As Long
Dim hPal As Long
Dim hPalPrev As Long
Dim RasterCapsScrn As Long
Dim HasPaletteScrn As Long
Dim PaletteSizeScrn As Long
Dim LogPal As LOGPALETTE

If Client Then
hDCSrc = GetDC(hWndSrc)
Else
hDCSrc = GetWindowDC(hWndSrc)
End If

hDCMemory = CreateCompatibleDC(hDCSrc)
hBmp = CreateCompatibleBitmap(hDCSrc, WidthSrc, HeightSrc)
hBmpPrev = SelectObject(hDCMemory, hBmp)

RasterCapsScrn = GetDeviceCaps(hDCSrc, RASTERCAPS)
HasPaletteScrn = RasterCapsScrn And RC_PALETTE
PaletteSizeScrn = GetDeviceCaps(hDCSrc, SIZEPALETTE)

If HasPaletteScrn And (PaletteSizeScrn = 256) Then
LogPal.palVersion = &H300
LogPal.palNumEntries = 256
r = GetSystemPaletteEntries(hDCSrc, 0, 256, LogPal.palPalEntry(0))
hPal = CreatePalette(LogPal)
hPalPrev = SelectPalette(hDCMemory, hPal, 0)
r = RealizePalette(hDCMemory)
End If

r = BitBlt(hDCMemory, 0, 0, WidthSrc, HeightSrc, hDCSrc, LeftSrc, TopSrc, vbSrcCopy)

hBmp = SelectObject(hDCMemory, hBmpPrev)

If HasPaletteScrn And (PaletteSizeScrn = 256) Then
hPal = SelectPalette(hDCMemory, hPalPrev, 0)
End If

r = DeleteDC(hDCMemory)
r = ReleaseDC(hWndSrc, hDCSrc)

Set CaptureWindow = CreateBitmapPicture(hBmp, hPal)
End Function

'创建一幅BMP图片
Public Function CreateBitmapPicture(ByVal hBmp As Long, ByVal hPal As Long) As Picture
Dim r As Long

Dim Pic As PicBmp
Dim IPic As IPicture
Dim IID_IDispatch As GUID

With IID_IDispatch
.Data1 = &H20400
.Data4(0) = &HC0
.Data4(7) = &H46
End With

With Pic
.Size = Len(Pic)
.Type = vbPicTypeBitmap
.hBmp = hBmp
.hPal = hPal
End With

r = OleCreatePictureIndirect(Pic, IID_IDispatch, 1, IPic)

Set CreateBitmapPicture = IPic
End Function

cxianfa 2006-04-06

打赏
举报

有意思的东西.学习

guoguo1982 2006-04-06

打赏
举报

学习

AnnaBear 2006-04-06

打赏
举报

不会
学习...
^_^

xinliangyu 2006-04-06

打赏
举报

鄙人在去年的blog中相关的内容，你看看吧：
http://blog.csdn.net/xinliangyu/archive/2005/02/06/274900.aspx

dingzhihui 2006-04-06

打赏
举报

picture1.autoredraw=true

用picture 来代替image试试
VB.SavePicture Picture1.picture, "d:\pic.jpg"

of123 2006-04-06

打赏
举报

借助另一个 PictureBox：
Public Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

Picture1.SetFocus
Picture2.AutoRedraw = True
rv = SendMessage(Picture1.hwnd, WM_PAINT, Picture2.hDC, 0)
rv = SendMessage(Picture1.hwnd, WM_PRINT, Picture2.hDC, _
PRF_CHILDREN + PRF_CLIENT + PRF_OWNED)
Picture2.Picture = Picture2.Image
Picture2.AutoRedraw = False

SavePicture Picture2.Picture, "路径\文件名"

Herolegend 2006-04-05

打赏
举报

忘了,剪切板可以用Clipboard对象

Herolegend 2006-04-05

打赏
举报

参考:
http://www.pc-zone.com.cn/html/200603/239.html

Herolegend 2006-04-05

打赏
举报

用GetDC、StretchBlt等API,具体看MSDN

fengyin520 2006-04-05

打赏
举报

还有个问题,如何把picturebox上的图形复制到剪切板里,同上也需要把picturebox上的东西一起复制下来,如果困难的话只复制picturebox上本身画的东西也可以

如何保存picturebox上的内容为图片

相关推荐