请问如何提取ppt文件中的图片

[snz]

用什么方法能提取ppt文件中的图片，多谢各位帮忙!

[xiongyuhui]

用Shape对象调用Export（图片名，图片类型）

VBA：
' Work's only in PowerPoint 2000 and later
Sub ExtractImagesFromPres()
On Error GoTo ErrorExtract
Dim oSldSource As Slide
Dim oDsnSource As Design
Dim oMstSource As Master
Dim oShpSource As Shape
Dim Ctr As Integer
Dim sPath As String

sPath = "c:\"
Ctr = 0

For Each oSldSource In ActivePresentation.Slides
For Each oShpSource In oSldSource.Shapes
If oShpSource.Type = msoPicture Then
' Hidden Export method
Call oShpSource.Export(sPath & "Img" & _
Format(Ctr, "0000") & ".PNG", ppShapeFormatPNG)
Ctr = Ctr + 1
End If
Next oShpSource
Next oSldSource

For Each oDsnSource In ActivePresentation.Designs
For Each oShpSource In oDsnSource.SlideMaster.Shapes
If oShpSource.Type = msoPicture Then
' Hidden Export method
Call oShpSource.Export(sPath & "Img" & _
Format(Ctr, "0000") & ".JPG", ppShapeFormatJPG)
Ctr = Ctr + 1
End If
Next oShpSource

For Each oShpSource In oDsnSource.SlideMaster.Background
If oShpSource.Type = msoPicture Then
' Hidden Export method
Call oShpSource.Export(sPath & "Img" & _
Format(Ctr, "0000") & ".JPG", ppShapeFormatJPG)
Ctr = Ctr + 1
End If
Next oShpSource
Next oDsnSource


If Ctr = 0 Then
MsgBox "There were no images found in this presentation", _
vbInformation, "Image extraction failed."
End If
Exit Sub
ErrorExtract:
If Err.Number <> 0 Then
MsgBox Err.Description, vbCritical, "Error #" & Err.Number
End If
End Sub

[snz]

多谢，已经搞定。