如何用存储过程实现这样的查询分页

[liangjianshi]

前台有若干个条件，他们是可选可不选的，
怎么写存储过程，查询后分页显示啊。

[liangjianshi]

是从多个表中联合查询的。

[viptiger]

select top 10 * from (
select * from tabela
inner join tableb
on x = y

) as XXX
where XXX.PKID > @LastPage

[viptiger]

select top 10 * from tabela
inner join tableb
on x = y
where PKID >= @LastPage

[liangjianshi]

CREATE procedure spoSplitPages
@SqlQuery nvarchar(4000), --查询字符串
@OrderFieldName varchar(30), --按该列为关键字来进行排序分页
@CurrentPage int,--第N页 （如果是 0 则读取 最后 一页的记录 ）
@PageSize int,--每页行数
@OrderType int --排序, 0：顺序, 1： 其它数字： 不进行排序 （只有此处的数字不为 0 为 1 的时候，外程序传入的 OrderFieldName 才可以为空！）

as

DECLARE @sql nvarchar(4000), @tPageCount int

IF @OrderType=0
SET @sql= @SqlQuery + ' ORDER BY '+@OrderFieldName

IF @OrderType=1
SET @sql =@SqlQuery + ' ORDER BY '+@OrderFieldName + ' DESC '
else
SET @sql =@SqlQuery
BEGIN
set nocount on
declare @P1 int,--P1是游标的id
@rowcount int
--print @sql
exec sp_cursoropen @P1 output,@sql,@scrollopt=1,@ccopt=1,@rowcount=@rowcount output
SET @tPageCount = ceiling(1.0*@rowcount/@PageSize)
if @CurrentPage = 0
set @CurrentPage = @tPageCount-- @PageIndex = 0 表示在调用时，是首次查询，先读取 最后 一页的记录
set @CurrentPage=(@CurrentPage-1)*@PageSize+1
exec sp_cursorfetch @P1,16,@CurrentPage,@PageSize
exec sp_cursorclose @P1

select @tPageCount as PagesCount ,@rowcount as RowsCount,@CurrentPage as CurrentPage
set nocount off
END
GO
从网上找了这样一个分页的存储过程，可是不知道在程序中怎么用啊？
怎么没见到有"首页" "后页" 类似这样的代码啊？
能写个调用这个存储过程的程序吗？

[Netflyhorse]

關注

[Netflyhorse]

也來轉貼一段
CREATE PROCEDURE sp_page
@tb varchar(50), --表名
@col varchar(50), --按该列来进行分页
@coltype int, --@col列的类型,0-数字类型,1-字符类型,2-日期时间类型
@orderby bit, --排序,0-顺序,1-倒序
@collist varchar(800),--要查询出的字段列表,*表示全部字段
@pagesize int, --每页记录数
@page int, --指定页
@condition varchar(800),--查询条件
@pages int OUTPUT --总页数
AS
/*
功能描述：对指定表中满足条件的记录按指定列进行分页查询，分页可以顺序、倒序
查询可以指定页大小、指定查询任意页、指定输出字段列表，返回总页数
作 者：pbsql
版 本：1.10
最后修改：2004-11-29
*/
DECLARE @sql nvarchar(4000),@where1 varchar(800),@where2 varchar(800)
IF @condition is null or rtrim(@condition)=''
BEGIN--没有查询条件
SET @where1=' WHERE '
SET @where2=' '
END
ELSE
BEGIN--有查询条件
SET @where1=' WHERE ('+@condition+') AND '--本来有条件再加上此条件
SET @where2=' WHERE ('+@condition+') '--原本没有条件而加上此条件
END
SET @sql='SELECT @pages=CEILING((COUNT(*)+0.0)/'+CAST(@pagesize AS varchar)+
') FROM '+@tb+@where2
EXEC sp_executesql @sql,N'@pages int OUTPUT',@pages OUTPUT--计算总页数
IF @orderby=0
SET @sql='SELECT TOP '+CAST(@pagesize AS varchar)+' '+@collist+
' FROM '+@tb+@where1+@col+'>(SELECT MAX('+@col+') '+
' FROM (SELECT TOP '+CAST(@pagesize*(@page-1) AS varchar)+' '+
@col+' FROM '+@tb+@where2+'ORDER BY '+@col+') t) ORDER BY '+@col
ELSE
SET @sql='SELECT TOP '+CAST(@pagesize AS varchar)+' '+@collist+
' FROM '+@tb+@where1+@col+'<(SELECT MIN('+@col+') '+
' FROM (SELECT TOP '+CAST(@pagesize*(@page-1) AS varchar)+' '+
@col+' FROM '+@tb+@where2+'ORDER BY '+@col+' DESC) t) ORDER BY '+
@col+' DESC'
IF @page=1--第一页
SET @sql='SELECT TOP '+CAST(@pagesize AS varchar)+' '+@collist+' FROM '+@tb+
@where2+'ORDER BY '+@col+CASE @orderby WHEN 0 THEN '' ELSE ' DESC' END
EXEC(@sql)
GO

本存储过程高效，曾用500万条数据测试（已建索引），只返回分页只需3秒，影响效率的地方是计算总页数，若不需要可以注释掉

--测试示例
declare @pages int
select identity(int,1,1) id,getdate() dt,xx=cast('' as varchar(10)) into #t
from sysobjects
update #t set dt=dateadd(day,id-200,dt),
xx='xxxx'+right('000000'+cast(id as varchar(10)),6)

exec sp_page '#t','id',0,0,'*',10,2,'',@pages output--按id顺序取第二页
exec sp_page '#t','id',0,1,'*',10,2,'',@pages output--按id倒序取第二页
exec sp_page '#t','xx',1,0,'*',10,3,'',@pages output--按xx顺序取第三页
exec sp_page '#t','xx',1,1,'*',10,3,'',@pages output--按xx倒序取第三页
exec sp_page '#t','dt',2,0,'*',10,2,'',@pages output--按dt顺序取第二页
exec sp_page '#t','dt',2,1,'*',10,2,'',@pages output--按dt倒序取第二页

select 总页数=@pages

drop table #t



Trackback: http://tb.blog.csdn.net/TrackBack.aspx?PostId=199657

[soft_newcoder]

mark