在储存过程中怎样执行这个select 语句

[kw816]

CREATE procedure us_example
@Unit varchar(50) --单位名称
as
set nocount on
declare
@sqlstr2 nvarchar(4000) --查询字符串

if (@Unit)="-1"

set @Unit="1=1"
else
set @Unit="ManaUnit="+@Unit

set @sqlstr2="select sum(Dimension) from Field where "+@Unit
--select sum(dimension) from field where Manaunit=@Unit
--怎样执行@sqlstr2变量，使得结果同上一语句一样
set nocount off
GO

[paoluo]

EXEC(@sqlstr2)

[OracleRoob]

动态sql语句基本语法
1 :普通SQL语句可以用Exec执行

eg: Select * from tableName
Exec('select * from tableName')
Exec sp_executesql N'select * from tableName' -- 请注意字符串前一定要加N

2:字段名，表名，数据库名之类作为变量时，必须用动态SQL

eg:
declare @fname varchar(20)
set @fname = 'FiledName'
Select @fname from tableName -- 错误,不会提示错误，但结果为固定值FiledName,并非所要。
Exec('select ' + @fname + ' from tableName') -- 请注意 加号前后的 单引号的边上加空格

当然将字符串改成变量的形式也可
declare @fname varchar(20)
set @fname = 'FiledName' --设置字段名

declare @s varchar(1000)
set @s = 'select ' + @fname + ' from tableName'
Exec(@s) -- 成功
exec sp_executesql @s -- 此句会报错



declare @s Nvarchar(1000) -- 注意此处改为nvarchar(1000)
set @s = 'select ' + @fname + ' from tableName'
Exec(@s) -- 成功
exec sp_executesql @s -- 此句正确

3. 输出参数
declare @num int,
@sqls nvarchar(4000)
set @sqls='select count(*) from tableName'
exec(@sqls)
--如何将exec执行结果放入变量中？

declare @num int,
@sqls nvarchar(4000)
set @sqls='select @a=count(*) from tableName '
exec sp_executesql @sqls,N'@a int output',@num output
select @num

[OracleRoob]

注意，用Exec()执行SQL语句时，一定要有()。

[kw816]

原来还要这个（）
谢楼上

[wfliu]

收藏