数据库插入图片问题！

[macula55]

有Access数据库a.mdb和图片ttt.jpg

=====================================================
字段 类型 备注
=====================================================
ID 自动编号
img OLE对象 存储图片
=====================================================

问题：
如何使用sql（Insert）语句将ttt.jpg插入新的记录？

[macula55]

谢谢2楼的指点！

[饮水需思源]

使用流对象保存和显示图片
打开vb6,新建工程。

添加两个按钮,一个image控件
注意:Access中的photo字段类型为OLE对象.
SqlServer中的photo字段类型为Image

'** 引用 Microsoft ActiveX Data Objects 2.5 Library 及以上版本
‘2.5版本以下不支持Stream对象
Dim iConcstr As String
Dim iConc As ADODB.Connection


'保存文件到数据库中
Sub s_SaveFile()
Dim iStm As ADODB.Stream
Dim iRe As ADODB.Recordset
Dim iConcstr As String

'读取文件到内容
Set iStm = New ADODB.Stream
With iStm
.Type = adTypeBinary '二进制模式
.Open
.LoadFromFile App.Path + "\test.jpg"
End With


'打开保存文件的表
Set iRe = New ADODB.Recordset
With iRe
.Open "select * from img", iConc, 1, 3
.AddNew '新增一条记录
.Fields("photo") = iStm.Read
.Update
End With


'完成后关闭对象
iRe.Close
iStm.Close
End Sub


Sub s_ReadFile()
Dim iStm As ADODB.Stream
Dim iRe As ADODB.Recordset
'打开表
Set iRe = New ADODB.Recordset
‘得到最新添加的纪录
iRe.Open "select top 1 * from img order by id desc", iConc, adOpenKeyset, adLockReadOnly
'保存到文件
Set iStm = New ADODB.Stream
With iStm
.Mode = adModeReadWrite
.Type = adTypeBinary
.Open
.Write iRe("photo")
‘这里注意了,如果当前目录下存在test1.jpg,会报一个文件写入失败的错误.
.SaveToFile App.Path & "\test1.jpg"
End With


Image1.Picture = LoadPicture(App.Path & "\test1.jpg")
'关闭对象
iRe.Close
iStm.Close
End Sub


Private Sub Command1_Click()
Call s_ReadFile
End Sub


Private Sub Command2_Click()
Call s_SaveFile
End Sub


Private Sub Form_Load()
'数据库连接字符串
iConcstr = "Provider=Microsoft.Jet.OLEDB.4.0;Persist Security Info=False" & _
";Data Source=F:\csdn_vb\database\保存图片\access图片\img.mdb"

‘下面的语句是连接sqlserver数据库的.
‘iConcstr = "Provider=SQLOLEDB.1;Persist Security Info=True;" & _
‘ "User ID=sa;Password=;Initial Catalog=test;Data Source=yang"


Set iConc = New ADODB.Connection
iConc.Open iConcstr
End Sub


Private Sub Form_Unload(Cancel As Integer)
iConc.Close
Set iConc = Nothing
End Sub

[changechange]

如何将文件保存在OLE字段里(OLE写入/读出)？


作者：未详 摘自：未详 编辑：cg1 更新日期：2002-11-21 浏览人次：3884

专题地址：
http://access911.net/?kbid;75FAB01E



简述：


阅读前需掌握：


难度等级：
等级未评定




问题：




如何将文件保存在OLE字段里(OLE写入/读出)？





回答：



注意：以下代码是将文件以二进制存储在OLE字段中，与手动(右键单击OLE字段，选"插入对象")将文件嵌入到OLE字段中是不同的。以二进制方法存储文件无法直接在字段中编辑，必须读出存为文件才能编辑，编辑完成后再写入到OLE字段中。

如何将文件保存在OLE字段里(OLE写入/读出)？
OLE文件读入和读出

支持的类型使所有文件，当然，你在读入数据的时候，最好做一个字段保存文件的类型，在保存文件的时候，就可以根据类型选择要保存的类型了。


Option Compare Database
Option Explicit

Public Function GetFromFile(strTable As String, strField As String, strFilter As String, objFileName As String) As Boolean

'============================================================
'　过程函数名： CommModule.GetFromFile　类型：Function
'　参数：
'　　　　 strTable (String)　　：准备保存图形数据的表名称
'　　　　 strField (String)　　：准备保存图形数据的字段名称
'　　　　 strFilter (String)　 ：打开表的过滤字符串，用于定位并确保被打开的表的数据的唯一性
'　　　　 objFileName (String) ：准备输入到表里边的图象文件名称
'　返回：如果保存成功，返回True，如果失败，返回False
'-------------------------------------------------------------
'　说明：把图象文件的数据保存到表里边
'-------------------------------------------------------------
'　修订历史：
'=============================================================
Dim recset　　 As ADODB.Recordset, FileData() As Byte, FileNo As Long, FileSize As Long, strSQL As String

　　strSQL = "Select " & strField & " From " & strTable & " Where " & strFilter & ";"
　　Set recset = New ADODB.Recordset
　　recset.Open strSQL, CurrentProject.Connection, adOpenDynamic, adLockOptimistic
　　GetFromFile = True
　　If recset(strField).Type <> DB_OLE Or Not IsFileName(objFileName) Then
　　　　GetFromFile = False　　　　 '如果字段不是OLE字段，或者文件不存在，返回错误
　　　　GoTo EndGetFromFile
　　End If
　　If recset.EOF Then　　　　　　　'如果记录不存在，返回错误
　　　　GetFromFile = False
　　　　GoTo EndGetFromFile
　　End If
　　FileSize = GetFileSize(objFileName) '如果被打开的文件大小为零，返回错误
　　If FileSize <= 0 Then
　　　　GetFromFile = False
　　　　GoTo EndGetFromFile
　　End If
　　ReDim FileData(FileSize)　　　　　　'重新初始化数组
　　FileNo = FreeFile　　　　　　　　　 '获取一个空闲的文件号
　　Open objFileName For Binary As #FileNo　'打开文件
　　Get #FileNo, , FileData()　　　　　 '读取文件内容到数组
　　Close #FileNo　　　　　　　　　　　 '关闭文件
　　recset(strField).value = FileData() '保存数据
　　recset.Update　　　　　　　　　　　 '更新数据
　　Erase FileData　　　　　　　　　　　'释放内存
EndGetFromfile:
　　recset.Close　　　　　　　　　　　　'关闭RecordSet
　　Set recset = Nothing　　　　　　　　'释放内存
End Function

Public Function SaveToFile(strTable As String, strField As String, strFilter As String, strFileName As String) As Boolean
'============================================================
'　过程函数名： CommModule.SaveToFile 类型：Function
'　参数：
'　　　　 strTable (String)　　：保存图形数据的表名称
'　　　　 strField (String)　　：保存图形数据的字段名称
'　　　　 strFilter (String)　 ：打开表的过滤字符串，用于定位并确保被打开的表的纪录的唯一性
'　　　　 strFileName (String) ：准备保存的图象的文件名称
'　返回：如果保存成功，返回True，如果失败，返回False
'-------------------------------------------------------------
'　说明：把由GetFromFile函数保存到表中OLE字段的数据还原到文件
'-------------------------------------------------------------
'　修订历史：
'=============================================================
Dim recset　　 As ADODB.Recordset, FileData() As Byte, FileNo As Long, FileSize As Long, strSQL As String

　　strSQL = "Select " & strField & " From " & strTable & " Where " & strFilter & ";"
　　Set recset = New ADODB.Recordset
　　recset.Open strSQL, CurrentProject.Connection, adOpenDynamic, adLockOptimistic
　　SaveToFile = True
　　If recset(strField).Type <> DB_OLE Then
　　　　SaveToFile = False　　　　 '如果字段不是OLE字段，返回错误
　　　　GoTo EndSaveToFile
　　End If
　　If recset.EOF Then　　　　　　　'如果记录不存在，返回错误
　　　　SaveToFile = False
　　　　GoTo EndSaveToFile
　　End If
　　FileNo = FreeFile
　　Open strFileName For Binary As #FileNo
　　ReDim FileData(recset(strField).ActualSize) '重新初始化数组
　　FileData() = recset(strField).GetChunk(recset(strField).ActualSize) '把OLE字段的内容保存到数组
　　Put #FileNo, , FileData()　 '把数组内容保存到文件
　　Close #FileNo
　　Erase FileData
EndSaveTofile:
　　recset.Close
　　Set recset = Nothing
End Function
'上述代码来源于AccXP网站

[wwwwb]

不能，用ADO才行
参考
http://www.access911.net/fixhtm/75FAB01E.htm?tt=如何将文件保存在OLE字段里(OLE写入/读出)？《表》

[OracleRoob]

不能直接用SQL语句追加图片文件。

必须通过代码方式实现。