ListView大图标显示时如何让各项不能拖拽

[Fxx]

我的目的:ListView以Icon显示,不能拖动,并且双击选中的项可以显示另一个窗体
遇到的问题
用下面的代码可以让Item不能拖动(不太好看,打家有没有更好的办法)
private sub listview1_MouseMove(Index As Integer,Button As Interger,Shift As Integer,x As Single,y As Single)
if Button=vbLeftButton then
if not ListView1.SelectedItem is nothing Then
ListView1.DragIcon=ListView1.SelectedItem.CreateDragImage
ListView1.Drag vbBeginDrag
End if
end if
end sub

不能拖拽后,点击其中的项目显示另一个窗体,发现窗体关闭后又可以拖动了

[rainstormmaster]

处理其父窗口的WM_NOTIFY消息，当发觉listview发出LVN_BEGINDRAG通知消息时，过滤掉这条消息即可，代码如下：
1个窗体，1个模块：
窗体：
1个listview（listview1),1个imagelist（ImageList1），并为ImageList1预先载入一些图标，代码如下：
Option Explicit


Private Sub Form_Load()
ListView1.View = lvwIcon
Set ListView1.Icons = ImageList1
Dim i As Long
For i = 1 To 100
ListView1.ListItems.Add , , "item" + CStr(i), 1
Next
InstallWindowProc Me.hWnd, ListView1.hWnd
End Sub


Private Sub Form_Unload(Cancel As Integer)
UninstallWindowProc
End Sub


模块：
Option Explicit

Private m_OldWindowProc As Long
Private m_ParentHwnd As Long
Private m_ChildHwnd As Long

Private Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hWnd As Long, ByVal msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long

Private Const GWL_WNDPROC = (-4)
Private Declare Sub MoveMemory Lib "kernel32" Alias "RtlMoveMemory" (pDest As Any, pSource As Any, ByVal dwLength As Long)


Private Type NMHDR
hwndFrom As Long
idfrom As Long
code As Long
End Type
Const WM_NCDESTROY = &H82
Const WM_NOTIFY = &H4E
Const LVN_FIRST = -100&
Const LVN_BEGINDRAG = (LVN_FIRST - 9)
Public Function NewWindowProc(ByVal hWnd As Long, ByVal msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Dim notify_header As NMHDR

If msg = WM_NCDESTROY Then
UninstallWindowProc
End If

If msg = WM_NOTIFY Then
MoveMemory notify_header, ByVal lParam, Len(notify_header)
If (notify_header.code = LVN_BEGINDRAG) And (notify_header.hwndFrom = m_ChildHwnd) Then
NewWindowProc = 1
Exit Function
End If
End If
NewWindowProc = CallWindowProc(m_OldWindowProc, hWnd, msg, wParam, lParam)
End Function

' Install the new WindowProc.
Public Sub InstallWindowProc(ByVal parent_hwnd As Long, ByVal child_hwnd As Long)
m_ParentHwnd = parent_hwnd
m_ChildHwnd = child_hwnd

m_OldWindowProc = SetWindowLong(m_ParentHwnd, GWL_WNDPROC, AddressOf NewWindowProc)
End Sub

' Restore the original WindowProc.
Public Sub UninstallWindowProc()
SetWindowLong m_ParentHwnd, GWL_WNDPROC, m_OldWindowProc
m_ParentHwnd = 0
m_ChildHwnd = 0
End Sub

说明：子类处理比较危险，建议测试时先保存代码，然后测试（结束程序时务必点击窗口的关闭按钮），最好编译后再测试

[qq76614842_老黄]

真是强人啊