如何取得窗体的四个角的坐标？

[chenyuandxm]

如题。
或者得到包括标题栏在内的窗体的height？应该如何实现，请各位指点，谢谢！

[cnszyuxin]

LZ要的是什么样的窗体的Size
如果是_Screen的话,可以用_Vfp.Height来取得它的Height.
如果是Top Level Form的话,用Height取得的高度只是Client的高度.
加上你的Toolbar的高度和菜单的高度就是整个窗体的高度了.
当然,还可以使用Window Api 的GetWindowRect来取得四个角的坐标.
这大约是最准确的了
--------------------------------------------------------------
Declare Integer GetWindowRect In WinApi32 Integer,String @
Local lpRect As String
lpRect = REPLI (Chr(0), 16)
= GetWindowRect (YourForm.Hwnd, @lpRect)

lnWinLeft = buf2dword(SUBSTR(lpRect, 1,4))
lnWinTop = buf2dword(SUBSTR(lpRect, 5,4))
lnWinRight = buf2dword(SUBSTR(lpRect, 9,4))
lnWinBottom = buf2dword(SUBSTR(lpRect, 13,4))
lnWinWidth = lnWinRight - lnWinLeft + 1
lnWinHeight = lnWinBottom - lnWinTop + 1

? "*** My Form Rectangle list: "
? " left: " + STR(lnWinLeft, 6)
? " top: " + STR(lnWinTop, 6)
? " right: " + STR(lnWinRight, 6)
? " bottom: " + STR(lnWinBottom, 6)
? " width: " + STR(lnWinWidth, 6)
? " height: " + STR(lnWinHeight, 6)
--------------------------------------------------------------
FUNCTION buf2dword(cBuffer)
RETURN Asc(SUBSTR(cBuffer, 1,1)) + ;
BitLShift(Asc(SUBSTR(cBuffer, 2,1)), 8) +;
BitLShift(Asc(SUBSTR(cBuffer, 3,1)), 16) +;
BitLShift(Asc(SUBSTR(cBuffer, 4,1)), 24)
--------------------------------------------------------------