帮忙写一个xml格式转换的xslt

[coldljy]

原始格式：
<users>
<user>
<name>aaa</name>
<groupid>1</groupid>
</user>
<user>
<name>aaa</name>
<groupid>2</groupid>
</user>
...
</users>

要求转换成：
<users>
<user>
<name>aaa</name>
<groupids>
<groupid>1</groupid>
<groupid>2</groupid>
</groupids>
</user>
</users>

含义：同一个用户属于多个组，把组标识整到一起，并为用户的子元素。

[licry01]

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" >

<xsl:output method="xml" indent="yes"/>
<xsl:key name="name-search" match="user" use="name"/>

<xsl:template match="/users">
<users>
<xsl:for-each select="user[ generate-id() = generate-id( key('name-search',name )[1])]">
<xsl:sort select="./name" />
<user>
<name>
<xsl:value-of select="./name"/>
</name>
<groupids>
<xsl:call-template name="Groups">
<xsl:with-param name="uname" select="./name" />
</xsl:call-template>
</groupids>
</user>
</xsl:for-each>
</users>
</xsl:template>

<xsl:template name="Groups">
<xsl:param name="uname" />

<xsl:for-each select="//user[ ./name = $uname ]">
<xsl:sort select="./groupid" />
<groupid>
<xsl:value-of select="./groupid"/>
</groupid>
</xsl:for-each>
</xsl:template>

</xsl:stylesheet>

[coldljy]

非常感谢licry01(龙) ，测试了一下，完全通过。不过我的应用还有点问题，就是原xml里user其实还有些子元素，类似这样：
<user>
<name>aaa</name>
<age>20</age>
...
<groupid>1</groupid>
</user>
<user>
<name>aaa</name>
<age>20</age>
...
<groupid>2</groupid>
</user>

两个完全一样，要求也能转换过去。

[licry01]

这样的话还真有点难弄了...................

[Qiaorui]

如果除了groupid的值有变化外，user下各元素一一对应，那只需在3楼代码的基础上增加相应的元素即可。
如，原代码为：
<name><xsl:value-of select="./name"/></name>
其下增加age等：
<age><xsl:value-of select="./age"/></age>
当然了，如果两个user之间，有的有<sex>，有的没有，做个简单的判断即可。

[Arxi]

帮你up~~

[coldljy]

多谢多谢！

[coldljy]

另外开个帖子，请两位光临：
http://community.csdn.net/Expert/topic/4838/4838237.xml?temp=.7225458