6,129
社区成员
发帖
与我相关
我的任务
分享MSSQL多列取最大或者最小值 --整理帖
/*
lvl1 lvl2 lvl3 lvl4 lvl
4 3 4 1
3 2 2 1
2 2 3 4
4 4 3 4
3 1 2 2
怎么写代码 去比较lvl1、lvl2、lvl3、lvl4 对应每行的值，取其中最小的，将其值添加到lvl列里
运行结果应该是
lvl
1
1
2
3
1
*/
--方法(一) 函數法
-->Title:Generating test data
-->Author:wufeng4552
-->Date :2009-10-16 09:58:16
if not object_id('Tempdb..#t') is null
drop table #t
Go
Create table #t([lvl1] int,[lvl2] int,[lvl3] int,[lvl4] int,[lvl] int)
Insert #t
select 4,3,4,1,null union all
select 3,2,2,1,null union all
select 2,2,3,4,null union all
select 4,4,3,4,null union all
select 3,1,2,2,null
Go
if object_id('UF_minget')is not null drop function UF_minget
go
create function UF_minget
(@col1 int,@col2 int,@col3 int,@col4 int)
returns int
as
begin
declare @t table(col int)
insert @t select @col1 union all
select @col2 union all
select @col3 union all
select @col4
return(select min(col)from @t)
end
go
update t set [lvl]=dbo.UF_minget([lvl1],[lvl2],[lvl3],[lvl4])
from #t t
select * from #t
/*
lvl1 lvl2 lvl3 lvl4 lvl
----------- ----------- ----------- ----------- -----------
4 3 4 1 1
3 2 2 1 1
2 2 3 4 2
4 4 3 4 3
3 1 2 2 1
(5 個資料列受到影響)
*/
--方法二 MSSQL2005 XML PATH
-------------------------------------
-- Author : liangCK 梁爱兰
-- Comment: 小梁 爱 兰儿
-- Date : 2009-10-16 09:57:38
-------------------------------------
--> 生成测试数据: @T
DECLARE @T TABLE (lvl1 int,lvl2 int,lvl3 int,lvl4 int,lvl int)
INSERT INTO @T
SELECT 4,3,4,1,null UNION ALL
SELECT 3,2,2,1,null UNION ALL
SELECT 2,2,3,4,null UNION ALL
SELECT 4,4,3,4,null UNION ALL
SELECT 3,1,2,2,null
--SQL查询如下:
UPDATE A SET
lvl = B.x.value('min(//row/*)','int')
FROM @T AS A
CROSS APPLY (SELECT x = (SELECT A.* FOR XML PATH('row'),TYPE)) AS B;
SELECT * FROM @T;
/*
lvl1 lvl2 lvl3 lvl4 lvl
----------- ----------- ----------- ----------- -----------
4 3 4 1 1
3 2 2 1 1
2 2 3 4 2
4 4 3 4 3
3 1 2 2 1
(5 行受影响)
*/
--方法(三) 作者 (四方城)
if object_id('[tb]') is not null drop table [tb]
go
create table [tb]([lvl1] int,[lvl2] int,[lvl3] int,[lvl4] int,[lvl] int)
insert [tb]
select 4,3,4,1,null union all
select 3,2,2,1,null union all
select 2,2,3,4,null union all
select 4,4,3,4,null union all
select 3,1,2,2,null
go
create function getmin(@a varchar(8000))
returns int
as
begin declare @ table (id int identity,a char(1))
declare @t int
insert @ select top 8000 null from sysobjects a,sysobjects b
select @t=min(cast(substring(','+@a,id+1,charindex(',',','+@a+',',id+1)-id-1) as int))
from @ where substring(','+@a,id,8000) like ',_%'
return @t
end
go
-->查询
select
lvl1,
lvl2,
lvl3,
lvl4,
lvl=dbo.getmin(ltrim(lvl1)+','+ltrim(lvl2)+','+ltrim(lvl3)+','+ltrim(lvl4))
from tb
/**
lvl1 lvl2 lvl3 lvl4 lvl
----------- ----------- ----------- ----------- -----------
4 3 4 1 1
3 2 2 1 1
2 2 3 4 2
4 4 3 4 3
3 1 2 2 1
(5 行受影响)
**/
--方法(四)
-->Title:Generating test data
-->Author:wufeng4552
-->Date :2009-10-16 09:58:16
if not object_id('Tempdb..#t') is null
drop table #t
Go
Create table #t([lvl1] int,[lvl2] int,[lvl3] int,[lvl4] int,[lvl] int)
Insert #t
select 4,3,4,1,null union all
select 3,2,2,1,null union all
select 2,2,3,4,null union all
select 4,4,3,4,null union all
select 3,1,2,2,null
Go
if object_id('UF_minget')is not null drop function UF_minget
go
create function UF_minget
(@s varchar(200))
returns int
as
begin
return(
select col=min(substring(@s,number,charindex(',',@s+',',number)-number))
from master..spt_values
where type='p' and number<=len(@s+'a') and charindex(',',','+@s,number)=number)
end
go
select
[lvl1],
[lvl2],
[lvl3],
[lvl4],
[lvl]=dbo.UF_minget(ltrim([lvl1])+','+ltrim([lvl2])+','+ltrim([lvl3])+','+ltrim([lvl4]))
from #T
/*
lvl1 lvl2 lvl3 lvl4 lvl
----------- ----------- ----------- ----------- -----------
4 3 4 1 1
3 2 2 1 1
2 2 3 4 2
4 4 3 4 3
3 1 2 2 1
*/
--方法(五)
-->Title:Generating test data
-->Author:wufeng4552
-->Date :2009-10-16 09:58:16
if not object_id('Tempdb..#t') is null
drop table #t
Go
Create table #t([lvl1] int,[lvl2] int,[lvl3] int,[lvl4] int,[lvl] int)
Insert #t
select 4,3,4,1,null union all
select 3,2,2,1,null union all
select 2,2,3,4,null union all
select 4,4,3,4,null union all
select 3,1,2,2,null
Go
select [lvl1],
[lvl2],
[lvl3],
[lvl4],
[lvl]=(select min([lvl1])
from (select [lvl1]
union all select [lvl2]
union all select [lvl3]
union all select [lvl4])T)
from #t
/*
lvl1 lvl2 lvl3 lvl4 lvl
----------- ----------- ----------- ----------- -----------
4 3 4 1 1
3 2 2 1 1
2 2 3 4 2
4 4 3 4 3
3 1 2 2 1
(5 個資料列受到影響)
*/更多方法,請跟帖討論
...全文
请发表友善的回复…
发表回复
thisiscandy 2011-06-02
- 打赏
- 举报
多年以后。，还是好贴一枚。顶一记。
blueberrySunny 2010-07-14
- 打赏
- 举报
学习了^^..好贴
老黎 2010-04-24
- 打赏
- 举报
函数的方法就不写了，xml的太高深了，不懂学习帮顶
老黎 2010-04-24
- 打赏
- 举报
--继续学习
if not object_id('Tempdb..#t') is null
drop table #t
Go
Create table #t([lvl1] int,[lvl2] int,[lvl3] int,[lvl4] int,[lvl] int)
Insert #t
select 4,3,4,1,null union all
select 3,2,2,1,null union all
select 2,2,3,4,null union all
select 4,4,3,4,null union all
select 3,1,2,2,null
Go
select
*, [lvl] = (select min(lvl1) from (select lvl1 union all select lvl2 union all select lvl3 union all select lvl4) a)
from
#t
老黎 2010-04-24
- 打赏
- 举报
老黎很笨，老黎只想到了最容易想到的方法
if not object_id('Tempdb..#t') is null
drop table #t
Go
Create table #t([lvl1] int,[lvl2] int,[lvl3] int,[lvl4] int,[lvl] int)
Insert #t
select 4,3,4,1,null union all
select 3,2,2,1,null union all
select 2,2,3,4,null union all
select 4,4,3,4,null union all
select 3,1,2,2,null
Go
select
*
,lvl = case when lvl1<=lvl2 and lvl1<=lvl3 and lvl1<=lvl4 then lvl1
when lvl2<=lvl3 and lvl2<=lvl4 and lvl2<=lvl1 then lvl2
when lvl3<=lvl4 and lvl3<=lvl1 and lvl3<=lvl2 then lvl3
when lvl4<=lvl1 and lvl4<=lvl2 and lvl4<=lvl3 then lvl4 end
from #t
J1985Z 2009-12-01
- 打赏
- 举报
没看懂题目是啥意思，但是lz写这么多应该很有道理，等以后能看懂了再回来看看啊
bulesky_xshp 2009-10-31
- 打赏
- 举报
if not object_id('Tempdb..#t') is null
drop table #t
Go
Create table #t(guid varchar(50),[lvl1] int,[lvl2] int,[lvl3] int,[lvl4] int,[lvl] int)
Insert #t
select newid(),4,3,4,1,null union all
select newid(),3,2,2,1,null union all
select newid(),2,2,3,4,null union all
select newid(),4,4,3,4,null union all
select newid(),3,1,2,2,null
Go
select [lvl1],
[lvl2],
[lvl3],
[lvl4],
[lvl]=(select min([lvl1])
from (select [lvl1] from #T as a where a.guid=#T.guid
union all select [lvl2]from #T as a where a.guid=#T.guid
union all select [lvl3] from #T as a where a.guid=#T.guid
union all select [lvl4] from #T as a where a.guid=#T.guid
)T)
from #tbulesky_xshp 2009-10-31
- 打赏
- 举报
drop table #t
Go
Create table #t(guid varchar(50),[lvl1] int,[lvl2] int,[lvl3] int,[lvl4] int,[lvl] int)
Insert #t
select newid(),4,3,4,1,null union all
select newid(),3,2,2,1,null union all
select newid(),2,2,3,4,null union all
select newid(),4,4,3,4,null union all
select newid(),3,1,2,2,null
Go
select [lvl1],
[lvl2],
[lvl3],
[lvl4],
[lvl]=(select min([lvl1])
from (select [lvl1] from #T as a where a.guid=#T.guid
union all select [lvl2]from #T as a where a.guid=#T.guid
union all select [lvl3] from #T as a where a.guid=#T.guid
union all select [lvl4] from #T as a where a.guid=#T.guid
)T)
from #t
school104 2009-10-27
- 打赏
- 举报
学习了
net_yuhai 2009-10-23
- 打赏
- 举报
学习了
lovezx1028 2009-10-23
- 打赏
- 举报
ding yixa.
nalnal_gnoD 2009-10-23
- 打赏
- 举报
学习并收藏
weichow 2009-10-23
- 打赏
- 举报
呵呵!! 好东西
gbrbw7 2009-10-22
- 打赏
- 举报
路过看看呢.
shili905 2009-10-22
- 打赏
- 举报
路过看看
icelovetwj 2009-10-22
- 打赏
- 举报
支持！
icelovetwj 2009-10-22
- 打赏
- 举报
支持！
icelovetwj 2009-10-22
- 打赏
- 举报
支持~
Rail100 2009-10-22
- 打赏
- 举报
真复杂啊
xiaoxiangqing 2009-10-22
- 打赏
- 举报
不错,支持
加载更多回复（180）
