自己动手写操作系统中的汇编代码看不懂啊,有高手帮忙解释吗?

[OfThOfTh]

; ==========================================
; pmtest1.asm
; 编译方法：nasm pmtest1.asm -o pmtest1.com
; ==========================================

%include "pm.inc" ; 常量, 宏, 以及一些说明

org 0100h
jmp LABEL_BEGIN

[SECTION .gdt]
; GDT
; 段基址, 段界限 , 属性
LABEL_GDT: Descriptor 0, 0, 0 ; 空描述符
LABEL_DESC_CODE32: Descriptor 0, SegCode32Len - 1, DA_C + DA_32 ; 非一致代码段, 32
LABEL_DESC_VIDEO: Descriptor 0B8000h, 0ffffh, DA_DRW ; 显存首地址
; GDT 结束

GdtLen equ $ - LABEL_GDT ; GDT长度
GdtPtr dw GdtLen - 1 ; GDT界限
dd 0 ; GDT基地址

; GDT 选择子
SelectorCode32 equ LABEL_DESC_CODE32 - LABEL_GDT
SelectorVideo equ LABEL_DESC_VIDEO - LABEL_GDT
; END of [SECTION .gdt]

[SECTION .s16]
[BITS 16]
LABEL_BEGIN:
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
mov sp, 0100h

; 初始化 32 位代码段描述符
xor eax, eax
mov ax, cs
shl eax, 4
add eax, LABEL_SEG_CODE32
mov word [LABEL_DESC_CODE32 + 2], ax
shr eax, 16
mov byte [LABEL_DESC_CODE32 + 4], al
mov byte [LABEL_DESC_CODE32 + 7], ah

; 为加载 GDTR 作准备
xor eax, eax
mov ax, ds
shl eax, 4
add eax, LABEL_GDT ; eax <- gdt 基地址
mov dword [GdtPtr + 2], eax ; [GdtPtr + 2] <- gdt 基地址

; 加载 GDTR
lgdt [GdtPtr]

; 关中断
cli

; 打开地址线A20
in al, 92h
or al, 00000010b
out 92h, al

; 准备切换到保护模式
mov eax, cr0
or eax, 1
mov cr0, eax

; 真正进入保护模式
jmp dword SelectorCode32:0 ; 执行这一句会把 SelectorCode32 装入 cs, 并跳转到 Code32Selector:0 处
; END of [SECTION .s16]


[SECTION .s32]; 32 位代码段. 由实模式跳入.
[BITS 32]

LABEL_SEG_CODE32:
mov ax, SelectorVideo
mov gs, ax ; 视频段选择子(目的)

mov edi, (80 * 10 + 0) * 2 ; 屏幕第 10 行, 第 0 列。
mov ah, 0Ch ; 0000: 黑底 1100: 红字
mov al, 'P'
mov [gs:edi], ax

; 到此停止
jmp $

SegCode32Len equ $ - LABEL_SEG_CODE32
; END of [SECTION .s32]

[ciahi]

一段TSR程序

[大熊猫侯佩]

什么地方不懂？先初始化gdt,然后通过cr0打开进入保护模式之门，然后
写视频缓存。没什么不清楚的啊？

[OfThOfTh]

mydo老大,
1, LABEL_BEGIN:
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
mov sp, 0100h
为什么要将cs的值赋给ds,es,ss？ 0100h（256）赋给sp是为什么？

2， xor eax, eax
mov ax, cs
shl eax, 4
add eax, LABEL_SEG_CODE32
mov word [LABEL_DESC_CODE32 + 2], ax
shr eax, 16
mov byte [LABEL_DESC_CODE32 + 4], al
mov byte [LABEL_DESC_CODE32 + 7], ah
为什么要将eax逻辑左移4位啊？

3，; GDT 选择子
SelectorCode32 equ LABEL_DESC_CODE32 - LABEL_GDT
SelectorVideo equ LABEL_DESC_VIDEO - LABEL_GDT
为什么要将LABEL_DESC_VIDEO - LABEL_GDT的值赋给SelectorVideo？而LABEL_DESC_VIDEO和LABEL_GDT都是描述符，他们相减以后是什么东东？

[大熊猫侯佩]

1, LABEL_BEGIN:
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
mov sp, 0100h
为什么要将cs的值赋给ds,es,ss？ 0100h（256）赋给sp是为什么？

Ａ：
　　这时还是在实模式下，是为了各个段共用一个段基址。赋值给ｓｐ是初始化栈指针，
　　要知道栈是向下生长的。


2， xor eax, eax
mov ax, cs
shl eax, 4
add eax, LABEL_SEG_CODE32
mov word [LABEL_DESC_CODE32 + 2], ax
shr eax, 16
mov byte [LABEL_DESC_CODE32 + 4], al
mov byte [LABEL_DESC_CODE32 + 7], ah
为什么要将eax逻辑左移4位啊？

Ａ：
　　这时要根据实模式下的ｃｓ值初始化保护模式下的　DESC_CODE32
　　描述符中的段基址，他被初始化为LABEL_SEG_CODE32的全地址，
　　因为你没开分页，所以线性就是物理地址。


3，; GDT 选择子
SelectorCode32 equ LABEL_DESC_CODE32 - LABEL_GDT
SelectorVideo equ LABEL_DESC_VIDEO - LABEL_GDT
为什么要将LABEL_DESC_VIDEO - LABEL_GDT的值赋给SelectorVideo？而LABEL_DESC_VIDEO和LABEL_GDT都是描述符，他们相减以后是什么东东？

Ａ：
　　很清楚啊！相减后构成选择子的索引部分后面都为０，意思是指向　
　　ｇｄｔ（ｒｐｌ＝０）中的描述符。看看选择子结构便知。

[OfThOfTh]

多谢mydo

[OfThOfTh]

多谢,帮顶也有分相赠